flash.ui.ContextMenuItem (ActionScript 3.0)

Package	flash.ui
Classe	public final class ContextMenuItem
Héritage	ContextMenuItem EventDispatcher Object

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

La classe ContextMenuItem vous permet de créer des éléments de menu personnalisés à afficher dans le menu contextuel de Flash Player. Chaque objet ContextMenuItem est doté d’une légende (texte) qui s'affiche dans le menu contextuel. Pour intégrer un nouvel élément à un menu contextuel, il vous suffit de l'ajouter au tableau customItems d'un objet ContextMenu.

Les propriétés de la classe ContextMenuItem vous permettent d’activer ou de désactiver des éléments de menu, mais aussi de les afficher ou de les masquer.

Vous écrivez un gestionnaire d’événements destiné à l’événement menuItemSelect pour ajouter une fonctionnalité à l’élément de menu lorsque l’utilisateur le sélectionne.

Les éléments de menu personnalisés s'affichent dans la partie supérieure du menu contextuel, au-dessus des éléments intégrés. Une barre de séparation sépare toujours les éléments de menu personnalisés des éléments intégrés.

Restrictions :

Vous ne pouvez pas ajouter plus de 15 éléments personnalisés à un menu contextuel.
Les légendes doivent comporter au moins un caractère visible.
Les caractères de contrôle, de nouvelle ligne et autres espaces blancs ne sont pas pris en compte.
Aucune légende ne peut comporter plus de 100 caractères.
Les éléments identiques à un élément de menu intégré, ou à un autre élément personnalisé, sont ignorés, que l'élément correspondant soit visible ou non. Les éléments de menu sont comparés aux éléments intégrés ou personnalisés existants sans respecter la casse, la ponctuation ou les espaces blancs.

Les légendes suivantes sont exclues, mais elles peuvent être utilisées en conjonction avec d’autres mots pour créer une légende personnalisée (ainsi, « Paste » (Coller) n’est pas autorisée, mais la légende « Paste tastes great » (Coller au texte) est permise) :

 Save (Enregistrer)
 Zoom In (Zoom avant)
 Zoom Out (Zoom arrière)
 100% (100%)
 Show All (Tout afficher)
 Quality (Qualité)
 Play (Lire)
 Loop (Boucle)
 Rewind (Rembobiner)
 Forward (En avant)
 Back (En arrière)
 Movie not loaded (L'animation n'est pas chargée)
 About (A propos)
 Print (Imprimer)
 Show Redraw Regions (Redessiner les régions)
 Debugger (Débogueur)
 Undo (Annuler)
 Cut (Couper)
 Copy (Copier)
 Paste (Coller)
 Delete (Supprimer)
 Select All (Tout sélectionner)
 Open (Ouvrir)
 Open in new window (Ouvrir dans une nouvelle fenêtre)
 Copy link (Copier un lien)

Les termes suivants ne doivent en aucun cas apparaître dans une légende personnalisée, seuls ou avec d’autres mots :
```
 Adobe
 Macromedia
 Flash Player (Lecteur Flash)
 Settings (Paramètres)
 
```

Remarque : lorsque le lecteur s’exécute sur un système qui n'est pas en anglais, les chaînes sont comparées à la liste anglaise et aux traductions équivalentes.

Consulter les exemples

Voir aussi

