Un valore della classe StageAlign che specifica l'allineamento dello stage in Flash Player o nel browser. I valori validi sono i seguenti:

La proprietà align è disponibile solo a un oggetto che si trova nella stessa funzione di sicurezza sandbox del titolare dello stage (il file SWF principale). Per evitare questa situazione, il titolare dello stage può autorizzare il dominio dell'oggetto chiamante chiamando il metodo Security.allowDomain() o Security.alowInsecureDomain(). Per ulteriori informazioni, consultare il capitolo "Sicurezza" in Programmazione in ActionScript 3.0.

Vedere anche

Un valore della classe StageDisplayState che specifica lo stato di visualizzazione da utilizzare. I valori validi sono i seguenti:

• StageDisplayState.FULL_SCREEN — Istruisce Flash Player a espandere lo stage fino a occupare l'intero schermo dell'utente.
• StageDisplayState.NORMAL — Riporta il lettore alla modalità di visualizzazione standard dello stage.

Il comportamento di ridimensionamento del filmato nella modalità a schermo intero è determinato dall'impostazione scaleMode (definita mediante la proprietà Stage.scaleMode o le impostazioni del tag embed del file SWF all'interno del file HTML). Se la proprietà scaleMode viene impostata su noScale mentre Flash Player passa alla modalità a schermo intero, le proprietà width e height dello stage vengono aggiornate e viene inviato l'evento Stage.resize.

Le restrizioni seguenti si applicano ai file SWF che vengono riprodotti all'interno di una pagina HTML (non quelli eseguiti nel lettore Flash Player autonomo):

• Per attivare la modalità a schermo intero, aggiungere il parametro allowFullScreen ai tag object e embed nella pagina HTML che include il file SWF, con allowFullScreen impostato su "true", come mostrato nell'esempio seguente:

  <param name="allowFullScreen" value="true" />
           ...
    <embed src="example.swf" allowFullScreen="true" ... >

  Una pagina HTML può anche usare uno script per generare tag di incorporamento SWF. È necessario modificare lo script in modo da inserire le impostazioni allowFullScreen corrette. Le pagine HTML generate da Flash e Flex Builder impiegano la funzione AC_FL_RunContent() per incorporare riferimenti a file SWF; l'utente deve aggiungere le impostazioni del parametro allowFullScreen come indicato di seguito:

  AC_FL_RunContent( ... "allowFullScreen", "true", ... )

• La modalità a schermo intero viene attivata in risposta a un clic del mouse o a una pressione di un tasto da parte dell'utente; il filmato non può cambiare la proprietà Stage.displayState senza l'intervento dell'utente. Quando Flash Player è in modalità a schermo intero, l'input dalla tastiera è disabilitato (a eccezione delle scelte rapide da tastiera che consentono all'utente di uscire dalla modalità a schermo intero). Quando l'utente attiva la modalità a schermo intero, una finestra di dialogo di Flash Player visualizzata sopra il filmato informa l'utente che la modalità a schermo intero è stata attivata e può essere chiusa premendo il tasto Esc.
• A partire dalla versione Flash Player Aggiornamento 3, la modalità a schermo intero funziona in modo identico nella modalità senza finestra e finestra. Se si imposta la modalità finestra (wmode nell'HTML) su Opaca senza finestra (opaque) o Trasparente senza finestra (transparent), è possibile avviare la modalità a schermo intero, ma la finestra rimane sempre opaca.

Vedere anche

package {
    import flash.display.Sprite;
    import flash.display.Stage;
    import flash.events.*;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.media.Video;
    
    public class FullScreenExample extends Sprite
    {
        private var videoURL:String = "testVideo.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var video:Video;        
        
        public function FullScreenExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
            
            loaderInfo.addEventListener(Event.INIT, createMouseListener);            
        }

        private function createMouseListener(event:Event):void {
            stage.addEventListener(MouseEvent.CLICK,toggleFullScreen);
        }        
        
        private function toggleFullScreen(event:MouseEvent):void {
            switch(stage.displayState) {
                case "normal":
                    stage.displayState = "fullScreen";    
                    break;
                case "fullScreen":
                default:
                    stage.displayState = "normal";    
                    break;
            }
        }    
        
        // Video related:
        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }
        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);

            video = new Video(stage.stageWidth,stage.stageHeight);
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }            
    }
}

