Contiene l'oggetto di visualizzazione principale del file SWF o del file di immagine (JPG, PNG o GIF) caricato mediante il metodo load() o loadBytes().

Vedere anche

Restituisce un oggetto LoaderInfo corrispondente all'oggetto che viene caricato. Gli oggetti LoaderInfo sono condivisi dall'oggetto Loader e dall'oggetto del contenuto caricato. L'oggetto LoaderInfo fornisce informazioni sullo stato del caricamento e statistiche sul file caricato.

Gli eventi correlati con il caricamento vengono inviati dall'oggetto LoaderInfo a cui fa riferimento la proprietà contentLoaderInfo dell'oggetto Loader. La proprietà contentLoaderInfo viene impostata su un oggetto LoaderInfo valido, anche prima che il contenuto venga caricato, per consentire di aggiungere dei listener di eventi all'oggetto prima del caricamento.

Vedere anche

Crea un oggetto Loader che può essere utilizzato per caricare file, ad esempio SWF, JPEG, GIF o PNG. Chiamare il metodo load() per caricare la risorsa come elemento secondario dell'istanza Loader. Quindi è possibile aggiungere l'oggetto Loader all'elenco di visualizzazione (ad esempio utilizzando il metodo addChild() di un'istanza DisplayObjectContainer). La risorsa appare sullo stage mentre viene caricata.

È anche possibile utilizzare un'istanza Loader "fuori elenco", ovvero senza aggiungerla a un contenitore di oggetto di visualizzazione incluso nell'elenco di visualizzazione. In questa modalità, l'istanza Loader potrebbe essere utilizzata per caricare un file SWF che contiene moduli aggiuntivi di un'applicazione.

Per rilevare la fine del caricamento del file SWF, è possibile utilizzare gli eventi dell'oggetto LoaderInfo associato alla proprietà contentLoaderInfo dell'oggetto Loader. A quel punto, è possibile eseguire il codice del file SWF del modulo per inizializzare e avviare il modulo. Nella modalità "fuori elenco", un'istanza Loader potrebbe essere utilizzata anche per caricare un file SWF che contiene componenti o risorse multimediali. Anche in questo caso, è possibile utilizzare le notifiche di evento dell'oggetto LoaderInfo per rilevare la fine del caricamento dei componenti. A quel punto l'applicazione può iniziare a utilizzare i componenti e le risorse multimediali della libreria del file SWF creando istanze delle classi ActionScript 3.0 che rappresentano tali componenti e risorse.

Per determinare lo stato di un oggetto Loader, monitorare gli eventi seguenti che l'oggetto LoaderInfo ha associato alla proprietà contentLoaderInfo dell'oggetto Loader:

• L'evento open viene inviato quando inizia il caricamento.
• L'evento ioError o securityError viene inviato se il file non può essere caricato o se si verifica un errore durante il caricamento.
• L'evento progress viene inviato continuamente durante il caricamento del file.
• L'evento complete viene inviato al termine dello scaricamento di un file, ma prima che siano disponibili i metodi e le proprietà del clip filmato caricato.
• L'evento init viene inviato dopo che le proprietà e i metodi del file SWF caricato diventano accessibili, in modo da consentire la modifica del file SWF caricato. Questo evento viene inviato prima del gestore complete. Nei file SWF di streaming, l'evento init può essere inviato con largo anticipo rispetto all'evento complete. Nella maggior parte delle situazioni, utilizzare il gestore init.

Vedere anche

Annulla un'operazione del metodo load() attualmente in corso per l'istanza Loader.

Vedere anche

Carica un file SWF, JPEG, JPEG progressivo, GIF non animato o PNG in un oggetto che è un elemento secondario dell'oggetto Loader. Se si carica un file GIF animato, viene visualizzato solo il primo fotogramma. Poiché l'oggetto Loader può contenere un unico elemento secondario, una successiva richiesta load() interrompe la richiesta precedente, se è ancora in corso, e avvia un nuovo caricamento.

Un file SWF o un'immagine caricata in un oggetto Loader filmato eredita le proprietà di posizione, rotazione e scala degli oggetti di visualizzazione principali dell'oggetto Loader.

Utilizzare il metodo unload() per rimuovere i filmati o le immagini caricate con questo metodo o per annullare un'operazione di caricamento in corso.

Quando si usa il metodo load(), considerare il modello di sicurezza di Flash Player:

• È possibile caricare contenuto da qualunque origine accessibile.
• Il caricamento non è consentito se il file SWF che effettua la chiamata si trova in una sandbox di rete e il file da caricare è locale.
• Se il contenuto caricato è un file SWF, non può essere utilizzato per lo scambio di script da un altro file SWF file appartenente a una sicurezza sandbox diversa, a meno che non lo scambio non sia stato concordato mediante una chiamata al metodo Security.allowDomain() nel file di contenuto caricato.
• I file SWF scritti in ActionScript 1.0 o 2.0, che vengono caricati come oggetti AVM1Movie, non possono eseguire lo scambio di script con file scritti ActionScript 3.0, che vengono caricati come oggetti Sprite o MovieClip. È possibile utilizzare la classe LocalConnection per consentire la comunicazione tra file di questo tipo.
• Se il contenuto caricato è un'immagine, un file SWF esterno alla sicurezza sandbox non può accedere ai dati dell'immagine, a meno che il dominio del file SWF non sia stato incluso in un file di criteri dei domini nel dominio di origine dell'immagine.
• I clip filmato nella sandbox locale con file system non possono scambiare script con clip filmato nella sandbox locale con rete (e viceversa).
• È possibile impedire che un file SWF utilizzi questo metodo impostando il parametro allowNetworking dei tag object ed embed nella pagina HTML che include il contenuto SWF.

