Ottiene o imposta un valore che indica se il componente può accettare l'interazione dell'utente. Il valore true indica che il componente può accettare l'interazione dell'utente, mentre il valore false indica che non può.

Se si imposta la proprietà enabled su false, il contenitore è visualizzato in grigio e l'input dell'utente viene bloccato (ad eccezione dei componenti Label e ProgressBar).

Il valore predefinito è true.

Ottiene o imposta un valore booleano che indica se il componente può ricevere l'attivazione quando un utente fa clic su di esso. Il valore true indica che il componente può ricevere l'attivazione, mentre il valore false indica che non può.

Se questa proprietà è false, viene attivato il primo elemento principale la cui proprietà mouseFocusEnabled è impostata su true.

Il valore predefinito è true.

Vedere anche

Ottiene o imposta il FocusManager che controlla l'attivazione di questo componente e dei suoi pari. Ogni componente a comparsa conserva il proprio ciclo di attivazione e la propria istanza FocusManager. Utilizzare questa proprietà per accedere al FocusManager corretto per il componente.

Ottiene o imposta l'altezza del componente in pixel.

Se si imposta questa proprietà, viene inviato un evento resize. Vedere l'evento resize per maggiori informazioni su quando questo evento viene inviato.

Se la proprietà scaleY del componente non corrisponde a 1.0, l'altezza del componente che viene ottenuta dalle sue coordinate interne non corrisponderà al height width delle coordinate principali. Ad esempio, un componente che presenta un'altezza di 100 pixel e un valore scaleY pari a 2, presenterà un valore di 100 pixel nell'elemento principale, ma internamente memorizzerà un valore che indica che la sua altezza è di 50 pixel.

Ottiene o imposta un valore che indica se il componente può ricevere l'attivazione quando un utente fa clic su di esso. Il valore true indica che il componente può ricevere l'attivazione, mentre il valore false indica che non può.

Se questa proprietà è false, viene attivato il primo elemento principale la cui proprietà mouseFocusEnabled è impostata su true.

Il valore predefinito è true.

Vedere anche

Moltiplica la larghezza corrente del componente per un fattore di scala.

Vedere anche

Moltiplica l'altezza corrente del componente per un fattore di scala.

Vedere anche

Numero di versione dei componenti.

import fl.controls.CheckBox;

var myCheckBox:CheckBox = new CheckBox();
trace(myCheckBox.version);

Ottiene o imposta un valore che indica se l'istanza corrente del componente è visibile. Il valore true indica che il componente corrente è visibile, mentre il valore false indica che non lo è.

Quando questa proprietà viene impostata su true, l'oggetto invia un evento show. Quando questa proprietà viene impostata su false, l'oggetto invia un evento hide. In entrambi i casi, gli elementi secondari dell'oggetto non generano un evento show o hide, a meno che l'oggetto non scriva specificamente un'implementazione preposta a farlo.

Il valore predefinito è true.

Vedere anche

Ottiene o imposta la larghezza del componente in pixel.

Se si imposta questa proprietà, viene inviato un evento resize. Vedere l'evento resize per maggiori informazioni su quando questo evento viene inviato.

Se la proprietà scaleX del componente non corrisponde a 1.0, la larghezza del componente che viene ottenuta dalle sue coordinate interne non corrisponderà al valore width delle coordinate principali. Ad esempio, un componente che presenta una larghezza di 100 pixel e un valore scaleX pari a 2, presenterà un valore di 100 pixel nell'elemento principale, ma internamente memorizzerà un valore che indica che la sua larghezza è di 50 pixel.

Vedere anche

Ottiene o imposta la coordinata x che rappresenta la posizione del componente sull'asse x nel contenitore principale. Questo valore è espresso in pixel e viene calcolato a partire da sinistra.

Se si imposta questa proprietà, viene inviato l'evento ComponentEvent.MOVE.

Il valore predefinito è 0.

Vedere anche

Ottiene o imposta la coordinata y che rappresenta la posizione del componente sull'asse y nel contenitore principale. Questo valore è espresso in pixel e viene calcolato a partire dall'alto.

Se si imposta questa proprietà, viene inviato l'evento move.

Vedere anche

Crea una nuova istanza del componente UIComponent.

Elimina una proprietà di stile dall'istanza del componente.

Questa azione non comporta necessariamente che il metodo getStyle() restituisca un valore undefined.

Parametri

Vedere anche

Mostra o nasconde l'indicatore di attivazione sul componente.

La classe UIComponent implementa questo metodo mediante la creazione e il posizionamento di un'istanza della classe specificata dallo stile focusSkin.

Parametri

Avvia un'azione di disegno immediata, senza invalidare tutto come fa invalidateNow.

Recupera l'oggetto che è l'elemento attivo corrente.

