fl.controls.Button (ActionScript 3.0)

Pacchetto	fl.controls
Classe	public class Button
Ereditarietà	Button LabelButton BaseButton UIComponent Sprite DisplayObjectContainer InteractiveObject DisplayObject EventDispatcher Object
Implementa	IFocusManagerComponent

Versione linguaggio:

ActionScript 3.0

Versione lettore:

Flash Player 9.0.28.0

Il componente Button rappresenta un pulsante rettangolare di uso comune. I componenti Button visualizzano un'etichetta di testo, un'icona o entrambe.

Un componente Button viene di solito associato a un metodo del gestore di eventi che intercetta un evento click e che, dopo che l'evento è stato inviato, esegue l'operazione specificata. Quando l'utente fa clic su un pulsante abilitato, il pulsante invia gli eventi click e buttonDown. Anche se non è abilitato, un pulsante invia anche altri eventi tra cui: mouseMove, mouseOver, mouseOut, rollOver, rollOut, mouseDown e mouseUp.

È possibile modificare l'aspetto del pulsante associando uno skin diverso a ogni suo stato. Un componente Button può anche essere impostato per fungere da pulsante di comando o da pulsante di tipo premuto/non premuto.

Vedere gli esempi

Proprietà pubbliche

Nascondi proprietà pubbliche ereditate

