Un oggetto che ha le seguenti proprietà della classe ContextMenuBuiltInItems: forwardAndBack, loop, play, print, quality, rewind, save e zoom. Se si impostano queste proprietà su false, vengono rimosse le voci di menu corrispondenti dall'oggetto ContextMenu specificato. Queste proprietà sono enumerabili e sono impostate su true per impostazione predefinita.

Vedere anche

Un array di oggetti ContextMenuItem. Ogni oggetto dell'array rappresenta un menu di scelta rapida che è stato definito. Utilizzare questa proprietà per aggiungere, rimuovere o modificare queste voci di menu personalizzate.

Per aggiungere nuove voci di menu, creare un oggetto ContextMenuItem e successivamente aggiungerlo all'array customItems (ad esempio, mediante Array.push()). Per ulteriori informazioni sulla creazione delle voci di menu, consultare la sezione relativa alla classe ContextMenuItem.

Vedere anche

Crea un oggetto ContextMenu.

Vedere anche

Crea una copia dell'oggetto ContextMenu specificato. La copia eredita tutte le proprietà dell'oggetto menu originale.

Nasconde tutte le voci di menu incorporate (a eccezione di Settings, o Impostazioni) nell'oggetto ContextMenu. Se è in esecuzione la versione di debug di Flash Player, viene visualizzata la voce di menu Debug (per i file SWF per cui non è attivato il debug remoto, la voce di menu è disattivata).

Questo metodo nasconde solo le voci dei menu di scelta rapida standard; non ha alcun effetto sulle voci che fanno parte del menu Modifica o dei menu di errore.

Questo metodo funziona impostando tutti i membri booleani di my_cm.builtInItems su false. È possibile rendere visibile una voce di menu incorporata in modo selettivo impostandone il membro corrispondente in my_cm.builtInItems su true.

Vedere anche

Inviato quando un utente genera per la prima volta un menu di scelta rapida, ma prima che il contenuto del menu venga visualizzato. Questo consente al programma di modificare il set delle voci del menu di scelta rapida prima di visualizzare il menu. L'utente genera il menu di scelta rapida facendo clic con il pulsante destro del dispositivo di puntamento.

Questo evento ha le seguenti proprietà:

1. Una proprietà di nome myContextMenu viene dichiarata e quindi assegnata a un nuovo oggetto ContextMenu, quindi viene dichiarata una proprietà redRectangle del tipo Sprite.
2. Viene chiamato il metodo removeDefaultItems(), che rimuove tutte le voci incorporate del menu di scelta rapida ad eccezione di Print.
3. Viene chiamato il metodo addCustomMenuItems(), che inserisce la voce di menu Red to Black nell'array defaultItems utilizzando il metodo push() di Array. Viene aggiunto un listener di eventi menuItemSelect all'oggetto ContextMenuItem e viene chiamato il metodo associato menuItemSelectHandler(). Questo metodo genera alcune istruzioni mediante trace() ogni volta che viene aperto il menu di scelta rapida e viene selezionata la voce Red to Black. Inoltre, il quadrato rosso viene rimosso e viene sostituito da uno nero.
4. Viene aggiunto un listener di eventi del tipo menuSelect, insieme al metodo associato menuSelectHandler, che si limita a generare tre istruzioni mediante trace() ogni volta che viene aperta una voce del menu di scelta rapida.
5. Quindi, addChildren() disegna un quadrato rosso e lo aggiunge all'elenco di visualizzazione nel quale viene visualizzato immediatamente.
6. Infine, myContextMenu viene assegato al menu di sceta rapida dello sprite redRectangle in modo che il menu di scelta rapida venga visualizzato solo quando il puntatore del mouse si trova sopra il quadrato.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.events.ContextMenuEvent;
    import flash.events.ContextMenuEvent;
    import flash.display.Sprite;
    import flash.display.Shape;
    import flash.text.TextField;

    public class ContextMenuExample extends Sprite {
        private var myContextMenu:ContextMenu;
        private var menuLabel:String = "Reverse Colors";
        private var textLabel:String = "Right Click";
        private var redRectangle:Sprite;
        private var label:TextField;
        private var size:uint = 100;
        private var black:uint = 0x000000;
        private var red:uint = 0xFF0000;

        public function ContextMenuExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            myContextMenu.addEventListener(ContextMenuEvent.MENU_SELECT, menuSelectHandler);

            addChildren();
            redRectangle.contextMenu = myContextMenu;
        }

        private function addChildren():void {
            redRectangle = new Sprite();
            redRectangle.graphics.beginFill(red);
            redRectangle.graphics.drawRect(0, 0, size, size);
            addChild(redRectangle);
            redRectangle.x = size;
            redRectangle.y = size;
            label = createLabel();
            redRectangle.addChild(label);
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();
            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem(menuLabel);
            myContextMenu.customItems.push(item);
            item.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, menuItemSelectHandler);
        }

        private function menuSelectHandler(event:ContextMenuEvent):void {
            trace("menuSelectHandler: " + event);
        }

        private function menuItemSelectHandler(event:ContextMenuEvent):void {
            trace("menuItemSelectHandler: " + event);
            var textColor:uint = (label.textColor == black) ? red : black;
            var bgColor:uint = (label.textColor == black) ? black : red;
            redRectangle.graphics.clear();
            redRectangle.graphics.beginFill(bgColor);
            redRectangle.graphics.drawRect(0, 0, size, size);
            label.textColor = textColor;
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = textLabel;
            return txtField;
        }
    }
}