Consente all'utente di spostarsi avanti o indietro un fotogramma alla volta in un file SWF in fase di runtime (non viene visualizzato per un file SWF costituito da un solo fotogramma).

Consente all'utente di impostare un file SWF in modo che ricominci da capo automaticamente quando viene raggiunto il fotogramma finale (non viene visualizzato per un file SWF costituito da un solo fotogramma).

Consente all'utente di avviare un file SWF in stato di pausa (non viene visualizzato per un file SWF costituito da un solo fotogramma).

Consente all'utente di inviare l'immagine del fotogramma visualizzato a una stampante.

Consente all'utente di impostare la risoluzione del file SWF in fase di runtime.

Consente all'utente di impostare un file SWF in modo che, quando viene selezionato e in qualsiasi momento, venga riprodotto dal primo fotogramma (non viene visualizzato per un file SWF costituito da un solo fotogramma).

Consente agli utenti che dispongono di Shockmachine di salvare un file SWF.

Consente all'utente di ingrandire e ridurre il contenuto di un file SWF in fase di runtime.

Crea un nuovo oggetto ContextMenuBuiltInItems, in modo che possano essere impostate le proprietà di Flash Player per visualizzare o nascondere ciascuna voce di menu.

1. Una proprietà di nome myContextMenu viene dichiarata e quindi assegnata a un nuovo oggetto ContextMenu.
2. Viene chiamato il metodo removeDefaultItems(), che rimuove tutte le voci incorporate del menu di scelta rapida ad eccezione di Print.
3. Viene chiamato il metodo addCustomMenuItems(), che inserisce la voce di menu Hello World nell'array customItems utilizzando il metodo push() di Array.
4. La voce di menu Hello World viene quindi aggiunta alle voci del menu di scelta rapida dello stage.
5. Al centro dello stage viene aggiunto un oggetto TextField con il testo "Right Click" mediante addChild() e createLabel().

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.display.Sprite;
    import flash.text.TextField;

    public class ContextMenuBuiltInItemsExample extends Sprite {
        private var myContextMenu:ContextMenu;

        public function ContextMenuBuiltInItemsExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            this.contextMenu = myContextMenu;
            addChild(createLabel());
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();

            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem("Hello World");
            myContextMenu.customItems.push(item);
        }
        
        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = "Right Click";
            txtField.x = this.stage.stageWidth/2 - txtField.width/2;
            txtField.y = this.stage.stageHeight/2 - txtField.height/2;
            return txtField;
        }
    }
}