Il numero di elementi o di byte caricati nel momento in cui il listener elabora l'evento.

Il numero totale di elementi o di byte che saranno caricati se il processo di caricamento viene completato correttamente.

Crea un oggetto Event contenente informazioni relative agli eventi progress. Gli oggetti evento vengono passati ai listener di eventi come parametri.

Crea una copia dell'oggetto ProgressEvent e imposta il valore di ogni proprietà in modo che corrisponda a quello dell'originale.

Restituisce una stringa che contiene tutte le proprietà dell'oggetto ProgressEvent. La stringa ha il seguente formato:

[ProgressEvent type=value bubbles=value cancelable=value bytesLoaded=value bytesTotal=value]

Definisce il valore della proprietà type di un oggetto evento progress.

Questo evento ha le seguenti proprietà:

Vedere anche

Definisce il valore della proprietà type di un oggetto evento socketData.

Questo evento ha le seguenti proprietà:

Vedere anche

1. Vengono create le proprietà downloadURL e fileName, che indicano la posizione e il nome del file da scaricare.
2. Nella funzione di costruzione ProgressEventExample viene creato un nuovo oggetto FileReference di nome file, che viene quindi passato al metodo configureListeners().
3. Le proprietà downloadURL e fileName vengono quindi passate a file.download(), che richiede la posizione in cui scaricare il file.
4. Il metodo configureListeners() aggiunge sette listener di eventi e i metodi subscriber a essi associati:
   1. cancel / cancelHandler() viene inviato se lo scaricamento del file viene annullato.
   2. complete / complereHandler() viene inviato al termine del processo di scaricamento del file.
   3. ioError / ioErrorHandler() viene inviato se il file da scaricare non è disponibile o accessibile.
   4. open / openHandler() viene inviato all'avvio dell'operazione di scaricamento.
   5. progress / progressHandler() viene inviato quando inizia il processo di scaricamento e di nuovo quando termina.
   6. securityError / securityErrorHandler viene inviato se l'impostazione di sicurezza per la riproduzione locale non corrisponde al tipo di accesso ai dati per il file da scaricare (locale o in rete); vedere le note di seguito.
   7. select / selectHandler() viene inviato quando viene selezionato l'oggetto da scaricare.

Note:

• È necessario compilare il file SWF con Sicurezza riproduzione locale impostato su Accedi solo alla rete.
• In questo esempio è necessario un file di nome SomeFile.pdf.
• Anche se questo esempio utilizza tutti gli eventi disponibili per l'oggetto FileReference, nella maggior parte delle situazioni è richiesto solo un sottoinsieme.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class ProgressEventExample extends Sprite {
        private var downloadURL:String = "http://www.[yourDomain].com/SomeFile.pdf";
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function ProgressEventExample() {
            var request:URLRequest = new URLRequest(downloadURL);
            file = new FileReference();
            configureListeners(file);
            file.download(request, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL);
        }
    }
}