Mostra proprietà pubbliche ereditate

	Proprietà		Definito da
		accessibilityProperties: AccessibilityProperties Le opzioni di accessibilità correnti di questo oggetto di visualizzazione.	DisplayObject
		alpha: Number Indica il valore della trasparenza alfa dell'oggetto specificato.	DisplayObject
		autoRepeat: Boolean Ottiene o imposta un valore booleano che indica se l'evento buttonDown viene inviato più di una volta quando l'utente tiene premuto il pulsante del mouse sul componente.	BaseButton
		blendMode: String Un valore della classe BlendMode che specifica il metodo di fusione da utilizzare.	DisplayObject
		buttonMode: Boolean Specifica la modalità pulsante di questo sprite.	Sprite
		cacheAsBitmap: Boolean Se è impostata su true, viene memorizzata nella cache una rappresentazione bitmap interna dell'oggetto di visualizzazione.	DisplayObject
		constructor: Object Un riferimento all'oggetto classe o alla funzione di costruzione per una determinata istanza di oggetto.	Object
		contextMenu: ContextMenu Specifica il menu di scelta rapida associato all'oggetto.	InteractiveObject
		doubleClickEnabled: Boolean Specifica se l'oggetto riceve gli eventi doubleClick.	InteractiveObject
		dropTarget: DisplayObject [sola lettura] Specifica l'oggetto di visualizzazione sopra il quale viene trascinato lo sprite o sul quale viene rilasciato.	Sprite
		emphasized: Boolean Ottiene o imposta un valore booleano che indica se attorno al componente Button viene disegnato un bordo quando il pulsante è nello stato su.	Button
		enabled: Boolean Ottiene o imposta un valore che indica se il componente è in grado di accettare l'input da parte dell'utente.	BaseButton
		filters: Array Un array indicizzato che contiene ogni oggetto filtro attualmente associato all'oggetto di visualizzazione.	DisplayObject
		focusEnabled: Boolean Ottiene o imposta un valore booleano che indica se il componente può ricevere l'attivazione quando un utente fa clic su di esso.	UIComponent
		focusManager: IFocusManager Ottiene o imposta il FocusManager che controlla l'attivazione di questo componente e dei suoi pari.	UIComponent
		focusRect: Object Specifica se l'oggetto visualizza un rettangolo di attivazione.	InteractiveObject
		graphics: Graphics [sola lettura] Specifica l'oggetto Graphics che appartiene a questo oggetto Sprite, in cui possono essere eseguiti i comandi di disegno vettoriale.	Sprite
		height: Number Ottiene o imposta l'altezza del componente in pixel.	UIComponent
		hitArea: Sprite Definisce un altro sprite come area attiva di uno sprite.	Sprite
		label: String Ottiene o imposta l'etichetta di testo del componente.	LabelButton
		labelPlacement: String La posizione dell'etichetta in relazione a un'icona specificata.	LabelButton
		loaderInfo: LoaderInfo [sola lettura] Restituisce un oggetto LoaderInfo contenente informazioni sul caricamento del file al quale questo oggetto di visualizzazione appartiene.	DisplayObject
		mask: DisplayObject L'oggetto di visualizzazione chiamante viene mascherato dall'oggetto mask specificato.	DisplayObject
		mouseChildren: Boolean Determina se gli elementi secondari dell'oggetto sono abilitati per il mouse o meno.	DisplayObjectContainer
		mouseEnabled: Boolean Specifica se l'oggetto riceve i messaggi relativi al mouse.	InteractiveObject
		mouseFocusEnabled: Boolean Ottiene o imposta un valore che indica se il componente può ricevere l'attivazione quando un utente fa clic su di esso.	UIComponent
		mouseX: Number [sola lettura] Indica la coordinata x della posizione del mouse, in pixel.	DisplayObject
		mouseY: Number [sola lettura] Indica la coordinata y della posizione del mouse, in pixel.	DisplayObject
		name: String Indica il nome dell'istanza dell'oggetto DisplayObject.	DisplayObject
		numChildren: int [sola lettura] Restituisce il numero di elementi secondari di questo oggetto.	DisplayObjectContainer
		opaqueBackground: Object Specifica se l'oggetto di visualizzazione è opaco con un determinato colore di sfondo.	DisplayObject
		parent: DisplayObjectContainer [sola lettura] Indica l'oggetto DisplayObjectContainer che contiene questo oggetto di visualizzazione.	DisplayObject
		prototype: Object [statico] Un riferimento all'oggetto prototipo di un oggetto classe o funzione.	Object
		root: DisplayObject [sola lettura] Nel caso di un oggetto di visualizzazione all'interno di un file SWF caricato, la proprietà principale è l'oggetto di visualizzazione più in alto nella porzione della struttura dell'elenco di visualizzazione rappresentata da quel file SWF.	DisplayObject
		rotation: Number Indica la rotazione dell'istanza DisplayObject, espressa in gradi, rispetto alla posizione originale.	DisplayObject
		scale9Grid: Rectangle La griglia di modifica in scala attualmente attiva.	DisplayObject
		scaleX: Number Moltiplica la larghezza corrente del componente per un fattore di scala.	UIComponent
		scaleY: Number Moltiplica l'altezza corrente del componente per un fattore di scala.	UIComponent
		scrollRect: Rectangle I limiti del rettangolo di scorrimento dell'oggetto di visualizzazione.	DisplayObject
		selected: Boolean Ottiene o imposta un valore booleano che indica se un pulsante di tipo premuto/non premuto è attivato nella posizione on o nella posizione off.	LabelButton
		soundTransform: SoundTransform Controlla il suono nello sprite.	Sprite
		stage: Stage [sola lettura] Lo stage dell'oggetto di visualizzazione.	DisplayObject
		tabChildren: Boolean Determina se gli elementi secondari dell'oggetto sono abilitati per la tabulazione.	DisplayObjectContainer
		tabEnabled: Boolean Specifica se questo oggetto è incluso nell'ordine di tabulazione.	InteractiveObject
		tabIndex: int Specifica l'ordine di tabulazione degli oggetti in un file SWF.	InteractiveObject
		textField: TextField Un riferimento al campo di testo interno del componente.	LabelButton
		textSnapshot: TextSnapshot [sola lettura] Restituisce un oggetto TextSnapshot per questa istanza DisplayObjectContainer.	DisplayObjectContainer
		toggle: Boolean Ottiene o imposta un valore booleano che indica se un pulsante può essere di tipo premuto/non premuto.	LabelButton
		transform: Transform Un oggetto con proprietà relative alla matrice, alla trasformazione del colore e ai limiti di pixel di un oggetto di visualizzazione.	DisplayObject
		useHandCursor: Boolean Un valore booleano che indica se viene visualizzato un puntatore a forma di mano quando il mouse passa sopra uno sprite in cui la proprietà buttonMode è impostata su true.	Sprite
		version: String = "3.0.0.15" Numero di versione dei componenti.	UIComponent
		visible: Boolean Ottiene o imposta un valore che indica se l'istanza corrente del componente è visibile.	UIComponent
		width: Number Ottiene o imposta la larghezza del componente in pixel.	UIComponent
		x: Number Ottiene o imposta la coordinata x che rappresenta la posizione del componente sull'asse x nel contenitore principale.	UIComponent
		y: Number Ottiene o imposta la coordinata y che rappresenta la posizione del componente sull'asse y nel contenitore principale.	UIComponent

