ignoreComments:Boolean [lettura-scrittura]
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Determina se i commenti XML vengono ignorati quando gli oggetti XML analizzano i dati XML di origine. Per impostazione predefinita, i commenti vengono ignorati (true). Per includere i commenti XML, impostare questa proprietà su false. La proprietà ignoreComments viene utilizzata solo durante l'analisi XML, non durante la chiamata a un metodo qualsiasi come myXMLObject.child(*).toXMLString(). Se l'XML di origine include dei nodi di commenti, vengono conservati o scartati durante l'analisi XML.
Implementazione
public static function get ignoreComments():Boolean
public function set ignoreComments(value:Boolean):void
Vedere anche
Esempio
L'esempio seguente mostra l'effetto dell'impostazione di
XML.ignoreComments su
false e su
true:
XML.ignoreComments = false;
var xml1:XML =
<foo>
<!-- comment -->
</foo>;
trace(xml1.toXMLString()); // <foo><!-- comment --></foo>
XML.ignoreComments = true;
var xml2:XML =
<foo>
<!-- example -->
</foo>;
trace(xml2.toXMLString()); // <foo/>
ignoreProcessingInstructions:Boolean [lettura-scrittura]
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Determina se le istruzioni di elaborazione XML vengono ignorate quando gli oggetti XML analizzano i dati XML di origine. Per impostazione predefinita, le istruzioni di elaborazione vengono ignorate (true). Per includere le istruzioni di elaborazione XML, impostare questa proprietà su false. La proprietà ignoreProcessingInstructions viene utilizzata solo durante l'analisi XML, non durante la chiamata a un metodo qualsiasi come myXMLObject.child(*).toXMLString(). Se l'XML di origine include dei nodi di istruzioni di elaborazione, vengono conservati o scartati durante l'analisi XML.
Implementazione
public static function get ignoreProcessingInstructions():Boolean
public function set ignoreProcessingInstructions(value:Boolean):void
Vedere anche
Esempio
L'esempio seguente mostra l'effetto dell'impostazione di
XML.ignoreProcessingInstructions su
false e su
true:
XML.ignoreProcessingInstructions = false;
var xml1:XML =
<foo>
<?exampleInstruction ?>
</foo>;
trace(xml1.toXMLString()); // <foo><?exampleInstruction ?></foo>
XML.ignoreProcessingInstructions = true;
var xml2:XML =
<foo>
<?exampleInstruction ?>
</foo>;
trace(xml2.toXMLString()); // <foo/>
ignoreWhitespace:Boolean [lettura-scrittura]
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Determina se i caratteri di spazio all'inizio e alla fine dei nodi di testo vengono ignorati durante l'analisi. Per impostazione predefinita, lo spazio vuoto viene ignorato (true). Se un nodo di testo è composto al 100% da spazio vuoto e la proprietà ignoreWhitespace è impostata su true, il nodo non viene creato. Per mostrare lo spazio vuoto in un nodo di testo, impostare la proprietà ignoreWhitespace su false.
Implementazione
public static function get ignoreWhitespace():Boolean
public function set ignoreWhitespace(value:Boolean):void
Esempio
L'esempio seguente mostra l'effetto dell'impostazione di
XML.ignoreWhitespace su
false e su
true:
XML.ignoreWhitespace = false;
var xml1:XML = <foo> </foo>;
trace(xml1.children().length()); // 1
XML.ignoreWhitespace = true;
var xml2:XML = <foo> </foo>;
trace(xml2.children().length()); // 0
prettyIndent:int [lettura-scrittura]
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Determina la quantità di rientro applicato dai metodi toString() e toXMLString() quando la proprietà XML.prettyPrinting è impostata su true. Il rientro viene applicato con il carattere di spazio, non con il carattere di tabulazione. Il valore predefinito è 2.
Implementazione
public static function get prettyIndent():int
public function set prettyIndent(value:int):void
Vedere anche
Esempio
L'esempio seguente mostra l'effetto dell'impostazione della proprietà statica
XML.prettyIndent:
var xml:XML = <foo><bar/></foo>;
XML.prettyIndent = 0;
trace(xml.toXMLString());
XML.prettyIndent = 1;
trace(xml.toXMLString());
XML.prettyIndent = 2;
trace(xml.toXMLString());
prettyPrinting:Boolean [lettura-scrittura]
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Determina se i metodi toString() e toXMLString() normalizzano i caratteri di spazio vuoto tra alcuni tag. Il valore predefinito è true.
Implementazione
public static function get prettyPrinting():Boolean
public function set prettyPrinting(value:Boolean):void
Vedere anche
Esempio
L'esempio seguente mostra l'effetto dell'impostazione della proprietà statica
XML.prettyPrinting:
var xml:XML = <foo><bar/></foo>;
XML.prettyPrinting = false;
trace(xml.toXMLString());
XML.prettyPrinting = true;
trace(xml.toXMLString());
public function XML(value:Object)
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Crea un nuovo oggetto XML. È necessario utilizzare la funzione di costruzione per creare un oggetto XML prima di chiamare i metodi della classe XML.
Utilizzare il metodo toXMLString() per restituire una rappresentazione in formato stringa dell'oggetto XML a prescindere dal tipo di contenuto (semplice o complesso) di quest'ultimo.
Parametri
| value:Object — Qualunque oggetto che può essere convertito in XML con la funzione XML() di primo livello.
|
Vedere anche
AS3 function addNamespace(ns:Object):XML
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Aggiunge uno spazio dei nomi al gruppo di spazi dei nomi validi per l'oggetto XML. Se lo spazio dei nomi esiste già negli spazi dei nomi validi dell'oggetto XML (con un prefisso che corrisponde a quello del parametro dato), il prefisso dello spazio dei nomi esistente viene impostato su undefined. Se il parametro di input è un oggetto Namespace, viene utilizzato direttamente. Se è un oggetto QName, l'URI del parametro di input viene utilizzato per creare un nuovo spazio dei nomi; in caso contrario, viene convertito in una stringa e da quest'ultima viene creato uno spazio dei nomi.
Parametri
| ns:Object — Lo spazio dei nomi da aggiungere all'oggetto XML.
|
Restituisce
| XML — Il nuovo oggetto XML, con l'aggiunta dello spazio dei nomi.
|
Vedere anche
Esempio
Questo esempio utilizza uno spazio dei nomi definito in un oggetto XML e lo applica a un altro oggetto XML:
var xml1:XML = <ns:foo xmlns:ns="www.example.com/ns" />;
var nsNamespace:Namespace = xml1.namespace();
var xml2:XML = <bar />;
xml2.addNamespace(nsNamespace);
trace(xml2.toXMLString()); // <bar xmlns:ns="www.example.com/ns"/>
AS3 function appendChild(child:Object):XML
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Aggiunge l'elemento secondario dato alla fine delle proprietà dell'oggetto XML. Il metodo appendChild() accetta un oggetto XML, un oggetto XMLList o qualunque altro tipo di dati, che viene successivamente convertito in stringa.
Utilizzare l'operatore delete (XML) per rimuovere i nodi XML.
Parametri
| child:Object — L'oggetto XML da aggiungere.
|
Restituisce
| XML — L'oggetto XML risultante.
|
Vedere anche
Esempio
Questo esempio aggiunge un nuovo elemento alla fine dell'elenco degli elementi secondari di un oggetto XML:
var xml:XML =
<body>
<p>hello</p>
</body>;
xml.appendChild(<p>world</p>);
trace(xml.p[0].toXMLString()); // <p>hello</p>
trace(xml.p[1].toXMLString()); // <p>world</p>
AS3 function attribute(attributeName:*):XMLList
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Restituisce il valore XML dell'attributo con il nome corrispondente al parametro attributeName. Gli attributi si trovano all'interno degli elementi XML. Nell'esempio seguente, l'elemento ha un attributo di nome "gender" con il valore "boy": <first gender="boy">John</first>.
Il parametro attributeName può essere di qualsiasi tipo di dati, tuttavia String è quello più comune. Quando si passa un oggetto diverso da un oggetto QName, il parametro attributeName utilizza il metodo toString() per convertire il parametro in una stringa.
Se è necessario un riferimento a un nome completo, è possibile passare un oggetto QName. Un oggetto QName definisce uno spazio dei nomi e il nome locale, che serve per definire il nome completo di un attributo. Pertanto, una chiamata a attribute(qname) non equivale a una chiamata a attribute(qname.toString()).
Parametri
| attributeName:* — Il nome dell'attributo.
|
Restituisce
| XMLList — Un oggetto XMLList o un oggetto XMLList vuoto. Restituisce un oggetto XMLList vuoto quando non è stato definito un valore di attributo.
|
Vedere anche
Esempio
Questo esempio mostra un oggetto QName passato al metodo
attribute(). La proprietà
localName è
attr mentre la proprietà
namespace è
ns.
var xml:XML = <ns:node xmlns:ns = "http://uri" ns:attr = '7' />
var qn:QName = new QName("http://uri", "attr");
trace(xml.attribute(qn)); // 7 Per restituire un attributo con un nome che corrisponde a una parola riservata di ActionScript, utilizzare il metodo
attribute() invece dell'operatore identificatore di attributo (@), come indicato nell'esempio seguente:
var xml:XML = <example class="first" />
trace(xml.attribute("class"));
AS3 function attributes():XMLList
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Restituisce un elenco di valori di attributo per l'oggetto XML dato. Utilizzare il metodo name() con il metodo attributes() per restituire il nome di un attributo. Utilizzare @* per restituire i nomi di tutti gli attributi.
Restituisce
| XMLList — L'elenco di valori di attributo.
|
Vedere anche
Esempio
L'esempio seguente restituisce il nome dell'attributo:
var xml:XML=<example id='123' color='blue'/>
trace(xml.attributes()[1].name()); //color
Questo esempio restituisce i nomi di tutti gli attributi:
var xml:XML = <example id='123' color='blue'/>
var attNamesList:XMLList = xml.@*;
trace(attNamesList is XMLList); // true
trace(attNamesList.length()); // 2
for (var i:int = 0; i < attNamesList.length(); i++)
{
trace(typeof (attNamesList[i])); // xml
trace(attNamesList[i].nodeKind()); // attribute
trace(attNamesList[i].name()); // id and color
}
AS3 function child(propertyName:Object):XMLList
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Elenca gli elementi secondari di un oggetto XML. Un elemento XML secondario è un elemento XML, un nodo di testo, un commento o un'istruzione di elaborazione.
Utilizzare il parametro propertyName per elencare il contenuto di un elemento XML secondario specifico. Ad esempio, per restituire il contenuto di un elemento secondario di nome <first>, utilizzare child.name("first"). Lo stesso risultato può essere ottenuto utilizzando il numero di indice dell'elemento secondario. Il numero di indice identifica la posizione dell'elemento secondario nell'elenco degli altri elementi XML secondari. Ad esempio, name.child(0) restituisce il primo elemento secondario in un elenco.
Utilizzare un asterisco (*) per produrre tutti gli elementi secondari in un documento XML. Ad esempio, doc.child("*").
Utilizzare il metodo length() con il parametro asterisco (*) del metodo child() per produrre il numero totale di elementi secondari. Ad esempio, numChildren = doc.child("*").length().
Parametri
| propertyName:Object — Il nome dell'elemento o l'intero dell'elemento XML secondario.
|
Restituisce
| XMLList — Un oggetto XMLList di nodi secondari che corrispondono al parametro di input.
|
Vedere anche
Esempio
Questo esempio mostra l'utilizzo del metodo
child() per identificare gli elementi secondari con un nome specificato:
var xml:XML =
<foo>
<bar>text1</bar>
<bar>text2</bar>
</foo>;
trace(xml.child("bar").length()); // 2
trace(xml.child("bar")[0].toXMLString()); // <bar>text1</bar>
trace(xml.child("bar")[1].toXMLString()); // <bar>text2</bar>
AS3 function childIndex():int
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Identifica la posizione di indice a base zero di questo oggetto XML nel contesto dei relativi elementi principali.
Restituisce
| int — La posizione dell'oggetto. Restituisce sia -1 che numeri interi positivi.
|
Vedere anche
Esempio
Questo esempio mostra l'utilizzo del metodo
childIndex():
var xml:XML =
<foo>
<bar />
text
<bob />
</foo>;
trace(xml.bar.childIndex()); // 0
trace(xml.bob.childIndex()); // 2
AS3 function children():XMLList
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Elenca gli elementi secondari dell'oggetto XML nella sequenza in cui compaiono. Un elemento XML secondario è un elemento XML, un nodo di testo, un commento o un'istruzione di elaborazione.
Restituisce
| XMLList — Un oggetto XMLList degli elementi secondari dell'oggetto XML.
|
Vedere anche
Esempio
Questo esempio mostra l'utilizzo del metodo
children():
XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var xml:XML =
<foo id="22">
<bar>44</bar>
text
<!-- comment -->
<?instruction ?>
</foo>;
trace(xml.children().length()); // 4
trace(xml.children()[0].toXMLString()); // <bar>44</bar>
trace(xml.children()[1].toXMLString()); // text
trace(xml.children()[2].toXMLString()); // <!-- comment -->
trace(xml.children()[3].toXMLString()); // <?instruction ?>
AS3 function comments():XMLList
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Elenca le proprietà dell'oggetto XML che contengono commenti XML.
Restituisce
| XMLList — Un oggetto XMLList delle proprietà che contengono commenti.
|
Vedere anche
Esempio
Questo esempio mostra l'utilizzo del metodo
comments():
XML.ignoreComments = false;
var xml:XML =
<foo>
<!-- example -->
<!-- example2 -->
</foo>;
trace(xml.comments().length()); // 2
trace(xml.comments()[1].toXMLString()); // <!-- example2 -->
AS3 function contains(value:XML):Boolean
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Confronta l'oggetto XML con il parametro value dato.
Parametri
| value:XML — Un valore da confrontare con l'oggetto XML corrente.
|
Restituisce
| Boolean — Se l'oggetto XML corrisponde al parametro value, viene restituito true; in caso contrario, false.
|
Vedere anche
Esempio
Questo esempio mostra l'utilizzo del metodo
contains():
var xml:XML =
<order>
<item>Rice</item>
<item>Kung Pao Shrimp</item>
</order>;
trace(xml.item[0].contains(<item>Rice</item>)); // true
trace(xml.item[1].contains(<item>Kung Pao Shrimp</item>)); // true
trace(xml.item[1].contains(<item>MSG</item>)); // false
AS3 function copy():XML
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Restituisce una copia dell'oggetto XML dato. La copia è un duplicato dell'intera struttura ad albero di nodi. L'oggetto XML copiato non ha un elemento principale e restituisce null se si tenta di chiamare il metodo parent().
Restituisce
| XML — La copia dell'oggetto.
|
Vedere anche
Esempio
L'esempio seguente mostra come il metodo
copy() crea una nuova istanza di un oggetto XML. Quando si modifica la copia, l'originale rimane invariato:
var xml1:XML = <foo />;
var xml2:XML = xml1.copy();
xml2.appendChild(<bar />);
trace(xml1.bar.length()); // 0
trace(xml2.bar.length()); // 1
AS3 static function defaultSettings():Object
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Restituisce un oggetto con le proprietà seguenti impostate sui valori predefiniti: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent e prettyPrinting. I valori predefiniti sono i seguenti:
ignoreComments = trueignoreProcessingInstructions = trueignoreWhitespace = trueprettyIndent = 2prettyPrinting = true
Nota: questo metodo non va applicato a un'istanza della classe XML, bensì a XML, come mostrato nel codice seguente: var df:Object = XML.defaultSettings().
Restituisce
| Object — Un oggetto con le proprietà impostate sui valori predefiniti.
|
Vedere anche
Esempio
L'esempio seguente illustra come applicare alcune impostazioni personalizzate (per inserire commenti e istruzioni di elaborazione) prima di impostare un oggetto XML, ripristinare le impostazioni predefinite prima di impostare un altro oggetto XML e quindi reimpostare le impostazioni personalizzate (per impostare eventuali oggetti XML aggiuntivi):
XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();
var xml1:XML =
<foo>
<!-- comment -->
<?instruction ?>
</foo>;
trace(xml1.toXMLString());
// <foo>
// <!-- comment -->
// <?instruction ?>
// </foo>
XML.setSettings(XML.defaultSettings());
var xml2:XML =
<foo>
<!-- comment -->
<?instruction ?>
</foo>;
trace(xml2.toXMLString());
AS3 function descendants(name:Object = *):XMLList
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Restituisce tutti gli elementi discendenti (secondari, inferiori di due livelli, inferiori di tre livelli, e così via) dell'oggetto XML che hanno il parametro name dato. Il parametro name è opzionale. Il parametro name può essere un oggetto QName, un tipo di dati String o qualunque altro tipo di dati che viene successivamente convertito in un tipo di dati String.
Per restituire tutti gli elementi discendenti, utilizzare il parametro "*". Se non viene passato alcun parametro, viene passata la stringa "*" che restituisce tutti i discendenti dell'oggetto XML.
Parametri
| name:Object (default = *) |
Restituisce
| XMLList — Un oggetto XMLList di elementi discendenti corrispondenti. Se non sono presenti dei discendenti, restituisce un oggetto XMLList vuoto.
|
Vedere anche
Esempio
Per restituire discendenti con nomi che corrispondono a parole riservate di ActionScript, utilizzare il metodo
descendants() invece dell'operatore discendente (..) come nell'esempio seguente:
var xml:XML =
<enrollees>
<student id="239">
<class name="Algebra" />
<class name="Spanish 2"/>
</student>
<student id="206">
<class name="Trigonometry" />
<class name="Spanish 2" />
</student>
</enrollees>
trace(xml.descendants("class")); L'esempio seguente mostra che il metodo
descendants() restituisce un oggetto XMLList che contiene
tutti gli oggetti discendenti, compresi gli oggetti secondari, inferiori di due livelli e così via:
XML.ignoreComments = false;
var xml:XML =
<body>
<!-- comment -->
text1
<a>
<b>text2</b>
</a>
</body>;
trace(xml.descendants("*").length()); // 5
trace(xml.descendants("*")[0]); // // <!-- comment -->
trace(xml.descendants("*")[1].toXMLString()); // text1
trace(xml.descendants("a").toXMLString()); // <a><b>text2</b></a>
trace(xml.descendants("b").toXMLString()); // <b>text2</b>
AS3 function elements(name:Object = *):XMLList
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Elenca gli elementi di un oggetto XML. Un elemento è costituito da un tag iniziale e da un tag finale, come in <first></first>. Il parametro name è opzionale. Il parametro name può essere un oggetto QName, un tipo di dati String o qualunque altro tipo di dati che viene successivamente convertito in un tipo di dati String. Utilizzare il parametro name per elencare un elemento specifico. Nell'esempio seguente, l'elemento "first" restituisce "John": <first>John</first>.
Per elencare tutti gli elementi, utilizzare il parametro asterisco (*). L'asterisco è anche il parametro predefinito.
Utilizzare il metodo length() con il parametro asterisco per produrre il numero totale di asterischi. Ad esempio, numElement = addressbook.elements("*").length().
Parametri
| name:Object (default = *)first" è il parametro name: <first></first>.
|
Restituisce
| XMLList — Un oggetto XMLList del contenuto dell'elemento. Il contenuto dell'elemento è compreso tra il tag iniziale e il tag finale. Se si utilizza l'asterisco (*) per chiamare tutti gli elementi, vengono restituiti sia i tag che il contenuto dell'elemento.
|
Vedere anche
Esempio
L'esempio seguente mostra che il metodo
elements() restituisce solo un elenco di elementi — e non di commenti, proprietà di testo o istruzioni di elaborazione:
var xml:XML =
<foo>
<!-- comment -->
<?instruction ?>
text
<a>1</a>
<b>2</b>
</foo>;
trace(xml.elements("*").length()); // 2
trace(xml.elements("*")[0].toXMLString()); // <a>1</a>
trace(xml.elements("b").length()); // 1
trace(xml.elements("b")[0].toXMLString()); // <b>2</b> Per restituire elementi con nomi che corrispondono a parole riservate di ActionScript, utilizzare il metodo
elements() invece dell'operatore XML punto (.), come nell'esempio seguente:
var xml:XML =
<student id="206">
<class name="Trigonometry" />
<class name="Spanish 2" />
</student>
trace(xml.elements("class"));
AS3 function hasComplexContent():Boolean
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Verifica se nell'oggetto XML è presente del contenuto complesso. Un oggetto XML ha del contenuto complesso se contiene degli elementi secondari. Gli oggetti XML che rappresentano attributi, commenti, istruzioni di elaborazione e nodi di testo non hanno contenuto complesso. Tuttavia, è possibile considerare che in un oggetto che contiene questi elementi sia presente del contenuto complesso, nel caso abbia degli elementi secondari.
Restituisce
| Boolean — Se nell'oggetto XMLList è presente del contenuto complesso, viene restituito true; in caso contrario false.
|
Vedere anche
Esempio
L'esempio seguente mostra un oggetto XML con una proprietà denominata
a con contenuto semplice e una proprietà denominata
a con contenuto complesso:
var xml:XML =
<foo>
<a>
text
</a>
<a>
<b/>
</a>
</foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true
trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false
AS3 function hasOwnProperty(p:String):Boolean
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Verifica se per l'oggetto la proprietà è specificata dal parametro p.
Parametri
| p:String — La proprietà per cui deve essere trovata la corrispondenza.
|
Restituisce
| Boolean — Se la proprietà esiste, viene restituito true; in caso contrario false.
|
Vedere anche
Esempio
L'esempio seguente utilizza il metodo
hasOwnProperty() per garantire che la proprietà (
b) sia esistente prima della valutazione di un'espressione (
b == "11") che utilizza tale proprietà:
var xml:XML =
<foo>
<a />
<a>
<b>10</b>
</a>
<a>
<b>11</b>
</a>
</foo>;
trace(xml.a.(hasOwnProperty("b") && b == "11")); Se l'ultima riga dell'esempio fosse la seguente, verrebbe generata un'eccezione in Flash Player perché il primo elemento denominato
a non ha una proprietà di nome
b:
trace(xml.a.(b == "11"));
L'esempio seguente utilizza il metodo
hasOwnProperty() per garantire che la proprietà (
item) sia esistente prima della valutazione di un'espressione (
item.contains("toothbrush")) che utilizza tale proprietà:
var xml:XML =
<orders>
<order id='1'>
<item>toothbrush</item>
<item>toothpaste</item>
</order>
<order>
<returnItem>shoe polish</returnItem>
</order>
</orders>;
trace(xml.order.(hasOwnProperty("item") && item.contains("toothbrush")));
AS3 function hasSimpleContent():Boolean
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Verifica se nell'oggetto XML è presente del contenuto semplice. Un oggetto XML ha del contenuto semplice se rappresenta un nodo di testo, un nodo di attributi o un elemento XML privo di elementi secondari. Gli oggetti XML che rappresentano commenti e istruzioni di elaborazione non hanno contenuto semplice.
Restituisce
| Boolean — Se nell'oggetto XMLList è presente del contenuto semplice, viene restituito true; in caso contrario false.
|
Vedere anche
Esempio
L'esempio seguente mostra un oggetto XML con una proprietà denominata
a con contenuto semplice e una proprietà denominata
a con contenuto complesso:
var xml:XML =
<foo>
<a>
text
</a>
<a>
<b/>
</a>
</foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true
trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false
AS3 function inScopeNamespaces():Array
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Elenca gli spazi dei nomi per l'oggetto XML, in base all'elemento principale dell'oggetto.
Restituisce
| Array — Un array di oggetti Namespace.
|
Vedere anche
AS3 function insertChildAfter(child1:Object, child2:Object):*
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Inserisce il parametro child2 dopo il parametro child1 in questo oggetto XML e restituisce l'oggetto risultante. Se il parametro child1 è null, il metodo inserisce il contenuto di child2 prima di tutti gli elementi secondari dell'oggetto XML (in altre parole, dopo none). Se child1 viene fornito ma non esiste nell'oggetto XML, l'oggetto XML non viene modificato e viene restituito undefined.
Se si chiama questo metodo su un elemento XML secondario che non è un elemento (testo, attributi, commenti, pi, e così via), viene restituito undefined.
Utilizzare l'operatore delete (XML) per rimuovere i nodi XML.
Parametri
| child1:Object — L'oggetto nell'oggetto di origine che è stato inserito prima di child2.
|
| |
| child2:Object — L'oggetto da inserire.
|
Restituisce
| * — L'oggetto XML risultante oppure undefined.
|
Vedere anche
Esempio
L'esempio seguente aggiunge un elemento alla fine degli elementi secondari di un oggetto XML:
var xml:XML =
<menu>
<item>burger</item>
<item>soda</item>
</menu>;
xml.insertChildAfter(xml.item[0], <saleItem>fries</saleItem>);
trace(xml); L'output di
trace() è il seguente:
<menu>
<item>burger</item>
<saleItem>fries</saleItem>
<item>soda</item>
</menu>
AS3 function insertChildBefore(child1:Object, child2:Object):*
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Inserisce il parametro child2 prima del parametro child1 in questo oggetto XML e restituisce l'oggetto risultante. Se il parametro child1 è null, il metodo inserisce il contenuto di child2 dopo tutti gli elementi secondari dell'oggetto XML (in altre parole, prima di none). Se child1 viene fornito ma non esiste nell'oggetto XML, l'oggetto XML non viene modificato e viene restituito undefined.
Se si chiama questo metodo su un elemento XML secondario che non è un elemento (testo, attributi, commenti, pi, e così via), viene restituito undefined.
Utilizzare l'operatore delete (XML) per rimuovere i nodi XML.
Parametri
| child1:Object — L'oggetto nell'oggetto di origine che è stato inserito dopo child2.
|
| |
| child2:Object — L'oggetto da inserire.
|
Restituisce
| * — L'oggetto XML risultante oppure undefined.
|
Vedere anche
Esempio
L'esempio seguente aggiunge un elemento alla fine degli elementi secondari di un oggetto XML:
var xml:XML =
<menu>
<item>burger</item>
<item>soda</item>
</menu>;
xml.insertChildBefore(xml.bar[0], <saleItem>fries</saleItem>);
trace(xml); L'output di
trace() è il seguente:
<menu>
<saleItem>fries</saleItem>
<item>burger</item>
<item>soda</item>
</menu>
AS3 function length():int
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Per gli oggetti XML, questo metodo restituisce sempre l'intero 1. Il metodo length() della classe XMLList restituisce il valore 1 per un oggetto XMLList che contiene un solo valore.
Restituisce
| int — Restituisce sempre 1 per qualunque oggetto XML.
|
Vedere anche
AS3 function localName():Object
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Fornisce la porzione del nome locale del nome completo dell'oggetto XML.
Restituisce
| Object — Il nome locale sotto forma di oggetto String o di valore null.
|
Vedere anche
Esempio
L'esempio seguente illustra l'utilizzo del metodo
localName().
var xml:XML =
<soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">
<soap:Body xmlns:wx = "http://example.com/weather">
<wx:forecast>
<wx:city>Quito</wx:city>
</wx:forecast>
</soap:Body>
</soap:Envelope>;
trace(xml.localName()); // Envelope
AS3 function name():Object
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Fornisce il nome completo per l'oggetto XML.
Restituisce
| Object — Il nome locale sotto forma di oggetto QName o di valore null.
|
Vedere anche
Esempio
L'esempio seguente illustra l'utilizzo del metodo
name() per ottenere il nome completo di un oggetto XML:
var xml:XML =
<soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">
<soap:Body xmlns:wx = "http://example.com/weather">
<wx:forecast>
<wx:city>Quito</wx:city>
</wx:forecast>
</soap:Body>
</soap:Envelope>;
trace(xml.name().localName); // Envelope
trace(xml.name().uri); // "http://www.w3.org/2001/12/soap-envelope" L'esempio seguente illustra l'utilizzo del metodo
name() chiamato su una proprietà XML, un elemento di testo e un attributo:
var xml:XML =
<foo x="15" y="22">
text
</foo>;
trace(xml.name().localName); // foo
trace(xml.name().uri == ""); // true
trace(xml.children()[0]); // text
trace(xml.children()[0].name()); // null
trace(xml.attributes()[0]); // 15
trace(xml.attributes()[0].name()); // x
AS3 function namespace(prefix:String = null):*
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Se non viene fornito alcun parametro, fornisce lo spazio dei nomi associato al nome completo dell'oggetto XML. Se viene specificato un parametro prefix, il metodo restituisce lo spazio dei nomi che corrisponde al parametro prefix e che è nell'area di validità dell'oggetto XML. Se non viene trovato uno spazio dei nomi simile, il metodo restituisce undefined.
Parametri
| prefix:String (default = null) |
Restituisce
| * — Restituisce null, undefined o uno spazio dei nomi.
|
Vedere anche
Esempio
L'esempio seguente utilizza il metodo
namespace() per ottenere lo spazio dei nomi di un oggetto XML e assegnarlo a un oggetto Namespace denominato
soap che viene quindi utilizzato per identificare una proprietà dell'oggetto
xml (
xml.soap::Body[0]):
var xml:XML =
<soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">
<soap:Body xmlns:wx = "http://example.com/weather">
<wx:forecast>
<wx:city>Quito</wx:city>
</wx:forecast>
</soap:Body>
</soap:Envelope>;
var soap:Namespace = xml.namespace();
trace(soap.prefix); // soap
trace(soap.uri); // http://www.w3.org/2001/12/soap-envelope
var body:XML = xml.soap::Body[0];
trace(body.namespace().prefix); // soap
trace(xml.namespace().uri); // http://www.w3.org/2001/12/soap-envelope
trace(body.namespace("wx").uri); // "http://example.com/weather" L'esempio seguente utilizza il metodo
namespace() per ottenere lo spazio dei nomi di un nodo, nonché di un prefisso specifico (
"dc"):
var xml:XML =
<rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
xmlns:dc="http://purl.org/dc/elements/1.1/"
xmlns="http://purl.org/rss/1.0/">
<!-- ... -->
</rdf:RDF>;
trace(xml.namespace()); // http://www.w3.org/1999/02/22-rdf-syntax-ns#
trace(xml.namespace("dc")); // http://purl.org/dc/elements/1.1/
trace(xml.namespace("foo")); // undefined
AS3 function namespaceDeclarations():Array
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Elenca le dichiarazioni degli spazi dei nomi associate all'oggetto nel contesto del suo elemento principale.
Restituisce
| Array — Un array di oggetti Namespace.
|
Vedere anche
Esempio
L'esempio seguente genera le dichiarazioni degli spazi dei nomi di un oggetto XML:
var xml:XML =
<rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
xmlns:dc="http://purl.org/dc/elements/1.1/"
xmlns="http://purl.org/rss/1.0/">
<!-- ... -->
</rdf:RDF>;
for (var i:uint = 0; i < xml.namespaceDeclarations().length; i++) {
var ns:Namespace = xml.namespaceDeclarations()[i];
var prefix:String = ns.prefix;
if (prefix == "") {
prefix = "(default)";
}
trace(prefix + ":" , ns.uri);
} L'output di
trace() è il seguente:
rdf: http://www.w3.org/1999/02/22-rdf-syntax-ns#
dc: http://purl.org/dc/elements/1.1/
(default): http://purl.org/rss/1.0/
AS3 function nodeKind():String
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Specifica il tipo di nodo: testo, commento, istruzione di elaborazione, attributo o elemento.
Restituisce
| String — Il tipo di nodo utilizzato.
|
Vedere anche
Esempio
In questo esempio vengono tracciati tutti i cinque tipi di nodo:
XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var xml:XML =
<example id="10">
<!-- this is a comment -->
<?test this is a pi ?>
and some text
</example>;
trace(xml.nodeKind()); // element
trace(xml.children()[0].nodeKind()); // comment
trace(xml.children()[1].nodeKind()); // processing-instruction
trace(xml.children()[2].nodeKind()); // text
trace(xml.@id[0].nodeKind()); // attribute
AS3 function normalize():XML
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Per l'oggetto XML e tutti gli oggetti XML discendenti, unisce i nodi di testo adiacenti ed elimina i nodi di testo vuoti.
Restituisce
| XML — L'oggetto XML normalizzato risultante.
|
Vedere anche
Esempio
L'esempio seguente mostra l'effetto della chiamata al metodo
normalize():
var xml:XML = <body></body>;
xml.appendChild("hello");
xml.appendChild(" world");
trace(xml.children().length()); // 2
xml.normalize();
trace(xml.children().length()); // 1
AS3 function parent():*
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Restituisce l'elemento principale dell'oggetto XML. Se l'oggetto XML non ha un elemento principale, il metodo restituisce undefined.
Restituisce
| * — L'oggetto XML principale. Restituisce un oggetto String o il valore null.
|
Vedere anche
Esempio
L'esempio seguente utilizza il metodo
parent() per identificare l'elemento principale di un elemento specifico di una struttura XML:
var xml:XML =
<body>
<p id="p1">Hello</p>
<p id="p2">Test:
<ul>
<li>1</li>
<li>2</li>
</ul>
</p>
</body>;
var node:XML = xml.p.ul.(li.contains("1"))[0]; // == <ul> ... </ul>
trace(node.parent().@id); // p2
AS3 function prependChild(value:Object):XML
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Inserisce una copia dell'oggetto child fornito nell'elemento XML prima di qualunque proprietà XML esistente di tale elemento.
Utilizzare l'operatore delete (XML) per rimuovere i nodi XML.
Parametri
| value:Object — L'oggetto da inserire.
|
Restituisce
| XML — L'oggetto XML risultante.
|
Vedere anche
Esempio
L'esempio seguente utilizza il metodo
prependChild() per aggiungere un elemento all'inizio dell'elenco degli elementi secondari di un oggetto XML:
var xml:XML =
<body>
<p>hello</p>
</body>;
xml.prependChild(<p>world</p>);
trace(xml.p[0].toXMLString()); // <p>world</p>
trace(xml.p[1].toXMLString()); // <p>hello</p>
AS3 function processingInstructions(name:String = "*"):XMLList
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Se viene fornito un parametro name, elenca tutti gli elementi secondari dell'oggetto XML che contengono le istruzioni di elaborazione con tale parametro name. In assenza di parametri, il metodo elenca tutti gli elementi secondari dell'oggetto XML che contengono delle eventuali istruzioni di elaborazione.
Parametri
| name:String (default = "*") |
Restituisce
| XMLList — Un elenco di oggetti secondari corrispondenti.
|
Vedere anche
Esempio
L'esempio seguente utilizza il metodo
processingInstructions() per ottenere un array di istruzioni di elaborazione per un oggetto XML:
XML.ignoreProcessingInstructions = false;
var xml:XML =
<body>
foo
<?xml-stylesheet href="headlines.css" type="text/css" ?>
<?instructionX ?>
</body>;
trace(xml.processingInstructions().length()); // 2
trace(xml.processingInstructions()[0].name()); // xml-stylesheet
AS3 function propertyIsEnumerable(p:String):Boolean
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Verifica se la proprietà p fa parte del gruppo di proprietà di cui è possibile eseguire l'iterazione in un'istruzione for..in applicata all'oggetto XML. Restituisce true solo se toString(p) == "0".
Parametri
| p:String — La proprietà da verificare.
|
Restituisce
| Boolean — Se della proprietà è possibile effettuare l'iterazione in un'istruzione for..in, viene restituito true; in caso contrario false.
|
Vedere anche
Esempio
L'esempio seguente mostra che il metodo
propertyNameIsEnumerable() restituisce, per un oggetto XML,
true solo per il valore
0, mentre per un oggetto XMLList, il valore restituito è
true per ogni valore di indice valido per l'oggetto XMLList:
var xml:XML =
<body>
<p>Hello</p>
<p>World</p>
</body>;
trace(xml.propertyIsEnumerable(0)); // true
trace(xml.propertyIsEnumerable(1)); // false
for (var propertyName:String in xml) {
trace(xml[propertyName]);
}
var list:XMLList = xml.p;
trace(list.propertyIsEnumerable(0)); // true
trace(list.propertyIsEnumerable(1)); // true
trace(list.propertyIsEnumerable(2)); // false
for (var propertyName:String in list) {
trace(list[propertyName]);
}
AS3 function removeNamespace(ns:Namespace):XML
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Rimuove lo spazio dei nomi dato per l'oggetto e tutti i suoi elementi discendenti. Il metodo removeNamespaces() non rimuove uno spazio dei nomi se a esso fa riferimento il nome completo dell'oggetto o il nome completo degli attributi dell'oggetto.
Parametri
| ns:Namespace — Lo spazio dei nomi da rimuovere.
|
Restituisce
| XML — Una copia dell'oggetto XML risultante.
|
Vedere anche
Esempio
L'esempio seguente mostra come rimuovere una dichiarazione dello spazio dei nomi da un oggetto XML:
var xml:XML =
<rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
xmlns:dc="http://purl.org/dc/elements/1.1/"
xmlns="http://purl.org/rss/1.0/">
<!-- ... -->
</rdf:RDF>;
trace(xml.namespaceDeclarations().length); // 3
trace(xml.namespaceDeclarations()[0] is String); //
var dc:Namespace = xml.namespace("dc");
xml.removeNamespace(dc);
trace(xml.namespaceDeclarations().length); // 2
AS3 function replace(propertyName:Object, value:XML):XML
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Sostituisce le proprietà specificate dal parametro propertyName con il parametro value dato. Se nessuna proprietà corrisponde a propertyName, l'oggetto XML viene lasciato invariato.
Parametri
| propertyName:Object — Può essere un valore numerico, un nome non completo per un gruppo di elementi XML, un nome completo per un gruppo di elementi XML o il carattere jolly asterisco ("*"). Utilizzare un nome non completo per identificare gli elementi XML nello spazio dei nomi predefinito.
|
| |
| value:XML — Il valore sostitutivo. Può essere un oggetto XML, un oggetto XMLList o qualunque valore che può essere convertito con toString().
|
Restituisce
| XML — L'oggetto XML risultante, con le proprietà corrispondenti sostituite.
|
Vedere anche
Esempio
L'esempio seguente mostra la chiamata al metodo
replace() con un numero intero come primo parametro:
var xml:XML =
<body>
<p>Hello</p>
<p>World</p>
<hr/>
</body>;
xml.replace(1, <p>Bob</p>);
trace(xml); Il risultato è l'output di
trace() che segue:
<body>
<p>Hello</p>
<p>Bob</p>
<hr/>
</body>
L'esempio seguente chiama il metodo
replace() con una stringa come primo parametro:
var xml:XML =
<body>
<p>Hello</p>
<p>World</p>
<hr/>
</body>;
xml.replace("p", <p>Hi</p>);
trace(xml); Il risultato è l'output di
trace() che segue:
<body>
<p>Hi</p>
<hr/>
</body>;
L'esempio seguente mostra la chiamata al metodo
replace() con QName come primo parametro:
var xml:XML =
<ns:body xmlns:ns = "myNS">
<ns:p>Hello</ns:p>
<ns:p>World</ns:p>
<hr/>
</ns:body>;
var qname:QName = new QName("myNS", "p");
xml.replace(qname, <p>Bob</p>);
trace(xml);
Il risultato è l'output di
trace() che segue:
<ns:body xmlns:ns = "myNS">
<p>Bob</p>
<hr/>
</ns:body>
L'esempio seguente mostra la chiamata al metodo
replace() con la stringa
"*" come primo parametro:
var xml:XML =
<body>
<p>Hello</p>
<p>World</p>
<hr/>
</body>;
xml.replace("*", <img src = "hello.jpg"/>);
trace(xml); Il risultato è l'output di
trace() che segue:
<body>
<img src="hello.jpg"/>
</body>
AS3 function setChildren(value:Object):XML
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Sostituisce le proprietà secondarie dell'oggetto XML con il gruppo specificato di proprietà XML fornito nel parametro value.
Parametri
| value:Object — Le proprietà XML sostitutive. Può essere un oggetto XML singolo o un oggetto XMLList.
|
Restituisce
| XML — L'oggetto XML risultante.
|
Vedere anche
Esempio
L'esempio seguente mostra la chiamata al metodo
setChildren(), prima con un oggetto XML come parametro e quindi con un oggetto XMLList:
var xml:XML =
<body>
<p>Hello</p>
<p>World</p>
</body>;
var list:XMLList = xml.p;
xml.setChildren(<p>hello</p>);
trace(xml);
// <body>
// <p>hello</p>
// </body>
xml.setChildren(list);
trace(xml);
// <body>
// <p>Hello</p>
// <p>World</p>
// </body>
AS3 function setLocalName(name:String):void
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Sostituisce il nome locale dell'oggetto XML con il parametro name dato.
Parametri
| name:String — Il nome sostitutivo per il nome locale.
|
Vedere anche
Esempio
L'esempio seguente utilizza il metodo
setLocalName() per modificare il nome locale di un elemento XML:
var xml:XML =
<ns:item xmlns:ns="http://example.com">
toothbrush
</ns:item>;
xml.setLocalName("orderItem");
trace(xml.toXMLString()); // <ns:orderItem xmlns:ns="http://example.com">toothbrush</ns:orderItem>
AS3 function setName(name:String):void
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Imposta il nome dell'oggetto XML sul nome completo o sul nome di attributo dato.
Parametri
| name:String — Il nuovo nome per l'oggetto.
|
Vedere anche
Esempio
L'esempio seguente utilizza il metodo
setName() per modificare il nome di un elemento XML:
var xml:XML =
<item>
toothbrush
</item>;
xml.setName("orderItem");
trace(xml.toXMLString()); // <orderItem>toothbrush</orderItem>
AS3 function setNamespace(ns:Namespace):void
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Imposta lo spazio dei nomi associato all'oggetto XML.
Parametri
Vedere anche
Esempio
L'esempio seguente utilizza lo spazio dei nomi
soap definito in un oggetto XML e lo applica allo spazio dei nomi di un altro oggetto XML (
xml2):
var xml1:XML =
<soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">
<!-- ... -->
</soap:Envelope>;
var ns:Namespace = xml1.namespace("soap");
var xml2:XML =
<Envelope>
<Body/>
</Envelope>;
xml2.setNamespace(ns);
trace(xml2);
AS3 static function setSettings(... rest):void
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Imposta i valori per le proprietà XML seguenti: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent e prettyPrinting. Di seguito sono indicate le proprietà predefinite, che vengono applicate se non viene fornito alcun parametro setObj:
XML.ignoreComments = trueXML.ignoreProcessingInstructions = trueXML.ignoreWhitespace = trueXML.prettyIndent = 2XML.prettyPrinting = true
Nota: questo metodo non va applicato a un'istanza della classe XML, bensì a XML, come nel codice XML.setSettings().
Parametri
| ... rest — Un oggetto con ognuna delle seguenti proprietà:
ignoreCommentsignoreProcessingInstructionsignoreWhitespaceprettyIndentprettyPrinting
|
Vedere anche
Esempio
L'esempio seguente illustra come applicare alcune impostazioni personalizzate (per inserire commenti e istruzioni di elaborazione) prima di impostare un oggetto XML, ripristinare le impostazioni predefinite prima di impostare un altro oggetto XML e quindi reimpostare le impostazioni personalizzate (per impostare eventuali oggetti XML aggiuntivi):
XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();
var xml1:XML =
<foo>
<!-- comment -->
<?instruction ?>
</foo>;
trace(xml1.toXMLString());
// <foo>
// <!-- comment -->
// <?instruction ?>
// </foo>
XML.setSettings(XML.defaultSettings());
var xml2:XML =
<foo>
<!-- comment -->
<?instruction ?>
</foo>;
trace(xml2.toXMLString());
AS3 static function settings():Object
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Recupera le proprietà seguenti: ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent e prettyPrinting.
Restituisce
| Object — Un oggetto con le seguenti proprietà:
ignoreCommentsignoreProcessingInstructionsignoreWhitespaceprettyIndentprettyPrinting
|
Vedere anche
Esempio
L'esempio seguente illustra come applicare alcune impostazioni personalizzate (per inserire commenti e istruzioni di elaborazione) prima di impostare un oggetto XML, ripristinare le impostazioni predefinite prima di impostare un altro oggetto XML e quindi reimpostare le impostazioni personalizzate (per impostare eventuali oggetti XML aggiuntivi):
XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();
var xml1:XML =
<foo>
<!-- comment -->
<?instruction ?>
</foo>;
trace(xml1.toXMLString());
// <foo>
// <!-- comment -->
// <?instruction ?>
// </foo>
XML.setSettings(XML.defaultSettings());
var xml2:XML =
<foo>
<!-- comment -->
<?instruction ?>
</foo>;
trace(xml2.toXMLString());
AS3 function text():XMLList
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Restituisce un oggetto XMLList di tutte le proprietà XML dell'oggetto XML che rappresentano i nodi di testo XML.
Restituisce
| XMLList — L'elenco delle proprietà.
|
Vedere anche
Esempio
L'esempio seguente utilizza il metodo
text() per ottenere i nodi di testo di un oggetto XML:
var xml:XML =
<body>
text1
<hr/>
text2
</body>;
trace(xml.text()[0]); // text1
trace(xml.text()[1]); // text2
AS3 function toString():String
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Restituisce la rappresentazione in formato stringa dell'oggetto XML. Le regole per questa conversione dipendono dal fatto che nell'oggetto XML sia presente del contenuto complesso o del contenuto semplice:
- Se nell'oggetto XML è presente del contenuto semplice,
toString() restituisce il contenuto di formato String dell'oggetto XML senza gli elementi seguenti: il tag iniziale, gli attributi, le dichiarazioni degli spazi dei nomi e il tag finale.
- Se nell'oggetto XML è presente del contenuto complesso,
toString() restituisce un oggetto String con codifica XML che rappresenta l'intero oggetto XML, compresi il tag iniziale, gli attributi, le dichiarazioni degli spazi dei nomi e il tag finale.
Per restituire ogni volta l'intero oggetto XML, utilizzare toXMLString().
Restituisce
| String — La rappresentazione in formato stringa dell'oggetto XML.
|
Vedere anche
Esempio
L'esempio seguente mostra il risultato del metodo
toString() quando nell'oggetto XML è presente del contenuto semplice:
var test:XML = <type name="Joe">example</type>;
trace(test.toString()); //example
L'esempio seguente mostra il risultato del metodo
toString() quando nell'oggetto XML è presente del contenuto complesso:
var test:XML =
<type name="Joe">
<base name="Bob"></base>
example
</type>;
trace(test.toString());
// <type name="Joe">
// <base name="Bob"/>
// example
// </type>
AS3 function toXMLString():String
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Restituisce la rappresentazione in formato stringa dell'oggetto XML. A differenza del metodo toString(), il metodo toXMLString() restituisce sempre il tag iniziale, gli attributi e il tag finale dell'oggetto XML, a prescindere dal contenuto (semplice o complesso) dell'oggetto XML. (Il metodo toString() esclude questi elementi negli oggetti XML con contenuto semplice.)
Restituisce
| String — La rappresentazione in formato stringa dell'oggetto XML.
|
Vedere anche
Esempio
L'esempio seguente mostra la differenza tra l'uso del metodo
toString(), applicato per impostazione predefinita a tutti i parametri del metodo
trace(), e l'uso del metodo
toXMLString():
var xml:XML =
<p>hello</p>;
trace(xml); // hello
trace(xml.toXMLString()); // <p>hello</p>
AS3 function valueOf():XML
| Versione linguaggio: | ActionScript 3.0 |
| Versione lettore: | Flash Player 9 |
Restituisce l'oggetto XML.
Restituisce
| XML — Il valore di base di un'istanza XML.
|
Vedere anche
Esempio
L'esempio seguente mostra che il valore restituito dal metodo
valueOf() è lo stesso dell'oggetto XML di origine:
var xml:XML = <p>hello</p>;
trace(xml.valueOf() === xml); // true
L'esempio seguente crea innanzitutto una variabile XML e quindi vi aggiunge dei nodi. Quindi, vengono utilizzate le proprietà XML per trovare e stampare i nodi XML. Si noti che il simbolo (
@) viene utilizzato in numerose chiamate
trace() per trovare informazioni in base al nome dell'attributo.
package {
import flash.display.Sprite;
public class XmlExample extends Sprite {
public function XmlExample() {
var employees:XML =
<employees>
<employee ssn="123-123-1234">
<name first="John" last="Doe"/>
<address>
<street>11 Main St.</street>
<city>San Francisco</city>
<state>CA</state>
<zip>98765</zip>
</address>
</employee>
<employee ssn="789-789-7890">
<name first="Mary" last="Roe"/>
<address>
<street>99 Broad St.</street>
<city>Newton</city>
<state>MA</state>
<zip>01234</zip>
</address>
</employee>
</employees>;
trace(employees.employee[0].address.zip); // 98765
trace(employees.employee[1].@ssn); // 789-789-7890
trace(employees.employee.name); // <name first="John" last="Doe"/>
// <name first="Mary" last="Roe"/>
trace(employees..zip[0]); // 98765
trace(employees..@ssn[1]); // 789-789-7890
trace(employees..name); // <name first="John" last="Doe"/>
// <name first="Mary" last="Roe"/>
trace(employees.employee[0].address.*); // <street>11 Main St.</street>
// <city>San Francisco</city>
// <state>CA</state>
// <zip>98765</zip>
var node:String = "zip";
trace(employees.employee[0].address[node]); // 98765
var attribute:String = "ssn";
trace(employees.employee[1].@[attribute]); // 789-789-7890
for each (var num:XML in employees..@ssn) {
trace(num); // 123-123-1234
} // 789-789-7890
var ssnToFind:String = "789-789-7890";
trace(employees.employee.(@ssn == ssnToFind).toXMLString());
// <employee ssn="789-789-7890">
// <name first="Mary" last="Roe"/>
// <address>
// <street>99 Broad St.</street>
// <city>Newton</city>
// <state>MA</state>
// <zip>01234</zip>
// </address>
// </employee>
}
}
}
© 2004-2007 Adobe Systems Incorporated. All rights reserved.
Fri Oct 12 2007, 3:14 AM GMT-07:00
Pagina corrente: http://livedocs.adobe.com/flash/9.0_it/ActionScriptLangRefV3/XML.html
Object
Nascondi proprietà pubbliche ereditate
Mostra proprietà pubbliche ereditate