Il giorno del mese (un numero intero compreso tra 1 e 31) specificato dall'oggetto Date, in base all'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

Vedere anche

Il giorno del mese (un numero intero compreso tra 1 e 31) di un oggetto Date, in base all'ora universale (UTC).

Vedere anche

Il giorno della settimana (0 per domenica, 1 per lunedì, e così via) specificato dall'oggetto Date, in base all'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

Vedere anche

Il giorno della settimana (0 per domenica, 1 per lunedì, e così via) dell'oggetto Date, in base all'ora universale (UTC).

Vedere anche

L'anno completo (un numero di quattro cifre, ad esempio 2000) specificato dall'oggetto Date, in base all'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

Vedere anche

L'anno completo a quattro cifre di un oggetto Date, in base all'ora universale (UTC).

Vedere anche

L'ora (un numero intero compreso tra 0 e 23) della porzione del giorno di un oggetto Date, in base all'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

Vedere anche

L'ora (un numero intero compreso tra 0 e 23) del giorno di un oggetto Date, in base all'ora universale (UTC).

Vedere anche

La porzione dei millisecondi (un numero intero compreso tra 0 e 999) di un oggetto Date, in base all'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

Vedere anche

La porzione dei millisecondi (un numero intero compreso tra 0 e 999) di un oggetto Date, in base all'ora universale (UTC).

Vedere anche

La porzione dei minuti (un numero intero compreso tra 0 e 59) di un oggetto Date, in base all'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

Vedere anche

La porzione dei minuti (un numero intero compreso tra 0 e 59) di un oggetto Date, in base all'ora universale (UTC).

Vedere anche

La porzione del mese (0 per gennaio, 1 per febbraio, e così via) di un oggetto Date, in base all'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

Vedere anche

La porzione del mese (da 0 per gennaio a 11 per dicembre) di un oggetto Date in base all'ora universale (UTC).

Vedere anche

La porzione dei secondi (un numero intero compreso tra 0 e 59) di un oggetto Date, in base all'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

Vedere anche

La porzione dei secondi (un numero intero compreso tra 0 e 59) di un oggetto Date, in base all'ora universale (UTC).

Vedere anche

Il numero di millisecondi trascorsi a partire dalla mezzanotte del 1 gennaio 1970 (ora universale) per un oggetto Date. Utilizzare questo metodo per rappresentare un istante specifico nel tempo in cui confrontare due o più oggetti Date.

Vedere anche

La differenza, espressa in minuti, tra l'ora universale (UTC) e l'ora locale del computer. In particolare, questo valore è il numero di minuti che è necessario aggiungere all'ora locale del computer in modo che corrisponda all'ora universale (UTC). Se l'ora del computer è successiva all'ora universale, il valore è negativo.

Vedere anche

Crea un nuovo oggetto Date che contiene la data e l'ora specificate.

La funzione di costruzione Date() richiede fino a sette parametri (year, month, ..., millisecond) per specificare una data e un'ora al millisecondo. La data contenuta nell'oggetto Date appena creato dipende dal numero e dal tipo di dati degli argomenti passati.

• Se non si passano argomenti, all'oggetto Date vengono assegnate la data e l'ora correnti.
• Se si passa un solo argomento di tipo Number, all'oggetto Date viene assegnato un valore temporale basato sul numero di millisecondi trascorsi a partire dal 1 gennaio 1970 0:00:000 GMT, come specificato nell'unico argomento.
• Se si passa un solo argomento di tipo String e la stringa contiene una data valida, l'oggetto Date contiene un valore temporale basato su tale data.
• Se si passano due o più argomenti, all'oggetto Date viene assegnato un valore temporale basato sui valori dell'argomento passati, che rappresentano l'anno, il mese, la data, l'ora, il minuto, il secondo e i millisecondi della data.

Se si passa una stringa alla funzione di costruzione della classe Date, la data può avere una vasta gamma di formati ma come minimo deve includere il mese, la data e l'anno. Ad esempio, Feb 1 2005 è valido, mentre Feb 2005 non lo è. L'elenco seguente indica alcuni dei formati validi:

• Giorno Mese Data Ore:Minuti:Secondi GMT Anno (ad esempio, "Tue Feb 1 00:00:00 GMT-0800 2005", che corrisponde a toString())
• Giorno Mese Data Anno Ore:Minuti:Secondi AM/PM (ad esempio, "Tue Feb 1 2005 12:00:00 AM", che corrisponde a toLocaleString())
• Giorno Mese Data Anno (ad esempio, "Tue Feb 1 2005", che corrisponde a toDateString())
• Mese/Giorno/Anno (ad esempio, "02/01/2005")

