Rilevamento dell'input di testo -- Flash CS3

Per impostazione predefinita, la proprietà type di un campo di testo è impostata su dynamic. Se si imposta la proprietà type su input mediante la classe TextFieldType, è possibile raccogliere l'input dell'utente e salvare il valore per utilizzarlo in altre parti dell'applicazione. I campi di testo di input sono utili per i form e per tutte le applicazioni che richiedono all'utente di definire un valore di testo da utilizzare altrove nel programma.

Ad esempio, il codice seguente crea un campo di testo di input denominato myTextBox. Quando l'utente immette il testo nel campo, viene attivato l'evento textInput. Un gestore di eventi di nome textInputCapture acquisisce la stringa di testo immessa e le assegna una variabile. Flash Player visualizza il nuovo testo in un altro campo di testo, di nome myOutputBox.

package
{
    import flash.display.Sprite;
    import flash.display.Stage;
    import flash.text.*;
    import flash.events.*;

    public class CaptureUserInput extends Sprite
    {
        private var myTextBox:TextField = new TextField();
        private var myOutputBox:TextField = new TextField();
        private var myText:String = "Type your text here.";

        public function CaptureUserInput()
        {
            captureText();
        }
        
        public function captureText():void
        {
            myTextBox.type = TextFieldType.INPUT;
            myTextBox.background = true;
            addChild(myTextBox);
            myTextBox.text = myText;
            myTextBox.addEventListener(TextEvent.TEXT_INPUT, textInputCapture);
        }
        
        public function textInputCapture(event:TextEvent):void
        {
            var str:String = myTextBox.text;
            createOutputBox(str);
        }
            
        public function createOutputBox(str:String):void
        {
            myOutputBox.background = true;
            myOutputBox.x = 200;
            addChild(myOutputBox);
            myOutputBox.text = str;
        }
        
    }
}