Indica il numero di byte che sono stati caricati fino a quel momento durante l'operazione di caricamento.

Indica il numero totale di byte dei dati scaricati. Questa proprietà contiene 0 mentre l'operazione di caricamento è in corso e viene compilata al termine dell'operazione. Inoltre, un'intestazione Content-Length mancante causa l'indeterminazione di bytesTotal.

I dati ricevuti dall'operazione di caricamento. Questa proprietà viene compilata solo quando l'operazione di caricamento è stata completata. Il formato dei dati dipende dall'impostazione della proprietà dataFormat:

Se la proprietà dataFormat è URLLoaderDataFormat.TEXT, i dati ricevuti sono costituiti da una stringa che contiene il testo del file caricato.

Se la proprietà dataFormat è URLLoaderDataFormat.BINARY, i dati ricevuti sono costituiti da un oggetto ByteArray che contiene i dati binari originari.

Se la proprietà dataFormat è URLLoaderDataFormat.VARIABLES, i dati ricevuti sono costituiti da un oggetto URLVariables che contiene le variabili con codifica URL.

Vedere anche

Controlla se i dati scaricati vengono ricevuti sotto forma di testo (URLLoaderDataFormat.TEXT), dati binari originari (URLLoaderDataFormat.BINARY) o variabili con codifica URL (URLLoaderDataFormat.VARIABLES).

Se il valore della proprietà dataFormat è URLLoaderDataFormat.TEXT, i dati ricevuti sono costituiti da una stringa che contiene il testo del file caricato.

Se il valore della proprietà dataFormat è URLLoaderDataFormat.BINARY, i dati ricevuti sono costituiti da un oggetto ByteArray che contiene i dati binari originari.

Se il valore della proprietà dataFormat è URLLoaderDataFormat.VARIABLES, i dati ricevuti sono costituiti da un oggetto URLVariables che contiene le variabili con codifica URL.

Il valore predefinito è URLLoaderDataFormat.TEXT.

Vedere anche

Crea un oggetto URLLoader.

Vedere anche

Chiude l'operazione di caricamento in corso. Tutte le operazioni di caricamento in corso vengono immediatamente terminate. Se al momento non è in corso lo streaming di un URL, viene generato un errore di streaming non valido.

Invia e carica i dati da un URL specificato. I dati possono essere ricevuti sotto forma di testo, dati binari originari o variabili con codifica URL, a seconda del valore che è stato impostato per la proprietà dataFormat. Il valore predefinito per la proprietà dataFormat è text. Per inviare dati all'URL specificato, è possibile impostare la proprietà data nell'oggetto URLRequest.

Nota: se un file caricato contiene caratteri non ASCII come in molte lingue diverse dall'inglese, si consiglia di salvare il file con una codifica UTF-8 o UTF-16, in contrapposizione a un formato non codificato con Unicode come ASCII.

Quando si utilizza questo metodo, considerare il modello di sicurezza di Flash Player:

Per Flash Player 9 e versioni successive, è possibile impedire a un file SWF di utilizzare questo metodo impostando il parametro allowNetworking dei tag object ed embed nella pagina HTML in cui è presente il contenuto SWF.

Per Flash Player 8 e versioni successive:

• Il caricamento dei dati non è consentito se il file SWF si trova nella sandbox locale con file system e la risorsa di destinazione si trova in una sandbox di rete.
• Il caricamento dei dati non è consentito nemmeno se il file SWF chiamante si trova in una sandbox di rete mentre la risorsa di destinazione è locale.

Per Flash Player 7 e versioni successive l'accesso a una risorsa sui siti Web è consentito mediante un file dei criteri per i domini. Nei file SWF di qualunque versione eseguita in Flash Player 7 e versioni successive, url deve trovarsi esattamente nello stesso dominio. Ad esempio, un file SWF sul sito www.adobe.com può caricare i dati solo dalle origini presenti in www.adobe.com.

Per ulteriori informazioni, vedere i seguenti riferimenti:

• Il capitolo Sicurezza di Flash Player nel volume Programmazione in ActionScript 3.0 e i commenti più recenti in LiveDocs
• Il White paper sulla sicurezza per Flash Player 9

Nei file SWF in esecuzione su una versione di Flash Player precedente alla 7, url deve trovarsi nello stesso superdominio del file SWF che effettua la chiamata. Per identificare il superdominio, rimuovere la parte più a sinistra dell'URL di un file. Ad esempio, un file SWF all'indirizzo www.adobe.com può scaricare i dati da origini presenti in store.adobe.com poiché entrambi i file si trovano nello stesso superdominio di adobe.com.

