Il tipo di contenuto MIME di qualunque dato POST.

Nota: i metodi FileReference.upload() e FileReference.download() non supportano il parametro URLRequest.contentType.

Un oggetto che contiene i dati da trasmettere con la richiesta URL.

Questa proprietà viene utilizzata con la proprietà method. Se il valore di URLRequest.method è POST, i dati vengono trasmessi con l'oggetto URLRequest utilizzando il metodo HTTP POST.

Se il valore di URLRequest.method è GET, i dati definiscono le variabili da inviare con l'oggetto URLRequest utilizzando il metodo HTTP GET.

L'API URLRequest offre il supporto POST binario e il supporto per le variabili con codifica URL, oltre al supporto per le stringhe. L'oggetto dati può essere di tipo ByteArray, URLVariables o String.

Il modo di utilizzo dei dati dipende dal tipo degli oggetti utilizzati:

• Se l'oggetto è un oggetto ByteArray, i dati binari dell'oggetto ByteArray vengono utilizzati come dati POST. Per GET, i dati di tipo ByteArray non sono supportati. Anche per FileReference.upload() e FileReference.download() i dati di tipo ByteArray non sono supportati.
• Se l'oggetto è un oggetto URLVariables e il metodo è POST, le variabili vengono codificate utilizzando il formato x-www-form-urlencoded e la stringa risultante viene utilizzata come dati POST. Un'eccezione è rappresentata da una chiamata a FileReference.upload(), in cui le variabili vengono inviate sotto forma di campi separati in un post multipart/form-data.
• Se l'oggetto è un oggetto URLVariables e il metodo è GET, l'oggetto URLVariables definisce le variabili da inviare con l'oggetto URLRequest.
• In caso contrario, l'oggetto viene convertito in una stringa, che viene utilizzata come dati POST o GET.

Questi dati vengono inviati fino a quando un metodo, ad esempio navigateToURL() o FileReference.upload(), utilizza l'oggetto URLRequest.

Vedere anche

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

Controlla se il metodo di invio dei form HTTP è un'operazione GET o POST. Il valore valido è URLRequestMethod.GET o URLRequestMethod.POST.

Il valore predefinito è URLRequestMethod.GET.

Vedere anche

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;
            
            navigateToURL(request);
        }
    }
}

L'array di intestazioni di richiesta HTTP da aggiungere alla richiesta HTTP. L'array è composto da oggetti URLRequestHeader. Ogni oggetto nell'array deve essere un oggetto URLRequestHeader che contiene una stringa nome e un valore stringa, come nell'esempio seguente:

  var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));
  

Flash Player impone determinate limitazioni alle intestazioni di richiesta; per ulteriori informazioni, vedere la descrizione della classe URLRequestHeader.

I metodi FileReference.upload() e FileReference.download() non supportano il parametro URLRequest.requestHeaders.

Vedere anche

L'URL da richiedere. Per impostazione predefinita, l'URL deve essere esattamente nello stesso dominio del file SWF che emette la chiamata, compresi i sottodomini. Ad esempio, i file SWF in www.adobe.com e store.adobe.com si trovano in domini diversi. Per caricare dati da un dominio diverso, collocare un file dei criteri dei domini sul server che ospita i dati. Per ulteriori informazioni, consultare la documentazione relativa alla sicurezza indicata nella descrizione della classe URLRequest.

Nota: Flash Player Aggiornamento 3 e versioni successive supportano IPv6 (Internet Protocol versione 6). IPv6 è una versione del protocollo Internet che supporta gli indirizzi a 128 bit (rappresenta un miglioramento rispetto al precedente protocollo IPv4 che supportava indirizzi a 32 bit). Potrebbe essere necessario attivare Ipv6 sulle interfacce di rete. Per maggiori informazioni, consultare la guida del sistema operativo sul quale si trovano i dati. Se il sistema ospite supporta IPv6 è possibile specificare il valore letterale numerico IPv6 degli indirizzi posti tra parentesi quadre ([]), come nel seguente esempio:

     rtmp://[2001:db8:ccc3:ffff:0:444d:555e:666f]:1935/test
     

Crea un oggetto URLRequest. Se System.useCodePage è true, la richiesta viene codificata utilizzando la tabella codici di sistema, anziché Unicode. Se System.useCodePage è false, la richiesta viene codificata utilizzando Unicode, anziché la tabella codici di sistema.

Vedere anche

Per provare l'esempio, collocare un file di nome XMLFile.xmf nella stessa directory del file SWF.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {

        public function URLRequestExample() {
            var loader:URLLoader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}