Types d'erreurs

Lorsque vous développez et exécutez des applications, vous rencontrez différents types d'erreurs et de termes. La liste suivante présente les principaux termes et types d'erreurs :

Erreurs de compilation : générées par le compilateur ActionScript lors de la compilation du code. Les erreurs de compilation ont lieu lorsque des problèmes de syntaxe dans votre code empêchent de créer votre application.

Erreurs d'exécution : générées lorsque vous exécutez votre application après l'avoir compilée. Les erreurs d'exécution sont générées lorsqu'un fichier SWF est lu dans Adobe Flash Player 9. Dans la plupart des cas, vous pouvez gérer ces erreurs lorsqu'elles se produisent, en les signalant à l'utilisateur et en faisant en sorte que l'exécution de votre application continue. S'il s'agit d'une erreur grave (impossibilité de se connecter à un site Web distant ou de charger des données), vous pouvez utiliser la gestion des erreurs pour mettre fin à votre application en douceur.

Erreurs synchrones : générées lorsqu'une fonction est appelée--par exemple, lorsque vous tentez d'utiliser une méthode spécifique et que l'argument que vous lui transmettez n'est pas valide, par conséquent, Flash Player renvoie une exception. La plupart des erreurs ont lieu de façon synchrone (au moment de l'exécution d'une instruction) et le flux de contrôle passe immédiatement à l'instruction catch la plus applicable.

Par exemple, l'extrait de code suivant renvoie une erreur d'exécution car la méthode browse() n'est pas appelée avant que le programme tente de charger un fichier :

var fileRef:FileReference = new FileReference();
try
{
    fileRef.upload("http://www.yourdomain.com/fileupload.cfm");
}
catch (error:IllegalOperationError)
{
    trace(error);
    // Error #2037: Fonctions appelées dans un ordre incorrect, ou appel
    // précédent impossible.
}

Dans ce cas, une erreur d'exécution est renvoyée de façon synchrone car Flash Player a déterminé que la méthode browse() n'a pas été appelée avant la tentative de chargement du fichier.

Pour de plus amples informations sur la gestions des erreurs synchrones, voir Gestion des erreurs synchrones dans une application.

Erreurs asynchrones : générées à différents moments lors de l'exécution. Elles provoquent des événements et sont interceptées par des écouteurs d'événements. Une opération asynchrone est une opération dans laquelle une fonction lance une opération mais n'attend pas qu'elle se termine. Vous pouvez créer un écouteur d'événement d'erreur pour attendre que l'application ou l'utilisateur tente une opération, et si cette dernière échoue, vous interceptez l'erreur avec un écouteur d'événement et répondez à l'événement d'erreur. Ensuite, l'écouteur d'événement appelle une fonction de gestionnaire d'événements pour répondre à l'événement d'erreur de façon utile. Par exemple, le gestionnaire d'événements peut lancer une boîte de dialogue qui invite l'utilisateur à résoudre l'erreur.

Reprenez l'exemple d'erreur synchrone lors du chargement d'un fichier présenté précédemment. Si vous réussissez à appeler la méthode browse() avant de lancer le chargement d'un fichier, Flash Player distribue plusieurs événements. Par exemple, au démarrage d'un chargement, l'événement open est distribué. A la fin du chargement, l'événement complete est distribué. Etant donné que la gestion d'événements est asynchrone (c'est-à-dire qu'elle n'a pas lieu à des moments prédéfinis, connus et spécifiques), vous devez utiliser la méthode addEventListener() pour détecter ces événements spécifiques, comme l'indique le code suivant :

var fileRef:FileReference = new FileReference();
fileRef.addEventListener(Event.SELECT, selectHandler);
fileRef.addEventListener(Event.OPEN, openHandler);
fileRef.addEventListener(Event.COMPLETE, completeHandler);
fileRef.browse();

function selectHandler(event:Event):void
{
    trace("...select...");
    var request:URLRequest = new URLRequest("http://www.yourdomain.com/fileupload.cfm");
    request.method = URLRequestMethod.POST;
    event.target.upload(request.url);
}
function openHandler(event:Event):void
{
    trace("...open...");
}
function completeHandler(event:Event):void
{
    trace("...complete...");
}

Pour de plus amples informations sur la gestions des erreurs asynchrones, voir Réponse à des événements d'erreurs et au statut.

Exceptions non interceptées : renvoyées sans logique correspondante (comme une instructioncatch) pour y répondre. Si votre application renvoie une erreur, et qu'aucune instruction catch ni gestionnaire d'événements approprié n'est trouvé au niveau actuel ou supérieur pour gérer l'erreur, cette dernière est considérée comme une exception non interceptée.

Lors de l'exécution, Flash Player ignore les erreurs non interceptées et tente de poursuivre la lecture si l'erreur n'arrête pas le fichier SWF actuel, car les utilisateurs ne peuvent pas nécessairement résoudre une erreur eux-même. Le fait d'ignorer une erreur non interceptée est appelé « échec silencieux » et peut compliquer le débogage des applications. La version de débogage de Flash Player répond à une erreur non interceptée en terminant le script courant et en affichant l'erreur non interceptée dans le résultat de l'instruction trace ou en enregistrant le message d'erreur dans un fichier journal. Si l'objet d'exception est une instance de la classe Error ou l'une de ses sous-classes, la méthode getStackTrace() est appelée, et les informations de trace de pile sont également affichées dans le résultat de l'instruction trace ou dans un fichier journal. Pour de plus amples informations sur l'utilisation de la version de débogage de Flash Player, voir Utilisation de la version de débogage de Flash Player.

Flash CS3

Page en cours: http://livedocs.adobe.com/flash/9.0_fr/main/00000097.html