fl.controls.RadioButtonGroup (ActionScript 3.0)

	Proprietà	Definito da
		constructor: Object Un riferimento all'oggetto classe o alla funzione di costruzione per una determinata istanza di oggetto.	Object
		name: String [sola lettura] Ottiene il nome di istanza del pulsante di scelta.	RadioButtonGroup
		numRadioButtons: int [sola lettura] Ottiene il numero di pulsanti di scelta presenti in questo gruppo di pulsanti di scelta.	RadioButtonGroup
		prototype: Object [statico] Un riferimento all'oggetto prototipo di un oggetto classe o funzione.	Object
		selectedData: Object Ottiene o imposta la proprietà value del pulsante di scelta selezionato.	RadioButtonGroup
		selection: RadioButton Ottiene o imposta un riferimento al pulsante di scelta attualmente selezionato nel gruppo di pulsanti di scelta.	RadioButtonGroup

	Metodo	Definito da
		RadioButtonGroup(name:String) Crea un nuova istanza RadioButtonGroup.	RadioButtonGroup
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registra un oggetto listener di eventi con un oggetto EventDispatcher, in modo che il listener riceva la notifica di un evento.	EventDispatcher
		addRadioButton(radioButton:RadioButton):void Aggiunge un pulsante di scelta all'array di pulsanti di scelta interno da utilizzare per l'indicizzazione del gruppo di pulsanti di scelta, al fine di consentire la selezione di un singolo pulsante di scelta in un gruppo.	RadioButtonGroup
		dispatchEvent(event:Event):Boolean Invia un evento nel flusso di eventi.	EventDispatcher
		getGroup(name:String):RadioButtonGroup [statico] Recupera un riferimento al gruppo di pulsanti di scelta specificato.	RadioButtonGroup
		getRadioButtonAt(index:int):RadioButton Recupera il componente RadioButton nella posizione di indice specificata.	RadioButtonGroup
		getRadioButtonIndex(radioButton:RadioButton):int Restituisce la posizione di indice dell'istanza RadioButton specificata.	RadioButtonGroup
		hasEventListener(type:String):Boolean Verifica se per l'oggetto EventDispatcher sono presenti listener registrati per un tipo specifico di evento.	EventDispatcher
		hasOwnProperty(name:String):Boolean Indica se per un oggetto è definita una proprietà specifica.	Object
		isPrototypeOf(theClass:Object):Boolean Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro.	Object
		propertyIsEnumerable(name:String):Boolean Indica se la proprietà specificata esiste ed è enumerabile.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Rimuove un listener dall'oggetto EventDispatcher.	EventDispatcher
		removeRadioButton(radioButton:RadioButton):void Cancella l'istanza RadioButton dall'elenco di pulsanti di scelta interno.	RadioButtonGroup
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche.	Object
		toString():String Restituisce la rappresentazione in formato stringa dell'oggetto specificato.	Object
		valueOf():Object Restituisce il valore di base dell'oggetto specificato.	Object
		willTrigger(type:String):Boolean Verifica se un listener di eventi è registrato con questo oggetto EventDispatcher o qualsiasi suo antenato per il tipo di evento specificato.	EventDispatcher

Riepilogo	Definito da
activate	Inviato quando Flash Player riceve lo stato di attivazione del sistema operativo e diventa attivo.	EventDispatcher
change	Inviato quando cambia l'istanza RadioButton selezionata in un gruppo.	RadioButtonGroup
click	Inviato quando viene fatto clic su un'istanza RadioButton.	RadioButtonGroup
deactivate	Inviato quando Flash Player perde lo stato di attivazione del sistema operativo e sta per diventare inattivo.	EventDispatcher

Descrizione delle proprietà

name

proprietà

name:String [sola lettura]

Versione linguaggio:

ActionScript 3.0

Versione lettore:

Flash Player 9.0.28.0

Ottiene il nome di istanza del pulsante di scelta.

Il valore predefinito è "RadioButtonGroup".

Implementazione
public function get name():String

numRadioButtons

proprietà

numRadioButtons:int [sola lettura]

Versione linguaggio:

ActionScript 3.0

Versione lettore:

Flash Player 9.0.28.0

Ottiene il numero di pulsanti di scelta presenti in questo gruppo di pulsanti di scelta.

Il valore predefinito è 0.