Metodi pubblici

Nascondi metodi pubblici ereditati

Mostra metodi pubblici ereditati

	Metodo		Definito da
		Button() Crea una nuova istanza del componente Button.	Button
		addChild(child:DisplayObject):DisplayObject Aggiunge un'istanza secondaria DisplayObject a questa istanza DisplayObjectContainer.	DisplayObjectContainer
		addChildAt(child:DisplayObject, index:int):DisplayObject Aggiunge un'istanza secondaria DisplayObject a questa istanza DisplayObjectContainer.	DisplayObjectContainer
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registra un oggetto listener di eventi con un oggetto EventDispatcher, in modo che il listener riceva la notifica di un evento.	EventDispatcher
		areInaccessibleObjectsUnderPoint(point:Point):Boolean Indica se le restrizioni di sicurezza possono determinare l'omissione di eventuali oggetti di visualizzazione dall'elenco restituito dalla chiamata al metodo DisplayObjectContainer.getObjectsUnderPoint() con il punto point specificato.	DisplayObjectContainer
		clearStyle(style:String):void Elimina una proprietà di stile dall'istanza del componente.	UIComponent
		contains(child:DisplayObject):Boolean Determina se l'oggetto di visualizzazione specificato è un elemento secondario dell'istanza DisplayObjectContainer oppure è l'istanza stessa.	DisplayObjectContainer
		dispatchEvent(event:Event):Boolean Invia un evento nel flusso di eventi.	EventDispatcher
		drawFocus(focused:Boolean):void Mostra o nasconde l'indicatore di attivazione sul componente.	UIComponent
		drawNow():void Avvia un'azione di disegno immediata, senza invalidare tutto come fa invalidateNow.	UIComponent
		getBounds(targetCoordinateSpace:DisplayObject):Rectangle Restituisce un rettangolo che definisce l'area dell'oggetto di visualizzazione relativa al sistema di coordinate dell'oggetto targetCoordinateSpace.	DisplayObject
		getChildAt(index:int):DisplayObject Restituisce l'istanza dell'oggetto di visualizzazione secondario che si trova in corrispondenza della posizione di indice specificata.	DisplayObjectContainer
		getChildByName(name:String):DisplayObject Restituisce l'oggetto di visualizzazione secondario al quale corrisponde il nome specificato.	DisplayObjectContainer
		getChildIndex(child:DisplayObject):int Restituisce la posizione di indice di un'istanza DisplayObject secondaria.	DisplayObjectContainer
		getFocus():InteractiveObject Recupera l'oggetto che è l'elemento attivo corrente.	UIComponent
		getObjectsUnderPoint(point:Point):Array Restituisce un array di oggetti che si trovano sotto il punto specificato e sono elementi secondari (di uno o più livelli inferiori) di questa istanza DisplayObjectContainer.	DisplayObjectContainer
		getRect(targetCoordinateSpace:DisplayObject):Rectangle Restituisce un rettangolo che definisce i bordi dell'oggetto di visualizzazione in base al sistema di coordinate definito dal parametro targetCoordinateSpace, esclusi gli eventuali tratti presenti sulle forme.	DisplayObject
		getStyle(style:String):Object Recupera una proprietà style impostata nella catena di ricerca dello stile del componente.	UIComponent
		getStyleDefinition():Object [statico] Recupera la mappa di stile predefinita del componente corrente.	Button
		globalToLocal(point:Point):Point Converte le coordinate dello stage (globali) in quelle (locali) dell'oggetto di visualizzazione per l'oggetto Point.	DisplayObject
		hasEventListener(type:String):Boolean Verifica se per l'oggetto EventDispatcher sono presenti listener registrati per un tipo specifico di evento.	EventDispatcher
		hasOwnProperty(name:String):Boolean Indica se per un oggetto è definita una proprietà specifica.	Object
		hitTestObject(obj:DisplayObject):Boolean Valuta l'oggetto di visualizzazione per stabilire se si sovrappone o si interseca con l'oggetto di visualizzazione obj.	DisplayObject
		hitTestPoint(x:Number, y:Number, shapeFlag:Boolean = false):Boolean Valuta l'oggetto di visualizzazione per stabilire se si sovrappone o si interseca con il punto specificato dai parametri x e y.	DisplayObject
		invalidate(property:String, callLater:Boolean = true):void Contrassegna una proprietà come non valida e ridisegna il componente sul fotogramma successivo salvo diversa indicazione.	UIComponent
		isPrototypeOf(theClass:Object):Boolean Indica se un'istanza della classe Object si trova nella catena di prototipi dell'oggetto specificato come parametro.	Object
		localToGlobal(point:Point):Point Converte le coordinate dell'oggetto di visualizzazione (locali) in quelle dello stage (globali) per l'oggetto Point.	DisplayObject
		mergeStyles(... list):Object [statico] Unisce gli stili di più classi in un unico oggetto.	UIComponent
		move(x:Number, y:Number):void Sposta il componente in una posizione specificata all'interno del relativo elemento principale.	UIComponent
		propertyIsEnumerable(name:String):Boolean Indica se la proprietà specificata esiste ed è enumerabile.	Object
		removeChild(child:DisplayObject):DisplayObject Rimuove l'istanza DisplayObject secondaria specificata dall'elenco degli elementi secondari dell'istanza DisplayObjectContainer.	DisplayObjectContainer
		removeChildAt(index:int):DisplayObject Rimuove un'istanza DisplayObject secondaria dalla posizione di indice specificata nell'elenco degli elementi secondari di DisplayObjectContainer.	DisplayObjectContainer
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Rimuove un listener dall'oggetto EventDispatcher.	EventDispatcher
		setChildIndex(child:DisplayObject, index:int):void Cambia la posizione di un elemento secondario nel contenitore di oggetto di visualizzazione.	DisplayObjectContainer
		setFocus():void Imposta questo componente come elemento attivo.	UIComponent
		setMouseState(state:String):void Imposta lo stato del mouse mediante ActionScript.	BaseButton
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Imposta la disponibilità di una proprietà dinamica per le operazioni cicliche.	Object
		setSize(width:Number, height:Number):void Imposta il componente sulla larghezza e sull'altezza specificate.	UIComponent
		setStyle(style:String, value:Object):void Imposta una proprietà di stile per l'istanza del componente.	UIComponent
		startDrag(lockCenter:Boolean = false, bounds:Rectangle = null):void Consente all'utente di trascinare lo sprite specificato.	Sprite
		stopDrag():void Termina il metodo startDrag().	Sprite
		swapChildren(child1:DisplayObject, child2:DisplayObject):void Scambia lo z-order (ordine di profondità) degli oggetti secondari specificati.	DisplayObjectContainer
		swapChildrenAt(index1:int, index2:int):void Scambia lo z-order (ordine di profondità) degli oggetti secondari nelle due posizioni di indice specificate nell'elenco degli elementi secondari.	DisplayObjectContainer
		toString():String Restituisce la rappresentazione in formato stringa dell'oggetto specificato.	Object
		validateNow():void Convalida e aggiorna le proprietà e il layout di questo oggetto e lo ridisegna, se necessario.	UIComponent
		valueOf():Object Restituisce il valore di base dell'oggetto specificato.	Object
		willTrigger(type:String):Boolean Verifica se un listener di eventi è registrato con questo oggetto EventDispatcher o qualsiasi suo antenato per il tipo di evento specificato.	EventDispatcher

