Contrôle de la lecture de la vidéo -- Flash CS3

La classe NetStream comporte quatre méthodes principales pour contrôler la lecture vidéo :

pause() : interrompt la lecture d'un flux vidéo. Si la lecture de la vidéo est déjà en pause, l'appel de cette méthode n'a aucun effet.

resume() : reprend la lecture d'un flux vidéo en pause. Si la vidéo est en cours de lecture, l'appel de cette méthode n'a aucun effet.

seek() : recherche l'image-clé la plus proche de l'emplacement spécifié (décalage, exprimé en secondes, par rapport au début du flux vidéo).

L'exemple suivant montre comment contrôler la lecture d'une vidéo à l'aide de divers boutons. Pour exécuter cet exemple, créez un document et ajoutez quatre instances de boutons à l'espace de travail (pauseBtn, playBtn, stopBtn et togglePauseBtn):

var nc:NetConnection = new NetConnection();
nc.connect(null);

var ns:NetStream = new NetStream(nc);
ns.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
ns.play("video.flv");
function asyncErrorHandler(event:AsyncErrorEvent):void
{
    // ignorer une erreur
}

var vid:Video = new Video();
vid.attachNetStream(ns);
addChild(vid);

pauseBtn.addEventListener(MouseEvent.CLICK, pauseHandler);
playBtn.addEventListener(MouseEvent.CLICK, playHandler);
stopBtn.addEventListener(MouseEvent.CLICK, stopHandler);
togglePauseBtn.addEventListener(MouseEvent.CLICK, togglePauseHandler);

function pauseHandler(event:MouseEvent):void
{
    ns.pause();
}
function playHandler(event:MouseEvent):void
{
    ns.resume();
}
function stopHandler(event:MouseEvent):void
{
    // mettre la lecture en pause et déplacer la tête de lecture au.
    // début du flux vidéo.
    ns.pause();
    ns.seek(0);
}
function togglePauseHandler(event:MouseEvent):void
{
    ns.togglePause();
}

Un clic sur l'instance de bouton pauseBtn pendant la lecture de la idéo provoque la mise en pause de celle-ci. Si la lecture de la vidéo est déjà en pause, l'appel de cette méthode n'a aucun effet. Un clic sur l'instance de playBtn reprend la lecture de la vidéo si celle-ci était en pause, sinon ce bouton n'a aucun effet.