L'oggetto interattivo attivato mediante la tastiera, oppure null se l'attivazione non è impostata oppure l'oggetto attivo appartiene a una sicurezza sandbox alla quale l'oggetto chiamante non ha accesso.

Ottiene e imposta la frequenza di fotogrammi dello stage. La frequenza è espressa in fotogrammi al secondo. Per impostazione predefinita, la frequenza impostata è quella del primo file SWF caricato. I valori validi sono compresi tra 0.01 e 1000 fotogrammi al secondo.

Nota: Flash Player potrebbe non essere in grado di applicare valori di frequenza di fotogrammi particolarmente elevati, ad esempio perché la piattaforma di destinazione non è abbastanza veloce oppure il lettore è sincronizzato con la temporizzazione verticale vuota del dispositivo di visualizzazione (solitamente 60 Hz sui dispositivi LCD). In alcuni casi, una piattaforma di destinazione potrebbe anche scegliere di ridurre la frequenza di fotogrammi massima se è previsto un uso intensivo della CPU.

Restituisce l'altezza del monitor che verrà utilizzata per la modalità a schermo intero, se tale stato viene attivato immediatamente. Se l'utente utilizza vari monitor, il monitor utilizzato è quello su cui si trova la maggior parte dello stage in un preciso momento.

Nota: se l'utente ha la possibilità di spostare il browser da un monitor a un altro tra il recupero del valore e il passaggio alla modalità a schermo intero, il valore potrebbe non essere corretto. Se si ripristina il valore in un gestore eventi che imposta Stage.displayState su StageDisplayState.FULL_SCREEN, il valore sarà corretto.

Questa è l'altezza in pixel del monitor, che corrisponde a quella dello stage se Stage.align è impostato su StageAlign.TOP_LEFT e Stage.scaleMode è impostato su StageScaleMode.NO_SCALE.

Versione di Player: Flash Player 9 Aggiornamento 3.

Vedere anche

import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageDisplayState;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
// cover the stage with a green rectangle
var greenRect:Sprite = new Sprite();
greenRect.graphics.beginFill(0x00FF00);
greenRect.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(greenRect);
 
// create red square on stage, turn it into a button for going to full screen
var redSquare:Sprite = new Sprite();
redSquare.graphics.beginFill(0xFF0000);
redSquare.graphics.drawRect(0, 0, 300, 300);
redSquare.x = 50;
redSquare.y = 50;
redSquare.addEventListener(MouseEvent.CLICK, enterFullScreen);
redSquare.buttonMode = true;
addChild(redSquare);
 
function enterFullScreen(e:MouseEvent):void
{
    // we will go to full screen zoomed in on the red square
    var redSquare:Sprite = e.target as Sprite;
    var fullScreenRect:Rectangle = new Rectangle(redSquare.x, redSquare.y, redSquare.width, redSquare.height);
 
    // calculate aspect ratio of the red square
    var rectAspectRatio:Number = fullScreenRect.width / fullScreenRect.height;
 
    // calculate aspect ratio of the screen
    var screenAspectRatio:Number = stage.fullScreenWidth / stage.fullScreenHeight;
  
    // change the fullScreenRect so that it covers the entire screen, keeping it centered on the redSquare
    // try commenting out this section to see what happens if you do not fix the aspect ratio.
    if (rectAspectRatio > screenAspectRatio) {
         var newHeight:Number = fullScreenRect.width / screenAspectRatio;
         fullScreenRect.y -= ((newHeight - fullScreenRect.height) / 2);
        fullScreenRect.height = newHeight;
    } else if (rectAspectRatio < screenAspectRatio) {
        var newWidth:Number = fullScreenRect.height * screenAspectRatio;
        fullScreenRect.x -= ((newWidth - fullScreenRect.width) / 2);
        fullScreenRect.width = newWidth;
    }
 
    // go to full screen
    stage.fullScreenSourceRect = fullScreenRect;
    stage.displayState = StageDisplayState.FULL_SCREEN;
}