Implementazione
public function get numRadioButtons():int

selectedData

proprietà

selectedData:Object [lettura-scrittura]

Versione linguaggio:

ActionScript 3.0

Versione lettore:

Flash Player 9.0.28.0

Ottiene o imposta la proprietà value del pulsante di scelta selezionato. Questa proprietà è null se al momento non è selezionato alcun pulsante di scelta.

Implementazione
public function get selectedData():Object
public function set selectedData(value:Object):void

Esempio

L'esempio seguente crea un nuovo componente RadioButtonGroup e ne intercetta l'evento change:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.value = "optionA";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.value = "optionB";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.value = "optionC";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rbg:RadioButtonGroup = event.target as RadioButtonGroup;
    if (rbg.selectedData != null) {
        trace(rbg.selectedData);
    } else {
        trace("no value specified.");
    }
}

selection

proprietà

selection:RadioButton [lettura-scrittura]

Versione linguaggio:

ActionScript 3.0

Versione lettore:

Flash Player 9.0.28.0

Ottiene o imposta un riferimento al pulsante di scelta attualmente selezionato nel gruppo di pulsanti di scelta.

Implementazione
public function get selection():RadioButton
public function set selection(value:RadioButton):void

Esempio

L'esempio seguente crea un nuovo gruppo di pulsanti di scelta che contiene due pulsanti. Quando il pulsante di scelta selezionato viene modificato, l'etichetta e il valore del pulsante vengono tracciati:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var radioGroup:RadioButtonGroup = new RadioButtonGroup("rbg");
radioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.group = radioGroup;
radio1.label = "Option A";
radio1.value = 1;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.group = radioGroup;
radio2.label = "Option B";
radio2.value = 2;
radio2.move(10, 30);
addChild(radio2);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.currentTarget as RadioButtonGroup;
    trace("change:", rg.selection.label, "(" + rg.selectedData + ")");
}

Descrizione della funzione di costruzione

RadioButtonGroup

()

Funzione di costruzione

public function RadioButtonGroup(name:String)

Versione linguaggio:

ActionScript 3.0

Versione lettore:

Flash Player 9.0.28.0

Crea un nuova istanza RadioButtonGroup. Questa operazione viene generalmente eseguita in modo automatico quando viene creata l'istanza di un pulsante di scelta.

Parametri

name:String — Il nome del gruppo dei pulsanti di scelta.

Descrizione dei metodi

addRadioButton

()

metodo

public function addRadioButton(radioButton:RadioButton):void

Versione linguaggio:

ActionScript 3.0

Versione lettore:

Flash Player 9.0.28.0

Aggiunge un pulsante di scelta all'array di pulsanti di scelta interno da utilizzare per l'indicizzazione del gruppo di pulsanti di scelta, al fine di consentire la selezione di un singolo pulsante di scelta in un gruppo. Questo metodo viene utilizzato automaticamente dai pulsanti di scelta, ma può anche essere utilizzato manualmente per aggiungere esplicitamente un pulsante di scelta a un gruppo.

Parametri

radioButton:RadioButton — Un'istanza RadioButton da aggiungere al gruppo di pulsanti di scelta corrente.

getGroup

()

metodo

public static function getGroup(name:String):RadioButtonGroup

Versione linguaggio:

ActionScript 3.0

Versione lettore:

Flash Player 9.0.28.0

Recupera un riferimento al gruppo di pulsanti di scelta specificato.

Parametri

name:String — Il nome del gruppo per cui viene recuperato un riferimento.

Restituisce

RadioButtonGroup — Un riferimento alla classe RadioButtonGroup specificata.

Esempio

L'esempio seguente mostra come determinare quale pulsante di scelta all'interno di un gruppo è selezionato:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var rbg1:RadioButtonGroup = new RadioButtonGroup("group1");

var rb1:RadioButton = new RadioButton();
rb1.label = "Choice A";
rb1.group = rbg1;
rb1.move(10, 10);
rb1.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb1);

var rb2:RadioButton = new RadioButton();
rb2.label = "Choice B";
rb2.group = rbg1;
rb2.move(10, 30);
rb2.addEventListener(MouseEvent.CLICK, announceCurrentGroup);
addChild(rb2);

