Documentation Flash CS3

Programmation avec ActionScript 3.0 > Utilisation de XML > Utilisation d'espaces de nom XML

Utilisation d'espaces de nom XML

Les espaces de nom dans un objet (ou document) XML identifient le type de données que contient l'objet. Par exemple, lorsque vous envoyez et fournissez des données XML à un service Web qui utilise le protocole de messagerie SOAP, vous déclarez l'espace de nom dans la balise de début de l'XML :

var message:XML = 
    <soap:Envelope xmlns:soap="http://schemas.xmlsoap.org/soap/envelope/"
    soap:encodingStyle="http://schemas.xmlsoap.org/soap/encoding/"> 
        <soap:Body xmlns:w="http://www.test.com/weather/">
            <w:getWeatherResponse> 
                <w:tempurature >78</w:tempurature> 
            </w:getWeatherResponse> 
        </soap:Body> 
    </soap:Envelope>;

L'espace de nom a un préfixe, soap, et un URI qui définit l'espace de nom, http://schemas.xmlsoap.org/soap/envelope/.

ActionScript 3.0 inclut la classe Namespace pour utiliser des espaces de nom XML. Pour l'objet XML dans l'exemple précédent, vous pouvez utiliser la classe Namespace comme suit :

var soapNS:Namespace = message.namespace("soap");
trace(soapNS); // Résultat : http://schemas.xmlsoap.org/soap/envelope/

var wNS:Namespace = new Namespace("w", "http://www.test.com/weather/");
message.addNamespace(wNS);
var encodingStyle:XMLList = message.@soapNS::encodingStyle;
var body:XMLList = message.soapNS::Body;

message.soapNS::Body.wNS::GetWeatherResponse.wNS::tempurature = "78";

La classe XML inclut les méthodes suivantes pour utiliser des espaces de nom : addNamespace(), inScopeNamespaces(), localName(), name(), namespace(), namespaceDeclarations(), removeNamespace(), setLocalName(), setName(), et setNamespace().

La directive default xml namespace vous permet d'affecter un espace de nom par défaut pour des objets XML. Par exemple, dans l'exemple suivant, x1 et x2 ont le même espace de nom par défaut :

var ns1:Namespace = new Namespace("http://www.example.com/namespaces/");
default xml namespace = ns1;
var x1:XML = <test1 />;
var x2:XML = <test2 />;

Flash CS3

M'envoyer un message électronique lorsque des commentaires sont ajoutés à cette page | Rapport de commentaire

Page en cours: http://livedocs.adobe.com/flash/9.0_fr/main/00000130.html

Ajouter un commentaire