Si noti che questo metodo non restituisce necessariamente il componente attivo. Può restituire il sottocomponente interno del componente attivo. Per ottenere il componente attivo, utilizzare la proprietà focusManager.focus.

Recupera una proprietà style impostata nella catena di ricerca dello stile del componente.

Il tipo restituito da questo metodo varia in base alla proprietà style recuperata dal metodo. La gamma di tipi possibili includono Boolean; String; Number; int; un uint per un colore RGB; una classe per uno skin; o qualsiasi tipo di oggetto.

Se si chiama questo metodo per recuperare una proprietà style particolare, si tratterà di una proprietà di tipo sconosciuto archiviabile in una variabile dello stesso tipo. L'inserimento di tipi non è necessario. Al contrario, può essere utile una semplice istruzione di assegnazione come la seguente:

var backgroundColor:uint = getStyle("backgroundColor");

Se la proprietà style non viene impostata nella catena di ricerca dello stile, questo metodo restituisce un valore undefined. undefined è un valore speciale diverso da false, "", NaN, 0 o null. Nessun valore di stile valido può essere undefined. Il metodo statico StyleManager.isValidStyleValue() può essere utilizzato per verificare se è stato impostato un valore.

Parametri

Vedere anche

import fl.controls.ComboBox;
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;

var myComboBox:ComboBox = new ComboBox();
myComboBox.setStyle("textPadding", 6);
myComboBox.setStyle("disabledAlpha", 0.8);

var styleObject:Object = ComboBox.getStyleDefinition();
var styleDP:DataProvider = new DataProvider();
var styleName:String;
var styleDefaultValue:String;
var styleCurrentValue:String;

for (styleName in styleObject) {
    styleDefaultValue = String(styleObject[styleName]);
    styleCurrentValue = String(myComboBox.getStyle(styleName));
    styleDP.addItem({name:styleName, defaultValue:styleDefaultValue, currentValue:styleCurrentValue});
}
styleDP.sortOn("name", Array.CASEINSENSITIVE);

var c1:DataGridColumn = new DataGridColumn("name");
c1.headerText = "Style name:";
var c2:DataGridColumn = new DataGridColumn("defaultValue");
c2.headerText = "Default style value:";
var c3:DataGridColumn = new DataGridColumn("currentValue");
c3.headerText = "Current style value:"

var styleDataGrid:DataGrid = new DataGrid();
styleDataGrid.addColumn(c1); // name
styleDataGrid.addColumn(c2); // defaultValue
styleDataGrid.addColumn(c3); // currentValue
styleDataGrid.dataProvider = styleDP;
styleDataGrid.setSize(stage.stageWidth - 20, stage.stageHeight - 20);
styleDataGrid.move(10, 10);
addChild(styleDataGrid);

Recupera la mappa di stile predefinita del componente corrente. La mappa di stile contiene il tipo appropriato per il componente, in base allo stile utilizzato dal componente. Ad esempio, lo stile disabledTextFormat contiene un valore null o un oggetto TextFormat. È possibile utilizzare questi stili e chiamare setStyle() sul componente corrente. Il codice seguente consente di ignorare lo stile disabledTextFormat predefinito sul componente specificato:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Vedere anche

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Contrassegna una proprietà come non valida e ridisegna il componente sul fotogramma successivo salvo diversa indicazione.

Parametri

Unisce gli stili di più classi in un unico oggetto. Se uno stile viene definito in più oggetti, viene utilizzata la prima occorrenza trovata.

Parametri

Sposta il componente in una posizione specificata all'interno del relativo elemento principale. Questa operazione ha lo stesso effetto di una modifica della posizione del componente mediante l'impostazione delle sue proprietà x e y. Se si chiama questo metodo viene attivato l'invio dell'evento ComponentEvent.MOVE.

Per ignorare il metodo updateDisplayList() in un componente personalizzato, utilizzare il metodo move() invece di impostare le proprietà x e y. Questo perché una chiamata al metodo move() provoca l'invio immediato di un evento move al termine dell'operazione di spostamento. Invece, se si modifica la posizione del componente impostando le proprietà x e y, l'oggetto event viene inviato al successivo aggiornamento dello schermo.

Parametri

Vedere anche

Imposta questo componente come elemento attivo. Il componente può a propria volta passare l'attivazione a un sottocomponente.

Nota: solo i componenti TextInput e TextArea mostrano un indicatore di attivazione quando questo metodo imposta l'attivazione. Tutti i componenti riportano un indicatore di attivazione quando un utente utilizza il tasto Tab per spostarsi sul componente.

Imposta il componente sulla larghezza e sull'altezza specificate.

Parametri

Imposta una proprietà di stile per l'istanza del componente. Questo stile può ignorare uno stile che è stato precedentemente impostato a livello globale.

La chiamata a questo metodo può ridurre le prestazioni. Utilizzarlo solo se strettamente necessario.