function announceCurrentGroup(e:MouseEvent):void {
    var group:RadioButtonGroup = RadioButtonGroup.getGroup("group1");
    trace("The currently selected radio button is: " + group.selection.label);
}

getRadioButtonAt

()

metodo

public function getRadioButtonAt(index:int):RadioButton

Versione linguaggio:

ActionScript 3.0

Versione lettore:

Flash Player 9.0.28.0

Recupera il componente RadioButton nella posizione di indice specificata.

Parametri

index:int — L'indice del componente RadioButton nel componente RadioButtonGroup, dove l'indice del primo componente è 0.

Restituisce

RadioButton — Il componente RadioButton specificato.

Genera

RangeError — Se l'indice specificato è inferiore a 0 oppure è superiore o uguale alla lunghezza del fornitore di dati.

getRadioButtonIndex

()

metodo

public function getRadioButtonIndex(radioButton:RadioButton):int

Versione linguaggio:

ActionScript 3.0

Versione lettore:

Flash Player 9.0.28.0

Restituisce la posizione di indice dell'istanza RadioButton specificata.

Parametri

radioButton:RadioButton — L'istanza RadioButton da individuare nel RadioButtonGroup corrente.

Restituisce

int — L'indice del componente RadioButton specificato oppure il valore -1 se il RadioButton specificato non viene trovato.

removeRadioButton

()

metodo

public function removeRadioButton(radioButton:RadioButton):void

Versione linguaggio:

ActionScript 3.0

Versione lettore:

Flash Player 9.0.28.0

Cancella l'istanza RadioButton dall'elenco di pulsanti di scelta interno.

Parametri

radioButton:RadioButton — L'istanza RadioButton da rimuovere.

Descrizione degli eventi

change

Evento

Tipo di oggetto evento: flash.events.Event
Event.type property = flash.events.Event.CHANGE

Versione linguaggio:

ActionScript 3.0

Versione lettore:

Flash Player 9.0.28.0

Inviato quando cambia l'istanza RadioButton selezionata in un gruppo.

Definisce il valore della proprietà type di un oggetto evento change.

Questo evento ha le seguenti proprietà:

Proprietà	Valore
`bubbles`	`true`
`cancelable`	`false`; non è presente alcun comportamento predefinito da annullare.
`currentTarget`	L'oggetto che elabora attivamente l'oggetto Event con un listener di eventi.
`target`	L'oggetto il cui valore è stato modificato. Il `target` non è sempre l'oggetto nell'elenco di visualizzazione che ha registrato il listener di eventi. Utilizzare la proprietà `currentTarget` per accedere all'oggetto nell'elenco di visualizzazione, che sta elaborando l'evento.

Esempio

L'esempio seguente crea tre pulsanti di scelta e aggiunge un listener di eventi per l'evento change di un gruppo di pulsanti di scelta:


import fl.controls.RadioButton;
import fl.controls.RadioButtonGroup;

var myRadioGroup:RadioButtonGroup = new RadioButtonGroup("options");
myRadioGroup.addEventListener(Event.CHANGE, changeHandler);

var radio1:RadioButton = new RadioButton();
radio1.label = "Option A";
radio1.group = myRadioGroup;
radio1.move(10, 10);
addChild(radio1);

var radio2:RadioButton = new RadioButton();
radio2.label = "Option B";
radio2.group = myRadioGroup;
radio2.move(10, 30);
addChild(radio2);

var radio3:RadioButton = new RadioButton();
radio3.label = "Option C";
radio3.group = myRadioGroup;
radio3.move(10, 50);
addChild(radio3);

function changeHandler(event:Event):void {
    var rg:RadioButtonGroup = event.target as RadioButtonGroup;
    switch (rg.selection) {
        case radio1:
            trace("radio1");
            break;
        case radio2:
            trace("radio2");
            break;
        case radio3:
            trace("radio3");
            break;
    }
}

click

Evento

Tipo di oggetto evento: flash.events.MouseEvent
MouseEvent.type property = flash.events.MouseEvent.CLICK

Versione linguaggio:

ActionScript 3.0

Versione lettore:

Flash Player 9.0.28.0

Inviato quando viene fatto clic su un'istanza RadioButton.

Definisce il valore della proprietà type di un oggetto evento click.

Questo evento ha le seguenti proprietà:

Proprietà	Valore
`bubbles`	`true`
`buttonDown`	`true` se viene premuto il pulsante principale del mouse; `false` in caso contrario.
`cancelable`	`false`; non è presente alcun comportamento predefinito da annullare.
`ctrlKey`	`true` se il tasto Ctrl è attivo; `false` se è inattivo.
`currentTarget`	L'oggetto che elabora attivamente l'oggetto Event con un listener di eventi.
`localX`	La coordinata orizzontale in cui si è verificato l'evento rispetto all'oggetto Sprite che lo contiene.
`localY`	La coordinata verticale in cui si è verificato l'evento rispetto all'oggetto Sprite che lo contiene.
`shiftKey`	`true` se il tasto Maiusc è attivo; `false` se è inattivo.
`stageX`	La coordinata orizzontale in cui si è verificato l'evento nelle coordinate globali dello stage.
`stageY`	La coordinata verticale in cui si è verificato l'evento nelle coordinate globali dello stage.
`target`	L'istanza InteractiveObject sotto il dispositivo di puntamento. Il `target` non è sempre l'oggetto nell'elenco di visualizzazione che ha registrato il listener di eventi. Utilizzare la proprietà `currentTarget` per accedere all'oggetto nell'elenco di visualizzazione, che sta elaborando l'evento.

Esempi Come utilizzare gli esempi

RadioButtonGroupExample.as

Questo esempio mostra come gestire molte istanze RadioButton in più gruppi.

Per provare l'esempio, eseguire queste operazioni:

Aggiungere i componenti RadioButton e Label alla libreria.
Salvare questo codice come RadioButtonGroupExample.as nella stessa directory del file FLA.
Impostare la classe documento nel file FLA su RadioButtonGroupExample.

package
{
    import fl.controls.Label;
    import fl.controls.RadioButton;
    import fl.controls.RadioButtonGroup;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.text.TextFieldAutoSize;
    
    public class RadioButtonGroupExample extends Sprite
    {
        private var padding:uint = 10;
        private var currHeight:uint = 0;
        private var verticalSpacing:uint = 30;
        private var posX:uint;
        private var reportLabel:Label;
        
        public function RadioButtonGroupExample() {
            setupRadioButtons();
        }
        private function setupRadioButtons():void {
            reportLabel = new Label();
            reportLabel.move(10,150);
            reportLabel.autoSize = TextFieldAutoSize.LEFT;
            reportLabel.text = "Select a Radio Button";
            addChild(reportLabel);

            createRadioButtonGroup("1st Group");
            createRadioButtonGroup("2nd Group");
            createRadioButtonGroup("3rd Group");
            createRadioButtonGroup("4th Group");
        }
        private function createRadioButtonGroup(name:String):void {
            var rbg:RadioButtonGroup = new RadioButtonGroup(name);
            rbg.addEventListener(Event.CHANGE, announceChange);
            createRadioButton("1st Button", rbg, posX);
            createRadioButton("2nd Button", rbg, posX);
            createRadioButton("3rd Button", rbg, posX);
            createRadioButton("4th Button", rbg, posX);
            posX += 125;
            currHeight = 0;
        }
        private function createRadioButton(rbLabel:String,rbg:RadioButtonGroup,posX:uint):void {
            var rb:RadioButton = new RadioButton();
            rb.group = rbg;
            rb.label = rbLabel;
            rb.move(posX, padding + currHeight);
            addChild(rb);

            currHeight += verticalSpacing;
        }
        private function announceChange(e:Event):void {
            var rbg:RadioButtonGroup = e.target as RadioButtonGroup;
            var rb:RadioButton = rbg.selection;
            reportLabel.text = rbg.name + " has selected " + rb.label;            
        }
    }
}

Pagina corrente: http://livedocs.adobe.com/flash/9.0_it/ActionScriptLangRefV3/fl/controls/RadioButtonGroup.html

Guida di riferimento del linguaggio e dei componenti ActionScript 3.0		Tutti i pacchetti \| Tutte le classi \| Elementi del linguaggio \| Indice \| Appendici \| Convenzioni \| Con frame Senza frame
RadioButtonGroup	Proprietà \| Metodi \| Eventi \| Esempi

Pacchetto	fl.controls
Classe	public class RadioButtonGroup
Ereditarietà	RadioButtonGroup EventDispatcher Object