Eventi

Nascondi eventi ereditati

Mostra eventi ereditati

	Riepilogo	Definito da
activate	Inviato quando Flash Player riceve lo stato di attivazione del sistema operativo e diventa attivo.	EventDispatcher
added	Inviato quando un oggetto di visualizzazione viene aggiunto all'elenco di visualizzazione.	DisplayObject
addedToStage	Inviato quando un oggetto di visualizzazione viene aggiunto all'elenco di visualizzazione sullo stage, sia direttamente o mediante l'aggiunta di una sottostruttura ad albero che contiene l'oggetto di visualizzazione.	DisplayObject
buttonDown	Inviato quando l'utente preme il componente Button.	BaseButton
change	Inviato quando cambia il valore della proprietà selected per un componente Button di tipo premuto/non premuto.	BaseButton
click	Inviato dopo che il pulsante di tipo premuto/non premuto ha ricevuto l'input dal mouse o dalla barra spaziatrice.	LabelButton
deactivate	Inviato quando Flash Player perde lo stato di attivazione del sistema operativo e sta per diventare inattivo.	EventDispatcher
doubleClick	Inviato quando l'utente preme e rilascia il pulsante principale di un dispositivo di puntamento due volte in rapida successione sopra la stessa istanza InteractiveObject quando il flag doubleClickEnabled dell'oggetto è impostato su true.	InteractiveObject
enterFrame	Inviato quando l'indicatore di riproduzione sta entrando in un nuovo fotogramma.	DisplayObject
focusIn	Inviato dopo che un oggetto di visualizzazione ha ricevuto lo stato di attivazione.	InteractiveObject
focusOut	Inviato dopo che un oggetto di visualizzazione ha perso lo stato di attivazione.	InteractiveObject
hide	Inviato dopo che il componente è passato da visibile a invisibile.	UIComponent
keyDown	Inviato quando l'utente preme un tasto.	InteractiveObject
keyFocusChange	Inviato quando l'utente tenta di cambiare l'elemento attivo utilizzando la tastiera.	InteractiveObject
keyUp	Inviato quando l'utente rilascia un tasto.	InteractiveObject
labelChange	Inviato dopo che il valore label è stato modificato.	LabelButton
mouseDown	Inviato quando un utente preme il pulsante del dispositivo di puntamento su un'istanza InteractiveObject nella finestra di Flash Player.	InteractiveObject
mouseFocusChange	Inviato quando l'utente tenta di cambiare l'elemento attivo utilizzando un dispositivo di puntamento.	InteractiveObject
mouseMove	Inviato quando l'utente sposta il dispositivo di puntamento mentre si trova sopra un'istanza InteractiveObject.	InteractiveObject
mouseOut	Inviato quando l'utente allontana un dispositivo di puntamento da un'istanza InteractiveObject.	InteractiveObject
mouseOver	Inviato quando un utente muove un dispositivo di puntamento sopra un'istanza InteractiveObject nella finestra di Flash Player.	InteractiveObject
mouseUp	Inviato quando un utente rilascia il pulsante del dispositivo di puntamento su un'istanza InteractiveObject nella finestra di Flash Player.	InteractiveObject
mouseWheel	Inviato quando la rotella del mouse viene fatta ruotare sopra un'istanza InteractiveObject nella finestra di Flash Player.	InteractiveObject
move	Inviato dopo che il componente viene spostato.	UIComponent
removed	Inviato quando un oggetto di visualizzazione sta per essere rimosso dall'elenco di visualizzazione.	DisplayObject
removedFromStage	Inviato quando un oggetto di visualizzazione sta per essere rimosso dall'elenco di visualizzazione sullo stage, sia direttamente o mediante la rimozione di una sottostruttura ad albero che contiene l'oggetto di visualizzazione.	DisplayObject
render	Inviato quando l'elenco di visualizzazione sta per essere aggiornato e sottoposto a rendering.	DisplayObject
resize	Inviato dopo che il componente viene ridimensionato.	UIComponent
rollOut	Inviato quando l'utente allontana un dispositivo di puntamento da un'istanza InteractiveObject.	InteractiveObject
rollOver	Inviato quando l'utente sposta un dispositivo di puntamento sopra un'istanza InteractiveObject.	InteractiveObject
show	Inviato dopo che il componente è passato da invisibile a visibile.	UIComponent
tabChildrenChange	Inviato quando cambia il valore del flag tabChildren dell'oggetto.	InteractiveObject
tabEnabledChange	Inviato quando cambia il flag tabEnabled dell'oggetto.	InteractiveObject
tabIndexChange	Inviato quando cambia il valore della proprietà tabIndex dell'oggetto.	InteractiveObject