Imposta Flash Player affinché scali una zona specifica dello stage alla modalità a schermo intero. Se possibile, Flash Player scala utilizzando l'hardware, ovvero utilizzando la scheda grafica e video presente sul computer dell'utente e visualizza in genere il contenuto più velocemente rispetto a quando viene scalato il software.

Quando questa proprietà è impostata su un rettangolo valido e la proprietà displayState è impostata sulla modalità a schermo intero, Flash Player scala l'area specificata. La dimensione attuale dello stage in pixel in ActionScript non varia. Flash Player applica un limite minimo per la dimensione del rettangolo che contiene il messaggio standard "Premere Esc per uscire dalla modalità a schermo intero". Questo limite si aggira in genere intorno a 260 per 30 pixel, ma può variare in base al tipo di piattaforma e alla versione di Flash Player.

Questa proprietà può essere impostata solo se Flash Player non è in modalità a schermo intero. Per utilizzare correttamente questa proprietà, impostarla per prima, quindi impostare la proprietà displayState sulla modalità a schermo intero, come mostrato negli esempi di codice.

Per consentire di scalare, impostare la proprietà fullScreenSourceRect su un oggetto rettangolo:

  
  // valid, will enable hardware scaling
  stage.fullScreenSourceRect = new Rectangle(0,0,320,240); 
  

Per disattivare la possibilità di scalare, impostare fullScreenSourceRect=null in ActionScript 3.0 e undefined in ActionScript 2.0.

  stage.fullScreenSourceRect = null;
  

L'utente finale può anche selezionare la disattivazione della possibilità di scalare dalle impostazioni di visualizzazione di Flash Player (impostazione predefinita). Per ulteriori informazioni, consultare il sito www.adobe.com/go/display_settings_it.

Versione di Player: Flash Player 9 Aggiornamento 3.

Vedere anche

 
import flash.geom.*; 
{
  stage.fullScreenSourceRect = new Rectangle(0,0,320,240);
  stage.displayState = StageDisplayState.FULL_SCREEN;
}

package {
    import flash.display.Sprite;
    import flash.display.StageDisplayState;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.events.NetStatusEvent;
    import flash.events.AsyncErrorEvent;
    import flash.events.SecurityErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class Stage_fullScreenSourceRectExample2 extends Sprite {
        private var videoURL:String = "testVideo1.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var myVideo:Video;        
        private    var savedWidth:uint;
        private    var savedHeight:uint;
 
        public function Stage_fullScreenSourceRectExample2() {
    
            connection = new NetConnection();
             connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);    
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);

            loaderInfo.addEventListener(Event.INIT, createMouseListener);            
        }

        private function createMouseListener(event:Event):void {
            stage.addEventListener(MouseEvent.CLICK, toggleFullScreen);
        }        

        private function toggleFullScreen(event:MouseEvent):void {

            if(stage.displayState == StageDisplayState.NORMAL) {
                myVideo.width = myVideo.videoWidth;
                  myVideo.height = myVideo.videoHeight;

                try {
                    stage.fullScreenSourceRect = new Rectangle(myVideo.x, myVideo.y, 
                                                           myVideo.width, myVideo.height);
                     stage.displayState = StageDisplayState.FULL_SCREEN;

                 } catch (e:SecurityError) {
                     trace ("A security error occurred while switching to full screen: " + event);
                    myVideo.width = savedWidth;
                    myVideo.height = savedHeight;
                 }

            }else {
                myVideo.width = savedWidth;
                myVideo.height = savedHeight;
                stage.displayState = StageDisplayState.NORMAL;
            }
        }    

       private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace ("Unable to locate video: " + videoURL);
                    break;
            }
        }

       private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);     

             myVideo = new Video();
            myVideo.attachNetStream(stream);
            stream.play(videoURL);

            savedWidth = myVideo.width;
            savedHeight = myVideo.height;

            addChild(myVideo);
        }
       
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);    
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            
        }            
    }
}

Restituisce la larghezza del monitor che verrà utilizzata per la modalità a schermo intero, se tale stato viene attivato immediatamente. Se l'utente utilizza vari monitor, il monitor utilizzato è quello su cui si trova la maggior parte dello stage in un preciso momento.

Nota: se l'utente ha la possibilità di spostare il browser da un monitor a un altro tra il recupero del valore e il passaggio alla modalità a schermo intero, il valore potrebbe non essere corretto. Se si ripristina il valore in un gestore eventi che imposta Stage.displayState su StageDisplayState.FULL_SCREEN, il valore sarà corretto.