Vedere anche

Restituisce il giorno del mese (un numero intero compreso tra 1 e 31) specificato dall'oggetto Date, in base all'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

Vedere anche

package {
    import flash.display.Sprite;

    public class DateExample extends Sprite {

        public function DateExample() {
            var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
            trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
            trace(someBirthday.getDate()); // 30
        }
    }
}

Restituisce il giorno della settimana (0 per domenica, 1 per lunedì, e così via) specificato dall'oggetto Date, in base all'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                       // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDay());            // 6
trace(weekDayLabels[someBirthday.getDay()]); // Saturday

Restituisce l'anno completo (un numero di quattro cifre, ad esempio 2000) specificato dall'oggetto Date, in base all'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

Restituisce l'ora (un numero intero compreso tra 0 e 23) della porzione del giorno specificata da un oggetto Date, in base all'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}

Restituisce la porzione dei millisecondi (un numero intero compreso tra 0 e 999) specificata dall'oggetto Date, in base all'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

var now:Date = new Date();
trace(now.getMilliseconds());

Restituisce la porzione dei minuti (un numero intero compreso tra 0 e 59) specificata dall'oggetto Date, in base all'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

Restituisce la porzione del mese (0 per gennaio, 1 per febbraio, e così via) specificata dall'oggetto Date, in base all'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

Restituisce la porzione dei secondi (un numero intero compreso tra 0 e 59) specificata dall'oggetto Date, in base all'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

var now:Date = new Date();
trace(now.getSeconds());

Restituisce il numero di millisecondi trascorsi a partire dalla mezzanotte del 1 gennaio 1970 (ora universale) per un oggetto Date. Utilizzare questo metodo per rappresentare un istante specifico nel tempo in cui confrontare due o più oggetti Date.

Nota: il metodo getTime() incorpora gli anni bisestili, in modo che l'esecuzione di operazioni aritmetiche con gli oggetti Date non richieda logica aggiuntiva per le modifiche relative all'anno bisestile.

var mlk:Date = new Date(1929, 0, 15);
trace(mlk);           // Tue Jan 15 00:00:00 GMT-0800 1929
trace(mlk.getTime()); // -1292601600000

var now:Date = new Date();
trace(now);
trace(DateMath.addSeconds(now, 30));
trace(DateMath.addMinutes(now, 30));
trace(DateMath.addHours(now, 6));
trace(DateMath.addDays(now, 30));
trace(DateMath.addWeeks(now, 4));

class DateMath {
    public static function addWeeks(date:Date, weeks:Number):Date {
        return addDays(date, weeks*7);
    }

    public static function addDays(date:Date, days:Number):Date {
        return addHours(date, days*24);
    }

    public static function addHours(date:Date, hrs:Number):Date {
        return addMinutes(date, hrs*60);
    }

    public static function addMinutes(date:Date, mins:Number):Date {
        return addSeconds(date, mins*60);
    }

    public static function addSeconds(date:Date, secs:Number):Date {
        var mSecs:Number = secs * 1000;
        var sum:Number = mSecs + date.getTime();
        return new Date(sum);
    }
}

Restituisce la differenza, espressa in minuti, tra l'ora universale (UTC) e l'ora locale del computer.

var date:Date = new Date();
trace(date.getTimezoneOffset() / 60);

Restituisce il giorno del mese (un numero intero compreso tra 1 e 31) di un oggetto Date, in base all'ora universale (UTC).

Vedere anche

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);             // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

Restituisce il giorno della settimana (0 per domenica, 1 per lunedì, e così via) dell'oggetto Date, in base all'ora universale (UTC).

Vedere anche

var weekDayLabels:Array = new Array("Sunday",
                    "Monday",
                    "Tuesday",
                    "Wednesday",
                    "Thursday",
                    "Friday",
                    "Saturday");

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDay()); // 6
trace(weekDayLabels[someBirthday.getUTCDay()]); // Saturday

Restituisce l'anno completo (un numero di quattro cifre) di un oggetto Date, in base all'ora universale (UTC).

Vedere anche

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);                 // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

Restituisce l'ora (un numero intero compreso tra 0 e 23) del giorno di un oggetto Date, in base all'ora universale (UTC).

Vedere anche

var someBirthday:Date = new Date(1974, 10, 30, 15, 5);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:5

var localTime:String = getUSClockTime(someBirthday.getHours(), someBirthday.getMinutes());
trace(localTime);    // 03:05 PM