Parametri

Vedere anche

import fl.controls.Button;

var myFormat:TextFormat = new TextFormat();
myFormat.font = "Georgia";

var b:Button = new Button();
b.label = "Hello World";
b.setStyle("textFormat", myFormat);
addChild(b);

import fl.controls.Button;

var flashIcon:Loader = new Loader();
flashIcon.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
flashIcon.load(new URLRequest("http://www.helpexamples.com/flash/images/logo.png"));

var myButton:Button = new Button();
myButton.label = "Flash";
myButton.move(10, 10);
addChild(myButton);

function completeHandler(event:Event):void {
    flashIcon.width = 16;
    flashIcon.height = 16;
    myButton.setStyle("icon", flashIcon);
}

Convalida e aggiorna le proprietà e il layout di questo oggetto e lo ridisegna, se necessario.

Le proprietà che richiedono una grande quantità di calcoli di solito non vengono elaborate fino a quando non è terminata l'esecuzione dello script. Questo perché l'impostazione di una proprietà potrebbe richiedere l'elaborazione di altre proprietà. Ad esempio, l'impostazione della proprietà width potrebbe richiedere che vengano ricalcolate anche le larghezza degli elementi principali o secondari dell'oggetto. E se lo script ricalcola la larghezza dell'oggetto più di una volta, potrebbe essere necessario ricalcolare anche queste proprietà interdipendenti. Utilizzare questo metodo per ignorare manualmente tale comportamento.

Inviato dopo che il componente è passato da visibile a invisibile.

Questo evento ha le seguenti proprietà:

import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Vedere anche

Inviato dopo che il componente viene spostato.

Questo evento ha le seguenti proprietà:

import fl.controls.Slider;
import fl.containers.UILoader;
import fl.events.ComponentEvent;
import fl.events.SliderEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
myUILoader.move(10, 20); 
myUILoader.addEventListener(ComponentEvent.MOVE, moveHandler);
addChild(myUILoader);

var mySlider:Slider = new Slider();
mySlider.liveDragging = true;
mySlider.minimum = myUILoader.x;
mySlider.maximum = myUILoader.x + 200;
mySlider.snapInterval = 1;
mySlider.tickInterval = 10;
mySlider.move(10, 10);
mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
addChild(mySlider);

function changeHandler(event:SliderEvent):void {
    myUILoader.x = event.value;
}

function moveHandler(event:ComponentEvent):void {
    trace("[move] x:" + event.currentTarget.x + ", y:" + event.currentTarget.y);
}

Inviato dopo che il componente viene ridimensionato.

Questo evento ha le seguenti proprietà:

import fl.containers.UILoader;
import fl.events.ComponentEvent;

var myUILoader:UILoader = new UILoader();
myUILoader.scaleContent = false;
myUILoader.addEventListener(ComponentEvent.RESIZE, resizeHandler);
myUILoader.source = "http://www.helpexamples.com/flash/images/image3.jpg";
addChild(myUILoader);

function resizeHandler(event:ComponentEvent):void {
    var myImg:UILoader = event.currentTarget as UILoader;
    var newX:uint = (stage.stageWidth - myImg.width) / 2;
    var newY:uint = (stage.stageHeight - myImg.height) / 2;
    myImg.move(newX, newY);
}

Inviato dopo che il componente è passato da invisibile a visibile.

Questo evento ha le seguenti proprietà:

import fl.controls.Button;
import fl.controls.List;
import fl.events.ComponentEvent;
import fl.events.ListEvent;

var toggleButton:Button = new Button();
toggleButton.label = "toggle visibility";
toggleButton.toggle = true;
toggleButton.selected = true;
toggleButton.emphasized = toggleButton.selected;
toggleButton.addEventListener(Event.CHANGE, changeHandler);
toggleButton.width = 150;
toggleButton.move(10, 10);
addChild(toggleButton);

var myList:List = new List();
myList.addItem({label:"Item 1"});
myList.addItem({label:"Item 2"});
myList.addItem({label:"Item 3"});
myList.addItem({label:"Item 4"});
myList.addItem({label:"Item 5"});
myList.move(10, 40);
myList.addEventListener(ComponentEvent.HIDE, hideHandler);
myList.addEventListener(ComponentEvent.SHOW, showHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
addChild(myList);


function changeHandler(event:Event):void {
    toggleButton.emphasized = toggleButton.selected;
    myList.visible = toggleButton.selected;
}

function hideHandler(event:ComponentEvent):void {
    trace("hiding list");
    myList.removeEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.removeEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function showHandler(event:ComponentEvent):void {
    trace("showing list");
    myList.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
    myList.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOverHandler);
}

function itemRollOverHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

function itemRollOutHandler(event:ListEvent):void {
    trace(event.type + ":", event.item.label);
}

Vedere anche