Un oggetto con proprietà che ne descrivono lo stato o la condizione di errore.

L'oggetto information potrebbe avere una proprietà code contenente una stringa che rappresenta un evento specifico, oppure una proprietà level contenente la stringa "status" o "error".

L'oggetto information potrebbe anche essere qualcosa di diverso. Le proprietà code e level potrebbero non funzionare in alcune implementazioni e alcuni server potrebbero inviare oggetti diversi.

Nella tabella seguente sono descritti i possibili valori di stringa delle proprietà code e level.

Se vengono continuamente rilevati errori relativi al buffer, provare a modificarlo mediante la proprietà NetStream.bufferTime.

Vedere anche

Crea un oggetto Event contenente informazioni relative agli eventi netStatus. Gli oggetti evento vengono passati ai listener di eventi come parametri.

Vedere anche

Crea una copia dell'oggetto NetStatusEvent e imposta il valore di ogni proprietà in modo che corrisponda a quello dell'originale.

Restituisce una stringa che contiene tutte le proprietà dell'oggetto NetStatusEvent. La stringa ha il seguente formato:

[NetStatusEvent type=value bubbles=value cancelable=value info=value]

Definisce il valore della proprietà type di un oggetto evento netStatus.

Questo evento ha le seguenti proprietà:

Vedere anche

In questo esempio, il metodo netStatusHandler viene registrato come listener per l'evento NetStatusEvent NetConnection.netStatus. Quando viene determinato lo stato (positivo o negativo) del tentativo di NetConnection.connect(), l'evento netStatus attiva questo metodo. Se il tentativo di connettersi all'oggetto NetConnection ha esito positivo (in altre parole, se alla proprietà info dell'oggetto NetStatusEvent inviata dall'evento netStatus è associata la proprietà code che indica l'esito positivo), il codice crea gli oggetti Video e NetStream ed effettua una chiamata ai metodi Video.attachNetStream() e NetStream.play().

Nota: per provare questo esempio, è necessario un file FLV con un nome e una posizione che corrispondono alla variabile passata a videoURL; in questo caso, si tratta di un file FLV denominato Video.flv che si trova nella stessa directory del file SWF.

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class NetStatusEventExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function NetStatusEventExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }

    }
 }