L'orientamento dell'immagine per la stampa. Questa proprietà è un valore della classe PrintJobOrientation ed è disponibile solo in seguito a una chiamata al metodo PrintJob.start().

Vedere anche

L'altezza dell'area stampabile effettiva sulla pagina, espressa in punti. Gli eventuali margini impostati dall'utente vengono ignorati. ed è disponibile solo in seguito a una chiamata al metodo PrintJob.start().

Vedere anche

La larghezza dell'area stampabile effettiva sulla pagina, espressa in punti. Gli eventuali margini impostati dall'utente vengono ignorati. ed è disponibile solo in seguito a una chiamata al metodo PrintJob.start().

Vedere anche

L'altezza totale del foglio, espressa in punti. ed è disponibile solo in seguito a una chiamata al metodo PrintJob.start().

La larghezza totale del foglio, espressa in punti. ed è disponibile solo in seguito a una chiamata al metodo PrintJob.start().

Crea un oggetto PrintJob che può essere utilizzato per stampare una o più pagine. Dopo aver creato l'oggetto PrintJob, è necessario utilizzare (nella sequenza seguente) i metodi PrintJob.start(), PrintJob.addPage() e PrintJob.send() per inviare un lavoro di stampa alla stampante.

Ad esempio, è possibile sostituire il testo segnaposto [params] per le chiamate al metodo my_pj.addPage() con parametri personalizzati, come nel codice seguente:

 // create PrintJob object
 var my_pj:PrintJob = new PrintJob();
  
 // display Print dialog box, but only initiate the print job
 // if start returns successfully.
 if (my_pj.start()) {
  
    // add specified page to print job
    // repeat once for each page to be printed
    try {
      my_pj.addPage([params]);
    }
    catch(e:Error) {
      // handle error 
    }
    try {
      my_pj.addPage([params]);
    }
    catch(e:Error) {
     // handle error 
    }
 
    // send pages from the spooler to the printer, but only if one or more
    // calls to addPage() was successful. You should always check for successful 
    // calls to start() and addPage() before calling send().
    my_pj.send();
 }
 

Non è possibile creare un secondo oggetto PrintJob mentre il primo è ancora attivo. Se si crea un secondo oggetto PrintJob (mediante una chiamata a new PrintJob()) mentre il primo oggetto PrintJob è ancora attivo, il secondo non viene creato. Per questo motivo, prima di creare un secondo PrintJob verificare la presenza del valore my_pj.

Vedere anche

Invia l'oggetto Sprite specificato come pagina singola allo spooler di stampa. Prima di utilizzare questo metodo, è necessario creare un oggetto PrintJob e quindi utilizzare PrintJob.start(). In seguito, dopo aver effettuato una o più chiamate a PrintJob.addPage() per un lavoro di stampa, utilizzare PrintJob.send() per inviare alla stampante le pagine elaborate dallo spooler. In altre parole, dopo aver creato l'oggetto PrintJob, utilizzare (nella sequenza seguente) i metodi PrintJob.start(), PrintJob.addPage() e PrintJob.send() per inviare un lavoro di stampa alla stampante. È possibile utilizzare PrintJob.addPage() più volte in seguito a una chiamata singola a PrintJob.start() per stampare più pagine contemporaneamente.

Se PrintJob.addPage() provoca la generazione di un'eccezione da parte di Flash Player (ad esempio se non è stata effettuata una chiamata a PrintJob.start() o se l'utente ha annullato il lavoro di stampa), tutte le successive chiamate a PrintJob.addPage() danno esito negativo. Tuttavia, se le precedenti chiamate a PrintJob.addPage() sono state effettuate correttamente, il comando PrintJob.send() conclusivo invia alla stampante le pagine inserite correttamente nello spool.

Se il lavoro di stampa impiega più di 15 secondi per completare un'operazione PrintJob.addPage(), Flash Player genera un'eccezione alla successiva chiamata a Print.addPage().

Se si passa un valore per il parametro printArea, le coordinate x e y dell'oggetto printArea vengono mappate all'angolo superiore sinistro (coordinate 0,0) dell'area stampabile della pagina. L'area stampabile è descritta dalle proprietà di sola lettura pageHeight e pageWidth impostate da PrintJob.start(). Dal momento che la pagina stampata è allineata all'angolo superiore sinistro dell'area stampabile della pagina, se l'area definita in printArea è superiore all'area stampabile della pagina, la pagina stampata viene troncata sul lato destro e/o inferiore dell'area definita da printArea. Se non si passa un valore per printArea e lo stage è più grande dell'area stampabile, viene applicato lo stesso tipo di troncatura.