var utcTime:String = getUSClockTime(someBirthday.getUTCHours(), someBirthday.getUTCMinutes());
trace(utcTime);      // 11:05 PM

function getUSClockTime(hrs:uint, mins:uint):String {
    var modifier:String = "PM";
    var minLabel:String = doubleDigitFormat(mins);

    if(hrs > 12) {
        hrs = hrs-12;
    } else if(hrs == 0) {
        modifier = "AM";
        hrs = 12;
    } else if(hrs < 12) {
        modifier = "AM";
    }

    return (doubleDigitFormat(hrs) + ":" + minLabel + " " + modifier);
}

function doubleDigitFormat(num:uint):String {
    if(num < 10) {
        return ("0" + num);
    }
    return num;
}

Restituisce la porzione dei millisecondi (un numero intero compreso tra 0 e 999) di un oggetto Date, in base all'ora universale (UTC).

var now:Date = new Date();
trace(now.getUTCMilliseconds());

Restituisce la porzione dei minuti (un numero intero compreso tra 0 e 59) di un oggetto Date, in base all'ora universale (UTC).

var now:Date = new Date();
trace(now.getUTCMinutes());

Restituisce la porzione del mese (da 0 per gennaio a 11 per dicembre) di un oggetto Date in base all'ora universale (UTC).

Vedere anche

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(now.getUTCMonth());
trace(monthLabels[now.getUTCMonth()]);

Restituisce la porzione dei secondi (un numero intero compreso tra 0 e 59) di un oggetto Date, in base all'ora universale (UTC).

var now:Date = new Date();
trace(now.getUTCSeconds());

Converte una stringa che rappresenta una data in un numero uguale al numero di millisecondi trascorsi a partire dal 1 gennaio 1970 UTC.

Parametri

     Gio Mes GG HH:MM:SS TZD AAAA
     

     Mer Apr 12 15:30:17 GMT-0700 2006.
     

     MM/GG/AAAA HH:MM:SS TZD HH:MM:SS TZD Gio Mes/GG/AAAA Mes GG AAAA HH:MM:SS TZD Gio Mes GG HH:MM:SS TZD AAAA Gio GG Mes HH:MM:SS TZD AAAA Mes/GG/AAAA HH:MM:SS TZD AAAA/MM/GG HH:MM:SS TZD
     

Vedere anche

var dateParsed:String = "Sat Nov 30 1974";

var milliseconds:Number = Date.parse(dateParsed);
trace(milliseconds); // 155030400000

Imposta il giorno del mese, in base all'ora locale, e restituisce il nuovo valore, espresso in millisecondi. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

Parametri

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);            // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getDate()); // 30

someBirthday.setDate(20);
trace(someBirthday.getDate()); // 20

Imposta l'anno, in base all'ora locale, e restituisce il nuovo valore, espresso in millisecondi. Se i parametri month e day vengono specificati, vengono impostati sull'ora locale. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

Se si chiama questo metodo, gli altri campi dell'oggetto Date non vengono modificati, ma è possibile che Date.getUTCDay() e Date.getDay() riportino un nuovo valore se il giorno della settimana cambia come conseguenza della chiamata a questo metodo.

Parametri

Vedere anche

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday);           // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getFullYear()); // 1974

someBirthday.setFullYear(2000);
trace(someBirthday.getFullYear()); // 2000

Imposta l'ora, in base all'ora locale, e restituisce il nuovo valore, espresso in millisecondi. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

Parametri

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 15:20

someBirthday.setHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes()); // 12:20

Imposta i millisecondi, in base all'ora locale, e restituisce il nuovo valore, espresso in millisecondi. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

Parametri

var now:Date = new Date();
trace(now);
trace(now.getMilliseconds());

var before:Date = new Date(now.setMilliseconds(4));
trace(before);
trace(before.getMilliseconds());

Imposta i minuti, in base all'ora locale, e restituisce il nuovo valore, espresso in millisecondi. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

Parametri

var now:Date = new Date();
trace(now);
trace(now.getMinutes());

var before:Date = new Date(now.setMinutes(0));
trace(before);
trace(before.getMinutes());

Imposta il mese e opzionalmente il giorno del mese, in base all'ora locale, e restituisce il nuovo valore, espresso in millisecondi. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

Parametri

var monthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getMonth());
trace(monthLabels[now.getMonth()]);

now.setMonth(0);
trace(now.getMonth());             // 0
trace(monthLabels[now.getMonth()]); // January