Questa è la larghezza in pixel del monitor, che corrisponde a quella dello stage se Stage.align è impostato su StageAlign.TOP_LEFT e Stage.scaleMode è impostato su StageScaleMode.NO_SCALE.

Versione di Player: Flash Player 9 Aggiornamento 3.

Vedere anche

import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageDisplayState;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
// cover the stage with a green rectangle
var greenRect:Sprite = new Sprite();
greenRect.graphics.beginFill(0x00FF00);
greenRect.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(greenRect);
 
// create red square on stage, turn it into a button for going to full screen
var redSquare:Sprite = new Sprite();
redSquare.graphics.beginFill(0xFF0000);
redSquare.graphics.drawRect(0, 0, 300, 300);
redSquare.x = 50;
redSquare.y = 50;
redSquare.addEventListener(MouseEvent.CLICK, enterFullScreen);
redSquare.buttonMode = true;
addChild(redSquare);
 
function enterFullScreen(e:MouseEvent):void
{
    // we will go to full screen zoomed in on the red square
    var redSquare:Sprite = e.target as Sprite;
    var fullScreenRect:Rectangle = new Rectangle(redSquare.x, redSquare.y, redSquare.width, redSquare.height);
 
    // calculate aspect ratio of the red square
    var rectAspectRatio:Number = fullScreenRect.width / fullScreenRect.height;
 
    // calculate aspect ratio of the screen
    var screenAspectRatio:Number = stage.fullScreenWidth / stage.fullScreenHeight;
  
    // change the fullScreenRect so that it covers the entire screen, keeping it centered on the redSquare
    // try commenting out this section to see what happens if you do not fix the aspect ratio.
    if (rectAspectRatio > screenAspectRatio) {
         var newHeight:Number = fullScreenRect.width / screenAspectRatio;
         fullScreenRect.y -= ((newHeight - fullScreenRect.height) / 2);
        fullScreenRect.height = newHeight;
    } else if (rectAspectRatio < screenAspectRatio) {
        var newWidth:Number = fullScreenRect.height * screenAspectRatio;
        fullScreenRect.x -= ((newWidth - fullScreenRect.width) / 2);
        fullScreenRect.width = newWidth;
    }
 
    // go to full screen
    stage.fullScreenSourceRect = fullScreenRect;
    stage.displayState = StageDisplayState.FULL_SCREEN;
}

Indica l'altezza dell'oggetto di visualizzazione espressa in pixel. L'altezza viene calcolata in base ai limiti del contenuto dell'oggetto di visualizzazione. Quando si imposta la proprietà height, la proprietà scaleY viene impostata di conseguenza, come illustrato nel codice seguente:

 var rect:Shape = new Shape();
 rect.graphics.beginFill(0xFF0000);
 rect.graphics.drawRect(0, 0, 100, 100);
 trace(rect.scaleY) // 1;
 rect.height = 200;
 trace(rect.scaleY) // 2;

A eccezione degli oggetti TextField e Video, un oggetto di visualizzazione senza contenuto (quale uno sprite vuoto) presenta un'altezza pari a 0, anche se si tenta di impostare height su un valore differente.

Determina se gli elementi secondari dell'oggetto sono abilitati per il mouse o meno. Se un oggetto è abilitato per il mouse, l'utente può interagire con esso mediante il mouse. Il valore predefinito è true.

Questa proprietà è utile quando si crea un pulsante con un'istanza della classe Sprite (anziché utilizzare la classe SimpleButton). Quando si usa un'istanza Sprite per creare un pulsante, è possibile scegliere di decorare il pulsante utilizzando il metodo addChild() per aggiungere ulteriori istanze Sprite. Questo processo può produrre un comportamento imprevisto degli eventi del mouse perché le istanze Sprite aggiunte come elementi secondari possono diventare l'oggetto target di un evento mouse invece dell'istanza principale. Per fare sì che solo l'istanza principale possa essere l'oggetto target degli eventi del mouse, è possibile impostare la proprietà mouseChildren dell'istanza principale su false.