Stili

Nascondi stili ereditati

Mostra stili ereditati

	Descrizione	Definito da
disabledIcon	Tipo: Class Nome della classe da utilizzare come icona quando il pulsante non è disattivato.	LabelButton
disabledSkin	Tipo: Class Nome della classe da utilizzare come skin per lo sfondo e il bordo quando il pulsante non è selezionato ed è disattivato.	LabelButton
disabledTextFormat	Tipo: flash.text.TextFormat L'oggetto TextFormat da utilizzare per il rendering dell'etichetta del componente quando il pulsante è disattivato.	UIComponent
downIcon	Tipo: Class Nome della classe da utilizzare come icona quando il pulsante non è selezionato e il pulsante del mouse è in basso.	LabelButton
downSkin	Tipo: Class Nome della classe da utilizzare come skin per lo sfondo e il bordo quando il pulsante non è selezionato e il pulsante del mouse è in basso.	LabelButton
embedFonts	Tipo: Boolean Indica se i profili di carattere incorporati vengono utilizzati per il rendering del campo di testo.	LabelButton
emphasizedPadding	Tipo: Number Formato: Length Il riempimento da applicare intorno ai pulsanti in uno skin evidenziato, in pixel. Il valore predefinito è `2`.	Button
emphasizedSkin	Tipo: Class Lo skin da utilizzare quando un pulsante è evidenziato. Il valore predefinito è `Button_emphasizedSkin`.	Button
focusRectPadding	Tipo: Number Formato: Length Il riempimento che separa i margini esterni del componente dai bordi esterni dell'indicatore di attivazione, in pixel.	UIComponent
focusRectSkin	Tipo: Class Lo skin da utilizzare per la visualizzazione degli indicatori di attivazione.	UIComponent
icon	Tipo: Class Nome della classe da utilizzare come icona quando un pulsante di premuto/non premuto non è selezionato e il mouse non si trova sopra il pulsante.	LabelButton
overIcon	Tipo: Class Nome della classe da utilizzare come icona quando il pulsante non è selezionato e il mouse si trova sopra il componente.	LabelButton
overSkin	Tipo: Class Nome della classe da utilizzare come skin per lo sfondo e il bordo quando il pulsante non è selezionato e il mouse si trova sopra il componente.	LabelButton
repeatDelay	Tipo: Number Formato: Time Il numero di millisecondi da attendere dopo che l'evento `buttonDown` viene inviato per la prima volta prima dell'invio di un secondo evento `buttonDown`.	LabelButton
repeatInterval	Tipo: Number Formato: Time L'intervallo, in millisecondi, tra gli eventi `buttonDown` che vengono inviati dopo il ritardo specificato dallo stile `repeatDelay`.	LabelButton
selectedDisabledIcon	Tipo: Class Nome della classe da utilizzare come icona quando il pulsante è selezionato e disattivato.	LabelButton
selectedDisabledSkin	Tipo: Class Nome della classe da utilizzare come skin per lo sfondo e il bordo quando un pulsante di premuto/non premuto è selezionato e disattivato.	LabelButton
selectedDownIcon	Tipo: Class Nome della classe da utilizzare come icona quando il pulsante viene selezionato e il pulsante del mouse è in basso.	LabelButton
selectedDownSkin	Tipo: Class Nome della classe da utilizzare come skin per lo sfondo e il bordo quando un pulsante di premuto/non premuto è selezionato e il pulsante del mouse è in basso.	LabelButton
selectedOverIcon	Tipo: Class Nome della classe da utilizzare come icona quando il pulsante viene selezionato e il mouse si trova sopra il componente.	LabelButton
selectedOverSkin	Tipo: Class Nome della classe da utilizzare come skin per lo sfondo e il bordo quando un pulsante di premuto/non premuto è selezionato e il mouse si trova sopra il componente.	LabelButton
selectedUpIcon	Tipo: Class Nome della classe da utilizzare come icona quando il pulsante viene selezionato e il pulsante del mouse è in alto.	LabelButton
selectedUpSkin	Tipo: Class Nome della classe da utilizzare come skin per lo sfondo e il bordo quando un pulsante di premuto/non premuto è selezionato e il mouse non si trova sopra il componente.	LabelButton
textFormat	Tipo: flash.text.TextFormat L'oggetto TextFormat da utilizzare per il rendering dell'etichetta del componente.	UIComponent
textPadding	Tipo: Number Formato: Length Lo spazio tra il testo e i bordi del componente e quello tra il testo e l'icona, in pixel.	LabelButton
upIcon	Tipo: Class Nome della classe da utilizzare come icona quando un pulsante di premuto/non premuto non è selezionato e il mouse non si trova sopra il pulsante.	LabelButton
upSkin	Tipo: Class Nome della classe da utilizzare come skin per lo sfondo e il bordo quando il pulsante non è selezionato e il mouse non si trova sopra il componente.	LabelButton