Classe ContextMenu
Classe ContextMenuBuiltInItems

	Propriété	Défini par
		caption : String Spécifie la légende (texte) de l'élément de menu qui s'affiche dans le menu contextuel.	ContextMenuItem
		constructor : Object Référence à l'objet de classe ou à la fonction constructeur d'une occurrence donnée d'un objet.	Object
		enabled : Boolean Indique si l’élément de menu spécifié est activé ou désactivé.	ContextMenuItem
		prototype : Object [static] Référence à l’objet prototype d’un objet de classe ou fonction.	Object
		separatorBefore : Boolean Indique si une barre de séparation doit apparaître au-dessus de l'élément de menu spécifié.	ContextMenuItem
		visible : Boolean Indique si l'élément de menu spécifié est visible lorsque le menu contextuel de Flash Player s'affiche.	ContextMenuItem

	Méthode	Défini par
		ContextMenuItem(caption:String, separatorBefore:Boolean = false, enabled:Boolean = true, visible:Boolean = true) Crée un objet ContextMenuItem pouvant être ajouté au tableau ContextMenu.customItems.	ContextMenuItem
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Enregistre un objet écouteur d’événement auprès d’un objet EventDispatcher afin que l’écouteur soit averti d’un événement.	EventDispatcher
		clone():ContextMenuItem Crée et renvoie une copie de l'objet ContextMenuItem spécifié.	ContextMenuItem
		dispatchEvent(event:Event):Boolean Distribue un événement dans le flux d’événements.	EventDispatcher
		hasEventListener(type:String):Boolean Vérifie si des écouteurs sont enregistrés auprès de l'objet EventDispatcher pour un type spécifique d’événement.	EventDispatcher
		hasOwnProperty(name:String):Boolean Indique si la propriété spécifiée d'un objet est définie.	Object
		isPrototypeOf(theClass:Object):Boolean Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l'objet spécifié en tant que paramètre.	Object
		propertyIsEnumerable(name:String):Boolean Indique si la propriété spécifiée existe et est énumérable.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Supprime un écouteur de l’objet EventDispatcher.	EventDispatcher
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Définit la disponibilité d'une propriété dynamique pour les opérations en boucle.	Object
		toString():String Renvoie la représentation sous forme de chaîne de l'objet spécifié.	Object
		valueOf():Object Renvoie la valeur primitive de l'objet spécifié.	Object
		willTrigger(type:String):Boolean Vérifie si un écouteur d’événement est enregistré auprès de cet objet EventDispatcher ou de ses ancêtres pour le type d’événement spécifié.	EventDispatcher

Synthèse	Défini par
activate	Distribué lorsque Flash Player a le focus du système d’exploitation et devient actif.	EventDispatcher
deactivate	Distribué lorsque Flash Player perd le focus du système d’exploitation et devient inactif.	EventDispatcher
menuItemSelect	Distribué lorsqu’un utilisateur sélectionne un élément dans un menu contextuel.	ContextMenuItem

Détails des propriétés

caption

propriété

caption:String [lecture-écriture]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Spécifie la légende (texte) de l'élément de menu qui s'affiche dans le menu contextuel. Pour plus d'informations sur les restrictions liées à la valeur caption, consultez la présentation de la classe ContextMenuItem.

Implémentation
public function get caption():String
public function set caption(value:String):void

enabled

propriété

enabled:Boolean [lecture-écriture]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Indique si l’élément de menu spécifié est activé ou désactivé.

La valeur par défaut est true.

Implémentation
public function get enabled():Boolean
public function set enabled(value:Boolean):void

separatorBefore

propriété

separatorBefore:Boolean [lecture-écriture]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Indique si une barre de séparation doit apparaître au-dessus de l'élément de menu spécifié.

Remarque : une barre de séparation apparaît toujours entre les éléments de menu personnalisés et intégrés.

La valeur par défaut est false.

Implémentation
public function get separatorBefore():Boolean
public function set separatorBefore(value:Boolean):void

visible

propriété

visible:Boolean [lecture-écriture]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Indique si l'élément de menu spécifié est visible lorsque le menu contextuel de Flash Player s'affiche.

La valeur par défaut est true.

Implémentation
public function get visible():Boolean
public function set visible(value:Boolean):void

Détails du constructeur

ContextMenuItem

()

Constructeur

public function ContextMenuItem(caption:String, separatorBefore:Boolean = false, enabled:Boolean = true, visible:Boolean = true)

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Crée un objet ContextMenuItem pouvant être ajouté au tableau ContextMenu.customItems.