Nessun evento viene inviato impostando questa proprietà. È necessario utilizzare il metodo addEventListener() per creare la funzionalità interattiva.

Restituisce il numero di elementi secondari di questo oggetto.

Un valore della classe StageQuality che specifica la qualità di rendering utilizzata da Flash Player. I valori validi sono i seguenti:

• StageQuality.LOW — Qualità di rendering bassa. Le immagini non vengono sottoposte ad aliasing e le bitmap non vengono smussate.
• StageQuality.MEDIUM — Qualità di rendering media. Le immagini vengono sottoposte ad aliasing utilizzando una griglia di 2 x 2 pixel, ma le bitmap non vengono smussate. Si tratta di un'impostazione adatta per i filmati che non contengono testo.
• StageQuality.HIGH — Qualità di rendering alta. Le immagini vengono sottoposte ad aliasing utilizzando una griglia di 4 x 4 pixel e le bitmap vengono smussate se il filmato è statico. È l'impostazione predefinita utilizzata da Flash per la qualità di rendering.
• StageQuality.BEST — Qualità di rendering molto alta. Le immagini vengono sottoposte ad aliasing utilizzando una griglia di 4 x 4 pixel e le bitmap vengono sempre smussate.

Vedere anche

Un valore della classe StageScaleMode che specifica la modalità scala da utilizzare. I valori validi sono i seguenti:

• StageScaleMode.EXACT_FIT — Rende visibile l'intera applicazione Flash nell'area specificata senza distorsione, mantenendone le proporzioni originali. Ai due lati dell'applicazione possono apparire dei bordi.
• StageScaleMode.SHOW_ALL — Rende visibile l'intera applicazione Flash nell'area specificata senza cercare di mantenere le proporzioni originali. Potrebbero verificarsi delle distorsioni.
• StageScaleMode.NO_BORDER — L'intera applicazione Flash riempie l'area specificata, senza distorsione ma con un eventuale ritaglio, mantenendo le proporzioni originali dell'applicazione.
• StageScaleMode.NO_SCALE — Rende fissa l'intera applicazione Flash, in modo che rimanga invariata anche se cambiano le dimensioni della finestra del lettore. Possono verificarsi dei ritagli se la finestra del lettore è più piccola del contenuto.

Vedere anche

Specifica se mostrare o nascondere le voci predefinite del menu di scelta rapida di Flash Player.

Se la proprietà showDefaultContextMenu è impostata su true (valore predefinito), vengono visualizzate tutte le voci del menu di scelta rapida. Se invece showDefaultContextMenu è impostata su false, vengono visualizzate solo le voci Impostazioni e Informazioni su Flash Player.

Specifica se viene visualizzato o meno un bordo luminoso intorno agli oggetti che vengono attivati.

L'altezza corrente dello stage, in pixel.

Quando il valore della proprietà Stage.scaleMode è impostato su StageScaleMode.NO_SCALE, la proprietà stageHeight rappresenta l'altezza della finestra di Flash Player. Quando il valore di Stage.scaleMode non è impostato su StageScaleMode.NO_SCALE, stageHeight rappresenta l'altezza del file SWF. Questa proprietà non può essere impostata.

Vedere anche

Specifica la larghezza corrente dello stage, in pixel.

Quando il valore della proprietà scaleMode è impostato su StageScaleMode.NO_SCALE, la proprietà stageWidth rappresenta la larghezza di Flash Player. Di conseguenza, il valore di stageWidth cambia man mano che si ridimensiona la finestra di Flash Player. Quando il valore della proprietà scaleMode non è impostato su StageScaleMode.NO_SCALE, la proprietà stageWidth rappresenta la larghezza del file SWF così come è stata impostata nella finestra di dialogo Proprietà documento al momento della creazione. Di conseguenza, il valore di stageWidth rimane costante quando si ridimensiona la finestra di Flash Player. Questa proprietà non può essere impostata.

Vedere anche

Determina se gli elementi secondari dell'oggetto sono abilitati per la tabulazione. Abilita o disabilita la tabulazione per gli elementi secondari dell'oggetto. Il valore predefinito è true.

Restituisce un oggetto TextSnapshot per questa istanza DisplayObjectContainer.