Descrizione delle proprietà

emphasized

proprietà

emphasized:Boolean [lettura-scrittura]

Versione linguaggio:

ActionScript 3.0

Versione lettore:

Flash Player 9.0.28.0

Ottiene o imposta un valore booleano che indica se attorno al componente Button viene disegnato un bordo quando il pulsante è nello stato su. Il valore true indica che attorno al componente Button viene disegnato un bordo quando il pulsante è nello stato su; il valore false indica che il bordo non viene disegnato.

Il valore predefinito è false.

Implementazione
public function get emphasized():Boolean
public function set emphasized(value:Boolean):void

Vedere anche

emphasizedPadding
emphasizedSkin

Esempio

L'esempio seguente imposta lo stile emphasizedPadding dell'istanza Button in base al valore di un componente Slider:


import fl.controls.Button;
import fl.controls.Slider;
import fl.events.SliderEvent;

var styleObject:Object = Button.getStyleDefinition();
var defaultEmphasizedPadding:uint = styleObject.emphasizedPadding;

var myButton:Button = new Button();
myButton.label = "emphasizedPadding:" + defaultEmphasizedPadding;
myButton.emphasized = true;
myButton.width = 150;
myButton.move(20, 20);
addChild(myButton);

var mySlider:Slider = new Slider();
mySlider.snapInterval = 1;
mySlider.tickInterval = 1;
mySlider.liveDragging = true;
mySlider.value = defaultEmphasizedPadding;
mySlider.width = myButton.width;
mySlider.move(20, 60);
mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
addChild(mySlider);