Per modificare in scala un oggetto Sprite prima della stampa, impostarne le proprietà (vedere flash.display.DisplayObject.scaleX e flash.display.DisplayObject.scaleY) prima di chiamare questo metodo e impostarle di nuovo sui rispettivi valori originali dopo la stampa. La scala di un oggetto Sprite non ha alcuna relazione con printArea. In altre parole, se si specifica un'area di stampa di 50 x 50 pixel, vengono stampati 2500 pixel. Se si modifica in scala l'oggetto Sprite, vengono stampati gli stessi 2500 pixel ma l'oggetto viene stampato nelle dimensioni modificate in scala.

La funzione di stampa di Flash Player supporta le stampanti PostScript e non PostScript. Le stampanti non PostScript convertono la grafica vettoriale in bitmap.

Parametri

Vedere anche

Invia alla stampante le pagine elaborate dallo spooler in seguito all'esito positivo delle chiamate a PrintJob.start() e PrintJob.addPage(). Le chiamate a PrintJob.send() non vengono eseguite correttamente se la chiamata a PrintJob.start() fallisce oppure se PrintJob.addpage() genera un'eccezione. Per questo motivo, prima di chiamare PrintJob.send(), è necessario verificare che PrintJob.start() restituisca true e rilevare eventuali eccezioni di PrintJob.addpage(). Ad esempio:

  var my_pj:PrintJob = new PrintJob();
    if (my_pj.start()) {
    try {
      my_pj.addPage([params]);
   }
    catch(e:Error) {
      // gestione dell'errore 
   }
      my_pj.send();
  }
  

Vedere anche

Visualizza la finestra di dialogo di stampa del sistema operativo, avvia lo spooling e imposta i valori delle proprietà di sola lettura di PrintJob. Questa finestra di dialogo consente all'utente di modificare le impostazioni di stampa. Quando il metodo PrintJob.start() restituisce un valore corretto (l'utente fa clic su OK nella finestra di dialogo di stampa), vengono specificate le seguenti proprietà di sola lettura, che rappresentano le impostazioni di stampa dell'utente:

Nota: se l'utente esce dalla finestra di dialogo di stampa facendo clic su Annulla, le proprietà non vengono specificate.

Dopo che l'utente ha fatto clic su OK nella finestra di dialogo Stampa, Flash Player inizia l'esecuzione dello spooling sul sistema operativo di un lavoro di stampa. Poiché iniziano ad essere visualizzate le informazioni sull'avanzamento della stampa, è necessario eseguire le chiamate a PrintJob.addPage() e PrintJob.send() il più presto possibile per inviare le pagine allo spooler. Per formattare la pagina stampata, è possibile utilizzare le proprietà di sola lettura relative all'altezza, alla larghezza e all'orientamento che vengono completate da questo metodo.