Indica la larghezza dell'oggetto di visualizzazione espressa in pixel. La larghezza viene calcolata in base ai limiti del contenuto dell'oggetto di visualizzazione. Quando si imposta la proprietà width, la proprietà scaleX viene impostata di conseguenza, come illustrato nel codice seguente:

 var rect:Shape = new Shape();
 rect.graphics.beginFill(0xFF0000);
 rect.graphics.drawRect(0, 0, 100, 100);
 trace(rect.scaleX) // 1;
 rect.width = 200;
 trace(rect.scaleX) // 2;

A eccezione degli oggetti TextField e Video, un oggetto di visualizzazione senza contenuto (quale uno sprite vuoto) presenta una larghezza pari a 0, anche se si tenta di impostare width su un valore differente.

Se si aggiunge un oggetto secondario che ha già un contenitore di oggetto di visualizzazione diverso come elemento principale, l'oggetto viene rimosso dall'elenco degli elementi secondari dell'altro contenitore.

Parametri

Vedere anche

L'esempio seguente mostra tre oggetti di visualizzazione (a, b e c) rispettivamente nelle posizioni di indice 0, 2 e 1:

Se si aggiunge un oggetto secondario che ha già un contenitore di oggetto di visualizzazione diverso come elemento principale, l'oggetto viene rimosso dall'elenco degli elementi secondari dell'altro contenitore.

Parametri

Vedere anche

Una volta registrato un listener di eventi, non è possibile modificarne la priorità mediante chiamate aggiuntive a addEventListener(). Per modificare la priorità di un listener è necessario chiamare innanzitutto removeListener(). In seguito è possibile registrare nuovamente il listener con il nuovo livello di priorità.

Tenere presente che, dopo la registrazione del listener, le successive chiamate a addEventListener() con un valore type o useCapture diverso determinano la creazione di un'altra registrazione per il listener. Ad esempio, se un listener viene registrato inizialmente con useCapture impostato su true, l'intercettazione avviene solo durante la fase di cattura. Se si chiama di nuovo addEventListener() utilizzando lo stesso oggetto listener ma impostando useCapture su false, si ottengono due listener separati: uno rileva gli eventi durante la fase di cattura e l'altro durante la fasi target e di bubbling.

Non è possibile registrare un listener di eventi solo per la fase target o per la fase di bubbling. Queste fasi vengono accoppiate durante la registrazione perché la propagazione è valida solo per gli antenati del nodo target.

Se il listener di eventi non è più necessario, rimuoverlo con una chiamata a removeEventListener() per evitare problemi di memoria. Gli oggetti con listener di eventi registrati non vengono eliminati automaticamente dalla memoria perché il garbage collector non rimuove gli oggetti ancora dotati di riferimenti.

Se si copia un'istanza EventDispatcher, i listener di eventi associati all'istanza non vengono copiati (se un nodo appena creato necessita di un listener di eventi, è necessario associarlo dopo avere creato il nodo). Se invece si sposta un'istanza EventDispatcher, insieme a questa vengono spostati anche i listener di eventi associati.

Se il listener di eventi viene registrato su un nodo mentre questo sta elaborando un evento, il listener di eventi non viene attivato durante la fase corrente ma può esserlo durante una fase successiva del flusso di eventi, ad esempio la fase di bubbling.

Se un listener di eventi viene rimosso da un nodo mentre questo sta elaborando un evento, il listener continua a essere attivato dalle azioni in corso. Dopo che è stato rimosso, il listener di eventi non viene più richiamato (a meno che non venga registrato nuovamente per elaborazioni future).

Parametri

Vedere anche

Parametri

La differenza tra hasEventListener() e willTrigger() consiste nel fatto che hasEventListener() esamina solo l'oggetto a cui appartiene, mentre willTrigger() esamina tutto il flusso di eventi relativo all'evento specificato dal parametro type.

Quando hasEventListener() viene chiamato da un oggetto LoaderInfo vengono considerati solo i listener a cui il chiamante può accedere.

Parametri