function changeHandler(event:SliderEvent):void {
    myButton.label = "emphasizedPadding:" + event.value;
    myButton.setStyle("emphasizedPadding", event.value);
}

Descrizione della funzione di costruzione

Button

()

Funzione di costruzione

public function Button()

Versione linguaggio:

ActionScript 3.0

Versione lettore:

Flash Player 9.0.28.0

Crea una nuova istanza del componente Button.

Descrizione dei metodi

getStyleDefinition

()

metodo

public static function getStyleDefinition():Object

Versione linguaggio:

ActionScript 3.0

Versione lettore:

Flash Player 9.0.28.0

Recupera la mappa di stile predefinita del componente corrente. La mappa di stile contiene il tipo appropriato per il componente, in base allo stile utilizzato dal componente. Ad esempio, lo stile disabledTextFormat contiene un valore null o un oggetto TextFormat. È possibile utilizzare questi stili e chiamare setStyle() sul componente corrente. Il codice seguente consente di ignorare lo stile disabledTextFormat predefinito sul componente specificato:

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Restituisce

Object — Oggetto stili predefinito.

Vedere anche

UIComponent.getStyle()
UIComponent.setStyle()
StyleManager

Esempio

L'esempio seguente crea un browser di stili per varie classi di componenti:

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Esempi Come utilizzare gli esempi