Verificare che il metodo restituisca true (quando l'utente fa clic su OK nella finestra di stampa del sistema operativo) prima di qualsiasi chiamata successiva a PrintJob.addPage() e PrintJob.send():

  var my_pj:PrintJob = new PrintJob();
     if(my_pj.start()) {
       // inserire qui le istruzioni addPage() e send() 
     }
  

Per l'istanza PrintJob specificata, se uno dei seguenti intervalli dura più di 15 secondi, la chiamata successiva a PrintJob.start() restituisce false:

• PrintJob.start() e il primo PrintJob.addPage()
• Un PrintJob.addPage() e il successivo PrintJob.addPage()
• L'ultimo PrintJob.addPage() e PrintJob.send()

Vedere anche

1. Dichiarare due variabili del tipo Sprite denominate sheet1 e sheet2.
2. Chiamare init(), che assegna una nuova istanza Sprite sia a sheet1 e sheet2 e quindi chiama createSheet() utilizzando argomenti diversi.
3. createSheet() consente di eseguire le seguenti operazioni:
   1. L'oggetto Sprite passato viene utilizzato per disegnare un rettangolo con uno sfondo grigio chiaro, un bordo nero di un pixel e una larghezza di 100 pixel e un'altezza di 200 pixel con x = 0, y = 0.
   2. Viene creato un nuovo oggetto TextField denominato txt con le stesse dimensioni di Sprite, la proprietà wordWrap impostata su true e la proprietà di testo impostata sul parametro String passato come argomento a createSheet().
   3. Se l'argomento Object passato non è null, creare una nuova istanza Sprite denominata img che viene utilizzata per disegnare un rettangolo con le proprietà di coordinate e dimensioni dell'argomento Object passato. Il rettangolo bianco viene aggiunto all'elenco di visualizzazione dell'oggetto Sprite utilizzando addChild().
   4. L'oggetto TextField txt viene aggiunto all'elenco di visualizzazione dell'oggetto Sprite utilizzando addChild().
4. Nella funzione di costruzione viene chiamato il metodo di stampa attivato (non impostato come commento). Poiché i metodi sono molto simili, printOnePerPage() è descritto di seguito.
5. printOnePerPage() consente di eseguire le seguenti operazioni:
   1. Dichiarare un nuovo oggetto PrintJob denominato pj e pagesToPrint come uint.
   2. Aprire la finestra di dialogo relativa alla stampa nativa del sistema operativo e attendere che l'utente faccia clic su OK.
   3. Verificare l'orientamento e se è selezionato Landscape (orizzontale), generare un errore e uscire.
   4. Impostare l'altezza e la larghezza della pagina per sheet1 e sheet2.
   5. Inviare sheet1 e sheet2 allo spooler di stampa utilizzando addPage().
   6. Se il numero di pagine da stampare è > 0, stampare tutte le pagine elaborate dallo spooler.
6. Viene chiamato il metodo draw(), che ridimensiona le due proprietà Sprite per adattarle allo stage e riposiziona sheet2 in modo che si trovi immediatamente a destra di sheet1.

Nota: la funzione di costruzione è impostata in modo che sia possibile selezionare uno dei tre metodi di stampa (un foglio per pagina, due fogli per pagina o stampa nella metà superiore della pagina), in base alle preferenze. Questo esempio non funzionerà correttamente, a meno che non vengano disattivati due metodi di stampa specifici utilizzando commenti nel codice. L'esempio è impostato in modo che venga chiamato printOnePerPage().

package {
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOrientation;
    import flash.display.Stage;
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.geom.Rectangle;
       
    public class PrintJobExample extends Sprite {
        private var sheet1:Sprite;
        private var sheet2:Sprite;
           
        public function PrintJobExample() {
            init();
            printOnePerPage();
//            printTwoPerPage();
//            printTopHalf();
            draw();
        }
        
        private function init():void {
            sheet1 = new Sprite();
            createSheet(sheet1, "Once upon a time...", {x:10, y:50, width:80, height:130});

            sheet2 = new Sprite();
            createSheet(sheet2, "There was a great story to tell, and it ended quickly.\n\nThe end.", null);
        }
        
        private function createSheet(sheet:Sprite, str:String, imgValue:Object):void {
            sheet.graphics.beginFill(0xEEEEEE);
            sheet.graphics.lineStyle(1, 0x000000);
            sheet.graphics.drawRect(0, 0, 100, 200);
            sheet.graphics.endFill();
            
            var txt:TextField = new TextField();
            txt.height = 200;
            txt.width = 100;
            txt.wordWrap = true;
            txt.text = str;
            
            if(imgValue != null) {
                var img:Sprite = new Sprite();
                img.graphics.beginFill(0xFFFFFF);
                img.graphics.drawRect(imgValue.x, imgValue.y, imgValue.width, imgValue.height);
                img.graphics.endFill();
                sheet.addChild(img);
            }
            sheet.addChild(txt);
        }
        
        private function printOnePerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.LANDSCAPE) {    
                    throw new Error("Without embedding fonts you must print one sheet per page with an orientation of portrait.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth;

                try {
                    pj.addPage(sheet1);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                try {
                    pj.addPage(sheet2);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }
        
        private function printTwoPerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print two sheets per page with an orientation of landscape.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }

        private function printTopHalf():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {                
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print the top half with an orientation of landscape.");
                }
                
                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets, new Rectangle(0, 0, sheets.width, sheets.height/2));
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }


        private function draw():void {
            var sheetWidth:Number = this.stage.stageWidth/2;
            var sheetHeight:Number = this.stage.stageHeight;
            
            addChild(sheet1);
            sheet1.width = sheetWidth;
            sheet1.height = sheetHeight;
            
            addChild(sheet2);
            sheet2.width = sheetWidth;
            sheet2.height = sheetHeight;
            sheet2.x = sheet1.width;
        }        
    }
}