Un oggetto ColorTransform contenente valori che rettificano i colori dell'oggetto di visualizzazione a livello globale.

Vedere anche

Un oggetto ColorTransform che rappresenta le trasformazioni di colore combinate applicate all'oggetto di visualizzazione e a tutti i suoi oggetti principali, fino al livello principale. Se sono state applicate trasformazioni di colore diverse a livelli diversi, tutte le trasformazioni vengono concatenate in un oggetto ColorTransform per questa proprietà.

Vedere anche

Un oggetto Matrix che rappresenta le matrici di trasformazione combinate dell'oggetto di visualizzazione e di tutti i suoi oggetti principali, fino al livello principale. Se sono state applicate matrici di trasformazione diverse a livelli diversi, tutte le matrici vengono concatenate in una matrice per questa proprietà.

Un oggetto Matrix contenente valori che modificano la scala, la rotazione e la conversione dell'oggetto di visualizzazione.

Vedere anche

Un oggetto Rectangle che definisce il rettangolo che delimita l'oggetto di visualizzazione sullo stage.

1. La funzione di costruzione TransformExample() crea un nuovo oggetto sprite target.
2. La funzione di costruzione TransformExample() chiama il metodo draw(), che disegna un quadrato con gradiente nello sprite.
3. La funzione di costruzione TransformExample() aggiunge un listener di eventi click per lo sprite, che viene gestito dal metodo clickHandler().
4. Il metodo clickHandler() crea un nuovo oggetto Matrix, skewMatrix, impostato in modo da applicare un effetto di inclinazione. Alla matrice di trasformazione corrente dello sprite viene assegnata un'altra matrice, tempMatrix, che viene quindi combinata con la matrice skewMatrix utilizzando il metodo concat(). Questa matrice viene assegnata alla proprietà transform.matrix dello sprite quadrato. Ogni volta che l'utente fa clic sul quadrato, la chiamata al metodo clickHandler() modifica la forma del quadrato inclinandolo.
5. Inoltre, il metodo clickHandler() crea un nuovo oggetto ColorTransform. La proprietà redOffset del nuovo oggetto ColorTransform viene impostata sul valore corrente di redOffset e viene aumentata di 25. In modo analogo, la proprietà blueOffset viene diminuita di 25. A ogni clic i colori dello sprite vengono cambiati.

package {
    import flash.display.Sprite;
    import flash.display.GradientType;
    import flash.geom.Matrix;
    import flash.geom.ColorTransform;
    import flash.events.MouseEvent;

    public class TransformExample extends Sprite {
        public function TransformExample() { 
            var target:Sprite = new Sprite();
            draw(target);
            addChild(target);
            target.useHandCursor = true;
            target.buttonMode = true;
            target.addEventListener(MouseEvent.CLICK, clickHandler)
        }
        public function draw(sprite:Sprite):void {
            var red:uint = 0xFF0000;
            var green:uint = 0x00FF00;
            var blue:uint = 0x0000FF;
            var size:Number = 100;
            sprite.graphics.beginGradientFill(GradientType.LINEAR, [red, blue, green], [1, 0.5, 1], [0, 200, 255]);
            sprite.graphics.drawRect(0, 0, 100, 100);
        }
        public function clickHandler(event:MouseEvent):void {
            var skewMatrix:Matrix = new Matrix();
            skewMatrix.c = 0.25;
            var tempMatrix:Matrix = this.transform.matrix;
            tempMatrix.concat(skewMatrix);
            this.transform.matrix = tempMatrix;
            
            var rOffset:Number = this.transform.colorTransform.redOffset + 25;
            var bOffset:Number = this.transform.colorTransform.blueOffset - 25;
            this.transform.colorTransform = new ColorTransform(1, 1, 1, 1, rOffset, 0, bOffset, 0);            
        }
    }
}