ButtonExample.as

Questo esempio illustra come creare e applicare degli stili in modo dinamico a un pulsante.

Per provare l'esempio, eseguire queste operazioni:

Aggiungere i componenti Button e TextArea alla libreria.
Salvare questo codice come ButtonExample.as nella stessa directory del file FLA.
Impostare la classe documento nel file FLA su ButtonExample.

package
{
    import fl.controls.Button;
    import fl.controls.TextArea;
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextFormat;
    
    public class ButtonExample extends Sprite
    {
        private var b1:Button;
        private var b2:Button;      
        private var b3:Button;
        private var ta:TextArea;
        
        public function ButtonExample() {
            createTraceField();
            setupButtons();
        }
        private function createTraceField():void {
            ta = new TextArea();
            ta.setSize(200, 300);
            ta.move(200, 10);
            addChild(ta);
        }
        private function setupButtons():void {
            b1 = new Button();
            b2 = new Button();
            b3 = new Button();

            b1.width = 160;
            b2.width = 160;
            b3.width = 160;

            b1.move(10,10);
            b2.move(10,40);
            b3.move(10,70);

            b1.label = "Default Button";
            b2.label = "Custom Styled Button";
            b3.label = "Toggle Button";

            b2.setStyle("textFormat", new TextFormat("Georgia"));

            b3.toggle = true;
            
            b1.addEventListener(MouseEvent.CLICK, buttonClick);
            b2.addEventListener(MouseEvent.CLICK, buttonClick);
            b3.addEventListener(MouseEvent.CLICK, buttonClick);

            addChild(b1);
            addChild(b2);
            addChild(b3);
        }
        private function buttonClick(e:MouseEvent) {
            var button:Button = e.target as Button;
            ta.appendText(button.label + "\n");
        }
    }
}

Pagina corrente: http://livedocs.adobe.com/flash/9.0_it/ActionScriptLangRefV3/fl/controls/Button.html

Guida di riferimento del linguaggio e dei componenti ActionScript 3.0		Tutti i pacchetti \| Tutte le classi \| Elementi del linguaggio \| Indice \| Appendici \| Convenzioni \| Con frame Senza frame
Button	Proprietà \| Metodi \| Eventi \| Stili \| Esempi