Capture de la saisie de texte -- Flash CS3

Par défaut, la propriété type d'un champ texte à la valeur dynamic. Si vous attribuez à cette propriété type la valeur input à l'aide de la classe TextFieldType, vous pouvez recueillir la saisie de l'utilisateur et enregistrer cette valeur pour l'utiliser dans d'autres zones de l'application. Les champs de texte saisi sont utiles dans les formulaires et toute autre application qui demande à l'utilisateur de définir une valeur de texte à utiliser ailleurs dans le programme.

Par exemple, le code suivant crée un champ de texte de saisie appelé myTextBox. Lorsque l'utilisateur saisit du texte dans le champ, l'événement textInput est déclenché. Un gestionnaire d'événements appelé textInputCapture capture la chaîne de texte saisie et l'attribue à une variable. Flash Player affiche le nouveau texte dans un autre champ texte appelé myOutputBox.

package
{
    import flash.display.Sprite;
    import flash.display.Stage;
    import flash.text.*;
    import flash.events.*;

    public class CaptureUserInput extends Sprite
    {
        private var myTextBox:TextField = new TextField();
        private var myOutputBox:TextField = new TextField();
        private var myText:String = "Type your text here.";

        public function CaptureUserInput()
        {
            captureText();
        }
        
        public function captureText():void
        {
            myTextBox.type = TextFieldType.INPUT;
            myTextBox.background = true;
            addChild(myTextBox);
            myTextBox.text = myText;
            myTextBox.addEventListener(TextEvent.TEXT_INPUT, textInputCapture);
        }
        
        public function textInputCapture(event:TextEvent):void
        {
            var str:String = myTextBox.text;
            createOutputBox(str);
        }
            
        public function createOutputBox(str:String):void
        {
            myOutputBox.background = true;
            myOutputBox.x = 200;
            addChild(myOutputBox);
            myOutputBox.text = str;
        }
        
    }
}