Imposta i secondi, in base all'ora locale, e restituisce il nuovo valore, espresso in millisecondi. La data e l'ora locali vengono determinate in base al sistema operativo su cui Flash Player è in esecuzione.

Parametri

var now:Date = new Date();
trace(now.getSeconds());

now.setSeconds(0);
trace(now.getSeconds()); // 0

Imposta la data, espressa in millisecondi, rispetto alla mezzanotte del 1 gennaio 1970, e restituisce il nuovo valore, espresso in millisecondi.

Parametri

var now:Date = new Date();
trace(now);

now.setTime(-1292601600000);
trace(now); // Tue Jan 15 00:00:00 GMT-0800 1929

Imposta il giorno del mese, in base all'ora universale (UTC), e restituisce il nuovo valore, espresso in millisecondi. Se si chiama questo metodo, gli altri campi di un oggetto Date non vengono modificati, ma è possibile che Date.getUTCDay() e Date.getDay() riportino un nuovo valore se il giorno della settimana cambia come conseguenza della chiamata a questo metodo.

Parametri

Vedere anche

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCDate()); // 30

someBirthday.setUTCDate(1);
trace(someBirthday); // Fri Nov 1 01:20:00 GMT-0800 1974

Imposta l'anno, in base all'ora universale (UTC), e restituisce il nuovo valore, espresso in millisecondi.

Facoltativamente, questo metodo può anche impostare il mese e il giorno del mese. Se si chiama questo metodo, gli altri campi vengono modificati, ma è possibile che i metodi Date.getUTCDay() e Date.getDay() riportino un nuovo valore se il giorno della settimana cambia come conseguenza della chiamata a questo metodo.

Parametri

Vedere anche

var someBirthday:Date = new Date(1974, 10, 30, 1, 20);
trace(someBirthday); // Sat Nov 30 01:20:00 GMT-0800 1974
trace(someBirthday.getUTCFullYear()); // 1974

someBirthday.setUTCFullYear(1975);
trace(someBirthday); // Thu Nov 30 01:20:00 GMT-0800 1975

Imposta l'ora, in base all'ora universale (UTC), e restituisce il nuovo valore, espresso in millisecondi. Facoltativamente, è possibile specificare i minuti, i secondi e i millisecondi.

Parametri

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);

trace(someBirthday); // Sat Nov 30 15:20:00 GMT-0800 1974
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 15:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 23:20

someBirthday.setUTCHours(12);
trace(someBirthday.getHours() + ":" + someBirthday.getMinutes());     // 4:20
trace(someBirthday.getUTCHours() + ":" + someBirthday.getUTCMinutes()); // 12:20

Imposta i millisecondi, in base all'ora universale (UTC), e restituisce il nuovo valore, espresso in millisecondi.

Parametri

var now:Date = new Date();
trace(now);
trace(now.getUTCMilliseconds());

var before:Date = new Date(now.setUTCMilliseconds(4));
trace(before);
trace(before.getUTCMilliseconds());

Imposta i minuti, in base all'ora universale (UTC), e restituisce il nuovo valore, espresso in millisecondi. Facoltativamente, è possibile specificare i secondi e i millisecondi.

Parametri

var now:Date = new Date();
trace(now);
trace(now.getUTCMinutes());

var before:Date = new Date(now.setUTCMinutes(0));
trace(before);
trace(before.getUTCMinutes());

Imposta il mese e facoltativamente il giorno, in base all'ora universale (UTC), e restituisce il nuovo valore, espresso in millisecondi. Se si chiama questo metodo, gli altri campi non vengono modificati, ma è possibile che i metodi Date.getUTCDay() e Date.getDay() riportino un nuovo valore se il giorno della settimana cambia come conseguenza della chiamata a questo metodo.

Parametri

Vedere anche

var UTCMonthLabels:Array = new Array("January",
                  "February",
                  "March",
                  "April",
                  "May",
                  "June",
                  "July",
                  "August",
                  "September",
                  "October",
                  "November",
                  "December");

var now:Date = new Date();
trace(now.getUTCMonth());
trace(UTCMonthLabels[now.getUTCMonth()]);

now.setUTCUTCMonth(0);
trace(now.getUTCMonth());              // 0
trace(UTCMonthLabels[now.getUTCMonth()]); // January

Imposta i secondi e facoltativamente i millisecondi, in base all'ora universale (UTC), e restituisce il nuovo valore, espresso in millisecondi.

Parametri

var now:Date = new Date();
trace(now.getUTCSeconds());

now.setUTCSeconds(0);
trace(now.getUTCSeconds()); // 0