Paramètres

	`caption:String` — Spécifie le texte associé à l'élément de menu. Pour plus d'informations sur les restrictions liées à la valeur `caption`, consultez la présentation de la classe ContextMenuItem.

	`separatorBefore:Boolean` (default = `false`) — Spécifie si une barre de séparation doit apparaître au-dessus de l'élément dans le menu contextuel. La valeur par défaut est `false`.

	`enabled:Boolean` (default = `true`) — Indique si l'élément de menu est activé ou désactivé dans le menu contextuel. La valeur par défaut est `true` (activé). Ce paramètre est facultatif.

	`visible:Boolean` (default = `true`) — Indique si l’élément de menu est visible ou invisible. La valeur par défaut est `true` (visible).

Détails des méthodes

clone

()

méthode

public function clone():ContextMenuItem

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Crée et renvoie une copie de l'objet ContextMenuItem spécifié. La copie comprend toutes les propriétés de l'objet d’origine.

Valeur renvoyée

ContextMenuItem — Objet ContextMenuItem contenant toutes les propriétés de l'objet d’origine.

Détails des événements

menuItemSelect

Evénement

Type d'objet événement: flash.events.ContextMenuEvent
ContextMenuEvent.type property = flash.events.ContextMenuEvent.MENU_ITEM_SELECT

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Distribué lorsqu’un utilisateur sélectionne un élément dans un menu contextuel. L'utilisateur génère le menu contextuel en cliquant avec le bouton secondaire de son périphérique de pointage.

Définit la valeur de la propriété type d'un objet événement menuItemSelect.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`contextMenuOwner`	Objet de la liste d'affichage auquel le menu est associé.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`mouseTarget`	Objet de la liste d’affichage sur lequel l'utilisateur a cliqué du bouton droit de la souris pour afficher le menu contextuel.
`target`	Objet ContextMenuItem qui a été sélectionné. La cible ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d'événements. Utilisez la propriété `currentTarget` pour accéder à l’objet de la liste d'affichage qui traite actuellement l'événement.

Exemples Utilisation des exemples

ContextMenuItemExample.as

L'exemple suivant utilise la classe ContextMenuBuiltInItemsExample pour supprimer les éléments apparaissant par défaut dans le menu contextuel de la scène et ajouter un nouvel élément au menu. Cette opération se déroule selon la procédure suivante :

Une propriété myContextMenu est déclarée, puis attribuée à un nouvel objet ContextMenu.
La méthode removeDefaultItems() est appelée, ce qui supprime tous les éléments de menu contextuel intégrés sauf Print.
La méthode addCustomMenuItems() est appelée, ce qui a pour effet de placer un élément de menu appelé Hello World dans le tableau customItems par le biais de la méthode push() de Array.
L'élément Hello World est ensuite ajouté à la liste des éléments du menu contextuel de la scène.
Un objet TextField contenant le texte « Right Click Here » (Cliquez ici avec le bouton droit) est ajouté à la scène.

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.display.Sprite;
    import flash.text.TextField;

    public class ContextMenuItemExample extends Sprite {
        private var myContextMenu:ContextMenu;

        public function ContextMenuItemExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            this.contextMenu = myContextMenu;
            addChild(createLabel());
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();

            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem("Hello World");
            myContextMenu.customItems.push(item);
        }
        
        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = "Right Click Here";
            return txtField;
        }
    }
}

Page en cours: http://livedocs.adobe.com/flash/9.0_fr/ActionScriptLangRefV3/flash/ui/ContextMenuItem.html

Guide de référence du langage et des composants ActionScript 3.0		Tous les packages \| Toutes les classes \| Eléments du langage \| Index \| Annexes \| Conventions \| Cadres Aucune image
ContextMenuItem	Propriétés \| Méthodes \| Evénements \| Exemples