Una chiamata al metodo invalidate() segnala a Flash Player di mettere un avviso per gli oggetti di visualizzazione alla prima opportunità di eseguire il rendering dell'elenco di visualizzazione (ad esempio, quando l'indicatore di riproduzione si sposta su un nuovo fotogramma). Dopo la chiamata al metodo invalidate(), quando viene eseguito il nuovo rendering dell'elenco di visualizzazione, Flash Player invia un evento render a ciascun oggetto di visualizzazione registrato per il rilevamento dell'evento render. È necessario chiamare il metodo invalidate() ogni volta che si vuole inviare un evento render mediante Flash Player.

L'evento render offre l'opportunità di modificare l'elenco di visualizzazione immediatamente prima che ne venga eseguito il rendering. In questo modo è possibile ritardare l'aggiornamento dell'elenco di visualizzazione fino all'ultima opportunità disponibile, ottenendo così un incremento delle prestazioni grazie all'eliminazione degli aggiornamenti dello schermo non necessari.

L'evento render viene inviato solo agli oggetti di visualizzazione che si trovano nello stesso dominio di sicurezza del codice che chiama il metodo stage.invalidate() oppure a quelli appartenenti a un dominio di sicurezza che è stato autorizzato tramite il metodo Security.allowDomain().

Vedere anche

Determina se la proprietà Stage.focus restituisce null per motivi di sicurezza. In altre parole, isFocusInaccessible restituisce true se l'oggetto di visualizzazione appartiene a una funzione di sicurezza sandbox a cui il file SWF non ha accesso.

Il garbage collector è il processo mediante il quale Flash Player rialloca lo spazio di memoria inutilizzato. Quando una variabile o un oggetto non sono più associati a un riferimento attivo o memorizzati da qualche parte, il garbage collector li rimuove e libera lo spazio di memoria che occupavano, se non risultano altri riferimenti ad essi.

Parametri

Quando si usa il metodo setChildIndex() e si specifica una posizione di indice già occupata, l'elemento secondario che si trova in quella posizione e tutti gli oggetti delle posizioni superiori dell'elenco degli elementi secondari vengono spostati in alto di una posizione. Ad esempio, se il contenitore di oggetto di visualizzazione dell'esempio precedente si chiama container, è possibile scambiare la posizione degli oggetti di visualizzazione con etichetta a e b chiamando il codice seguente:

container.setChildIndex(container.getChildAt(1), 0);

Questo codice determina la seguente disposizione degli oggetti:

Parametri

Parametri

La differenza tra il metodo hasEventListener() e il metodo willTrigger() consiste nel fatto che hasEventListener() esamina solo l'oggetto a cui appartiene, mentre willTrigger() esamina tutto il flusso di eventi relativo all'evento specificato dal parametro type.

Quando willTrigger() viene chiamato da un oggetto LoaderInfo vengono considerati solo i listener a cui il chiamante può accedere.

Parametri

Inviato da Flash Player quando l'oggetto Stage entra o esce dalla modalità a schermo intero. La modalità a schermo intero può essere modificata mediante ActionScript, tramite una scelta rapida selezionata dall'utente oppure se la finestra a schermo intero perde lo stato di attivazione.

Questo evento ha le seguenti proprietà:

Inviato dall'oggetto Stage quando il puntatore del mouse esce dall'area della finestra di Flash Player.

Questo evento ha le seguenti proprietà:

Inviato quando la proprietà scaleMode dell'oggetto Stage viene impostata su StageScaleMode.NO_SCALE e il file SWF viene ridimensionato.

Questo evento ha le seguenti proprietà:

1. La funzione di costruzione della classe dapprima imposta l'applicazione Flash da regolare, a prescindere dalle dimensioni della finestra di Flash Player, quindi aggiunge due listener di eventi con i metodi activateHandler() e resizeHandler().
2. Il metodo activateHandler() viene eseguito ogni volta che viene premuto il pulsante sinistro del mouse.
3. Il metodo resizeHandler() viene eseguito quando lo stage viene ridimensionato.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.Event;

    public class StageExample extends Sprite {

        public function StageExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            stage.addEventListener(Event.ACTIVATE, activateHandler);
            stage.addEventListener(Event.RESIZE, resizeHandler);
        }

        private function activateHandler(event:Event):void {
            trace("activateHandler: " + event);
        }

        private function resizeHandler(event:Event):void {
            trace("resizeHandler: " + event);
            trace("stageWidth: " + stage.stageWidth + " stageHeight: " + stage.stageHeight);
        }
    }
}