Restituisce una rappresentazione in formato stringa solo del giorno e della data, e non include l'ora o il fuso orario. In contrasto con i metodi seguenti:

• Date.toTimeString(), che restituisce solo l'ora e il fuso orario
• Date.toString(), che restituisce non solo il giorno e la data, ma anche l'ora e il fuso orario.

Vedere anche

var now:Date = new Date();
trace(now);
trace(now.toDateString());

Restituisce una rappresentazione in formato stringa solo del giorno e della data, e non include l'ora o il fuso orario. Questo metodo restituisce lo stesso valore di Date.toDateString. In contrasto con i metodi seguenti:

• Date.toTimeString(), che restituisce solo l'ora e il fuso orario
• Date.toString(), che restituisce non solo il giorno e la data, ma anche l'ora e il fuso orario.

Vedere anche

Restituisce una rappresentazione in formato stringa del giorno, della data e dell'ora in base all'ora locale. In contrasto con il metodo Date.toString(), che restituisce le stesse informazioni (con l'aggiunta del fuso orario) con l'anno indicato alla fine della stringa.

Restituisce una rappresentazione in formato stringa solo dell'ora, e non include il giorno, la data o il fuso orario. In contrasto con il metodo Date.toTimeString(), che restituisce l'ora e il fuso orario.

Vedere anche

Restituisce una rappresentazione in formato stringa del giorno, della data, dell'ora e del fuso orario. Il formato data per l'output è:

     Gio Mes Data HH:MM:SS TZD AAAA
     

Ad esempio:

     Mer Apr 12 15:30:17 GMT-0700 2006.
     

var now:Date = new Date();
trace(now);

Restituisce una rappresentazione in formato stringa solo dell'ora o del fuso orario, e non include il giorno e la data. In contrasto con il metodo Date.toDateString(), che restituisce solo il giorno e la data.

Vedere anche

Restituisce una rappresentazione in formato stringa del giorno, della data e dell'ora in base all'ora universale (UTC). Ad esempio, la data 1 febbraio 2005 viene restituita come Tue Feb 1 00:00:00 2005 UTC.

Vedere anche

Restituisce il numero di millisecondi trascorsi tra la mezzanotte del 1 gennaio 1970 (ora universale) e il tempo specificato nei parametri. Questo metodo utilizza l'ora universale, mentre la funzione di costruzione Date utilizza l'ora locale.

Questo metodo è utile se si desidera passare una data UTC alla funzione di costruzione della classe Date. Poiché la funzione di costruzione della classe Date accetta l'offset dei millisecondi come argomento, è possibile utilizzare il metodo Date.UTC() per convertire una data UTC nell'offset dei millisecondi corrispondente e inviare tale offset come argomento alla funzione di costruzione della classe Date:

Parametri

var someBirthday:Date = new Date(1974, 10, 30, 15, 20);
trace(someBirthday.toString());

someBirthday.setTime(Date.UTC(1974, 10, 30, 15, 20));
trace(someBirthday.toString());

Restituisce il numero di millisecondi trascorsi a partire dalla mezzanotte del 1 gennaio 1970 (ora universale) per un oggetto Date.

var now:Date = new Date();
trace(now.getTime());
trace(now.valueOf());

• myDate1 chiama Date() senza parametri, che imposta myDate1 sulla data e ora correnti (in base alla data e ora del sistema in uso).
• myDate2 chiama Date() passando i parametri year (2000), month (0 = gennaio) e day (1).
• myDate3 chiama Date() passando i parametri year (65 = 1965), month (2 = marzo), day (6), hour (9), minute (30), second (15) e millisecond -+ (0).
• myDate4 chiama Date() con il valore dell'ora rappresentato dal numero di millisecondi prima (dato che il valore è negativo) delle 0:00:00 GMT del 1 gennaio 1970.

package {
    import flash.display.Sprite;
    
    public class DateExample extends Sprite{
        public function DateExample() {
            var myDate1:Date = new Date();
            trace(myDate1); // [NOW]

            var myDate2:Date = new Date(2000, 0, 1);
            trace(myDate2); // Sat Jan 1 00:00:00 GMT-0800 2000

            var myDate3:Date = new Date(65, 2, 6, 9, 30, 15, 0);
            trace(myDate3); // Sat Mar 6 09:30:15 GMT-0800 1965

            var myDate4:Date = new Date(-14159025000);
            trace(myDate4); // Sun Jul 20 19:56:15 GMT-0700 1969
        }        
    }    
}