Parametri

Vedere anche

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.xml.*;
    import flash.events.IOErrorEvent;
  
    public class URLLoader_loadExample extends Sprite {
        private var xmlTextField:TextField = new TextField();
        private var externalXML:XML;    
        private var loader:URLLoader;

        public function URLLoader_loadExample() {
            var request:URLRequest = new URLRequest("xmlFile.xml");

            loader = new URLLoader();
            
            try {
                loader.load(request);
            }
            catch (error:SecurityError)
            {
                trace("A SecurityError has occurred.");
            }

             loader.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            loader.addEventListener(Event.COMPLETE, loaderCompleteHandler);

            xmlTextField.x = 10;
            xmlTextField.y = 10;
            xmlTextField.background = true;
            xmlTextField.autoSize = TextFieldAutoSize.LEFT;

            addChild(xmlTextField);
        }

        private function loaderCompleteHandler(event:Event):void {

                try {
                    externalXML = new XML(loader.data);
                    readNodes(externalXML);    
                } catch (e:TypeError) {
                    trace("Could not parse the XML file.");
                }
        }

        private function readNodes(node:XML):void {

                for each (var element:XML in node.elements()) {
                    xmlTextField.appendText(element.attributes()[0] + "\n");

                    readNodes(element);
                }    
        }

        private function errorHandler(e:IOErrorEvent):void {
            xmlTextField.text = "Had problem loading the XML File.";
        }
    }
}

Inviato dopo che tutti i dati ricevuti sono stati decodificati e collocati nella proprietà data dell'oggetto URLLoader. È possibile accedere ai dati ricevuti solo quando questo evento è stato inviato.

Questo evento ha le seguenti proprietà:

Vedere anche

Inviato se una chiamata a URLLoader.load() tenta di accedere ai dati via HTTP e l'ambiente Flash Player corrente è in grado di rilevare e restituire il codice di stato della richiesta. (Alcuni ambienti browser potrebbero non essere in grado di fornire queste informazioni). L'evento httpStatus (se presente) viene inviato prima di (e in aggiunta a) qualsiasi evento complete o error.

Questo evento ha le seguenti proprietà:

Vedere anche

Inviato se una chiamata a URLLoader.load() produce un errore fatale che termina lo scaricamento.

Questo evento ha le seguenti proprietà:

Vedere anche

Inviato quando l'operazione di scaricamento inizia in seguito a una chiamata al metodo URLLoader.load().

Questo evento ha le seguenti proprietà:

Vedere anche

Inviato quando vengono ricevuti i dati mentre è in corso l'operazione di scaricamento.

Con un oggetto URLLoader non è possibile accedere ai dati fino a quando i dati non sono stati completamente ricevuti. Pertanto, l'evento di avanzamento funge solo da notifica dell'avanzamento dello scaricamento. Per accedere ai dati prima di averli completamente scaricati, utilizzare un oggetto URLStream.

Questo evento ha le seguenti proprietà:

Vedere anche

Inviato se una chiamata al metodo URLLoader.load() tenta di caricare dati da un server al di fuori della funzione di sicurezza sandbox.

Questo evento ha le seguenti proprietà:

Vedere anche

Nota: per provare l'esempio, collocare un file denominato urlLoaderExample.txt nella stessa directory del file SWF. Il file deve contenere solo la riga di testo seguente: answer=42&question=unknown

Il codice di esempio esegue le seguenti operazioni:

1. La funzione di costruzione crea un'istanza URLLoader di nome loader e un'istanza URLRequest di nome request, che contiene la posizione e il nome del file da caricare.
2. L'oggetto loader viene passato al metodo configureListeners() che aggiunge i listener per ognuno degli eventi URLLoader supportati.
3. Quindi, l'oggetto request viene passato a loader.load(), che carica il file di testo.
4. Quando URLLoader ha terminato il caricamento del file di testo, si attiva l'evento Event.COMPLETE, che a sua volta attiva il metodo completeHandler(). Il metodo completeHandler() crea un oggetto URLVariables dal testo caricato dal file. L'oggetto URLVariables converte le coppie nome/valore con codifica URL in proprietà ActionScript per facilitare la gestione dei dati caricati.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLLoaderExample extends Sprite {
        public function URLLoaderExample() {
            var loader:URLLoader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("urlLoaderExample.txt");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
    
            var vars:URLVariables = new URLVariables(loader.data);
            trace("The answer is " + vars.answer);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}