Per ulteriori informazioni, vedere i seguenti riferimenti:

• Il capitolo Sicurezza di Flash Player nel volume Programmazione in ActionScript 3.0 e i commenti più recenti in LiveDocs
• Il White paper sulla sicurezza per Flash Player 9

Parametri

Vedere anche

Carica dai dati binari memorizzati nell'oggetto ByteArray.

Parametri

Vedere anche

Rimuove un elemento secondario di questo oggetto Loader caricato mediante il metodo load(). La proprietà dell'oggetto LoaderInfo associato viene reimpostata su null. L'elemento secondario non viene necessariamente eliminato perché altri oggetti potrebbero farvi riferimento, tuttavia cessa di essere un elemento secondario dell'oggetto Loader.

È buona norma, prima di scaricare un file SWF secondario, chiudere esplicitamente i flussi degli oggetti del file, ad esempio gli oggetti LocalConnection, NetConnection, NetStream e Sound. In caso contrario, la riproduzione dell'audio del file SWF secondario potrebbe continuare anche se il file è stato scaricato. Per chiudere i flussi del file, aggiungere un listener di eventi all'elemento secondario che rileva l'evento unload. Quando l'oggetto principale chiama Loader.unload(), l'evento unload viene inviato all'elemento secondario. Il codice di esempio seguente produce il risultato descritto:

function closeAllStreams(evt:Event) { 
    myNetStream.close();
    mySound.close();
    myNetConnection.close();
    myLocalConnection.close();
}

myMovieClip.loaderInfo.addEventListener(Event.UNLOAD, closeAllStreams);

Vedere anche

1. Viene creata una proprietà url, che corrisponde alla posizione e al nome del file di immagine.
2. Nella funzione di costruzione LoaderExample viene creato un nuovo oggetto Loader di nome loader, che viene successivamente passato al metodo configureListeners(), descritto al punto 3.
3. La funzione di costruzione crea una nuova istanza di un oggetto URLRequest, request, passando url in modo che il nome e la posizione del file siano noti.
4. L'oggetto request viene quindi passato al metodo load() dell'oggetto loader, che carica l'immagine nell'elenco di visualizzazione.
5. Un listener di eventi clickHandler viene registrato per l'evento click del loader. In seguito a un clic del mouse, l'immagine caricata viene scaricata.
6. Il metodo configureListeners() aggiunge sette listener di eventi utilizzando i metodi seguenti:
   • Il metodo completeHandler() viene eseguito al termine del caricamento dell'immagine.
   • Il metodo httpStatusHandler() viene eseguito se l'immagine non viene caricata a livello locale e solo se la richiesta di rete viene resa disponibile e Flash Player è in grado di rilevarla.
   • Il metodo initHandler() viene eseguito prima del metodo completeHandler() e dopo il metodo progressHandler(). In genere, l'evento init risulta più utile quando si caricano dei file SWF.
   • Il metodo ioErrorHandler() viene eseguito se il file di immagine non è disponibile o accessibile.
   • Il metodo openHandler() viene eseguito alla prima apertura del file di immagine.
   • Il metodo progressHandler() viene eseguito quando inizia il caricamento del file di immagine e successivamente quando il caricamento è terminato.
   • Il metodo unLoadHandler() viene eseguito quando l'immagine viene scaricata utilizzando il metodo unload() quando l'utente fa clic sull'immagine.

Tenere presente quanto segue:

• Questo esempio richiede che un file di nome Image.gif venga aggiunto alla stessa directory del file SWF compilato. Utilizzare un'immagine con un'area che non ecceda le dimensioni del file SWF principale.
• Anche se questo esempio utilizza tutti gli eventi disponibili per l'oggetto LoaderInfo, nella maggior parte delle situazioni è richiesto solo un sottoinsieme. In particolare, quando si carica solo un file di immagine, l'evento complete (e probabilmente l'errore ioError) è sufficiente quando si carica un'immagine locale.

package {
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderExample() {
            var loader:Loader = new Loader();
            configureListeners(loader.contentLoaderInfo);
            loader.addEventListener(MouseEvent.CLICK, clickHandler);

            var request:URLRequest = new URLRequest(url);
            loader.load(request);

            addChild(loader);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(Event.INIT, initHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(Event.UNLOAD, unLoadHandler);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function initHandler(event:Event):void {
            trace("initHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler: bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function unLoadHandler(event:Event):void {
            trace("unLoadHandler: " + event);
        }

        private function clickHandler(event:MouseEvent):void {
            trace("clickHandler: " + event);
            var loader:Loader = Loader(event.target);
            loader.unload();
        }
    }
}