Indique l'alignement du paragraphe. Les valeurs valides sont des constantes TextFormatAlign.

La valeur par défaut est TextFormatAlign.LEFT.

Voir aussi

Indique l'indentation du bloc en pixels. L'indentation d'un bloc est appliquée à l'ensemble d'un bloc de texte ; c'est-à-dire à toutes les lignes du texte. Par contraste, l'indentation normale (TextFormat.indent) affecte seulement la première ligne de chaque paragraphe. Si cette propriété est null, l'objet TextFormat ne spécifie pas l'indentation d'un bloc (l'indentation de bloc est de 0).

Spécifie si le texte est en gras. La valeur par défaut est null, ce qui signifie qu'aucune police en gras n'est utilisée. Si la valeur est true, le texte est en gras.

Indique que le texte fait partie d'une liste à puces. Dans une liste à puces, chaque paragraphe du texte apparaît en retrait. A gauche de la première ligne de chaque paragraphe, le symbole d'une puce s'affiche. La valeur par défaut est null, ce qui signifie qu'aucune liste à puces n'est utilisée.

Indique la couleur du texte. Nombre contenant trois composants RVB 8 bits ; par exemple, 0xFF0000 correspond au rouge et 0x00FF00 au vert. La valeur par défaut est null, ce qui signifie que Flash Player utilise la couleur noire (0x000000).

Nom de la police pour du texte dans ce format de texte, sous forme de chaîne. La valeur par défaut est null, ce qui signifie que Flash Player utilise la police Times New Roman pour le texte.

Indique l'indentation à appliquer de la marge gauche au premier caractère du paragraphe. La valeur par défaut est null, ce qui indique qu'aucune indentation n'est utilisée.

Voir aussi

Indique si le texte concerné par ce format doit être en italiques. La valeur par défaut est null, ce qui signifie qu'aucun caractère ne sera en italiques.

Valeur booléenne indiquant si le crénage est activé (true) ou désactivé (false). Le crénage modifie le nombre de pixels séparant chaque paire de caractères pour améliorer la lisibilité et ne doit être employé que si nécessaire, dans les titres en grande police, par exemple. Le crénage est supporté uniquement pour les polices incorporées.

Certaines polices, telles que Verdana, et les polices à espacement fixe, telles que Courier New, ne prennent pas en charge le crénage.

La valeur par défaut est null, ce qui signifie que le crénage est désactivé.

Entier représentant le montant d'espace vertical (appelé leading) entre les lignes. La valeur par défaut est null, ce qui indique que le montant d'interlignage est défini sur 0.

Marge gauche du paragraphe, en pixels. La valeur par défaut est null, ce qui indique que la marge gauche est de 0 pixels.

Nombre représentant la quantité d'espace répartie uniformément entre tous les caractères. Cette valeur spécifie le nombre de pixels à ajouter après chaque caractère. La valeur par défaut est null, ce qui signifie que les lettres sont séparées par 0 pixels. Vous pouvez utiliser des valeurs décimales telles que 1.75.

Marge droite du paragraphe, en pixels. La valeur par défaut est null, ce qui indique que la marge droite est de 0 pixels.

Taille en points du texte dans ce format de texte. La valeur par défaut est null, ce qui signifie qu'une taille en points de 12 pixels est utilisée.

Spécifie des taquets de tabulation personnalisés, sous forme d’un tableau d’entiers non négatifs. Chaque taquet de tabulation est spécifié en pixels. Si des taquets de tabulation personnalisés ne sont pas spécifiés (null), le taquet de tabulation par défaut est 4 (largeur moyenne de caractère).

Indique la fenêtre cible dans laquelle s'affiche l'hyperlien. Si la fenêtre cible est une chaîne vide, le texte s'affiche dans la fenêtre cible par défaut _self. Vous pouvez choisir un nom personnalisé ou l'un des quatre noms suivants : _self spécifie l'image active dans la fenêtre actuelle, _blank spécifie une nouvelle fenêtre, _parent spécifie le parent de l'image active et _top spécifie l'image de plus haut niveau dans la fenêtre active. Si la propriété TextFormat.url est une chaîne vide ou null, vous pouvez obtenir ou définir cette propriété, mais la propriété n'aura aucun effet.

Voir aussi

Indique si le texte qui utilise ce format texte est souligné (true) ou non (false). Ce soulignement est similaire à celui créé par la balise <U> mais ce dernier n'est pas un vrai soulignement, étant donné qu'il ne saute pas correctement les lettres à jambage. La valeur par défaut est null, ce qui indique qu'aucune partie du texte n'est soulignée.

Indique l'URL cible du texte concerné par ce format. Si la propriété url est une chaîne vide, le texte ne comporte pas d'hyperlien. La valeur par défaut est null, ce qui indique que le texte ne comporte pas d'hyperlien.

Remarque : le texte et le format qui lui est associé doit être défini avec la propriété htmlText pour que l'hyperlien fonctionne.

Voir aussi

Crée un objet TextFormat avec les propriétés spécifiées. Vous pouvez modifier les propriétés de l'objet TextFormat pour modifier le format des champs texte.

Tout paramètre peut être défini sur null pour indiquer qu'il n'est pas défini. Tous les paramètres sont facultatifs ; tous les paramètres omis sont traités comme null.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.text.TextFormatAlign;
    
    public class TextFormat_constructorExample extends Sprite {
        private var contentTextField:TextField = new TextField();
        private var formatTextField:TextField = new TextField();
        private var newFormat:TextFormat = new TextFormat();
        
        public function TextFormat_constructorExample() {
            contentTextField.x = 10;
            contentTextField.y = 10;
            contentTextField.background = true;
            contentTextField.border = true;
            contentTextField.multiline = true;
            contentTextField.wordWrap = true;
            contentTextField.selectable = false;
            contentTextField.width = 250;
            contentTextField.height = 120; 
  
            contentTextField.htmlText = "<p>The TextFormat class represents character formatting "
                + "information. Use the TextFormat class to create specific text formatting "
                + "for text fields." + 
                " </p><br>" + "\tTab One" + "\tTab Two<br>";
              
            formatTextField.x = 10;
            formatTextField.y = 140;
            formatTextField.background = true;
            formatTextField.border = true;
            formatTextField.autoSize = TextFieldAutoSize.LEFT;
            
            formatTextField.text = "align: right\n" + "blockIndent: 10 pixels\n" + "bold:\n" + "bullet:\n" + "color: red\n"
                                + "font: Arial\n" + "indent: 20 pixels\n" + "italic:\n" + "leading: 5 spaces\n" 
                                + "leftMargin: 20 pixels\n" + "letterSpacing: 4 pixels\n" + "rightMargin: 20 pixels\n" 
                                + "size: 16 point\n" + "target: new window\n" + "tabStops: 50 and 150 pixel\n" 
                                + "underline:\n" + "url: Adobe Flex page\n";

            formatTextField.addEventListener(MouseEvent.CLICK, formatTextFieldClickHandler);
            
            contentTextField.addEventListener(MouseEvent.CLICK, contentTextFieldClickHandler);
            
            this.addChild(contentTextField);
            this.addChild(formatTextField);
        }

        private function formatTextFieldClickHandler(e:MouseEvent):void {
                var value:String= "";
                var i:uint = 0;
                var index:int = formatTextField.getLineIndexAtPoint(e.localX, e.localY);
                var line:String = formatTextField.getLineText(index);;

                line = line.substr(0, (line.indexOf(":")));

                switch(line) {
                    case "align":
                        newFormat.align = TextFormatAlign.RIGHT;
                        break;
                    case "blockIndent":
                        newFormat.blockIndent = 10;
                        break;
                    case "bold":
                        newFormat.bold = true;
                        break;
                    case "bullet":
                        newFormat.bullet = true;
                        break;
                    case "color":
                        newFormat.color = 0xFF0000;        
                        break;
                    case "font":
                        newFormat.font = "Arial";
                        break;
                    case "indent":
                        newFormat.indent = 20;
                        break;
                    case "italic":
                        newFormat.italic = true;
                        break;
                    case "leading":
                        newFormat.leading = 5;
                        break;
                    case "leftMargin":
                        newFormat.leftMargin = 20;
                        break;
                    case "letterSpacing":
                        newFormat.letterSpacing = 4;
                        break;
                    case "rightMargin":
                        newFormat.rightMargin = 20;
                        break;
                    case "size":
                        newFormat.size = 16;
                        break;
                    case "tabStops":                
                        newFormat.tabStops = [50, 150];
                        break;
                    case "target":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        newFormat.target = "_blank";
                        break;    
                    case "underline":
                        newFormat.underline = true;
                        break;
                    case "url":
                        newFormat.url = "http://www.adobe.com/products/flex/";    
                        break;
                }    

                contentTextField.setTextFormat(newFormat);
        }

        private function contentTextFieldClickHandler(e:MouseEvent):void {
            contentTextField.setTextFormat(contentTextField.defaultTextFormat);
            newFormat = contentTextField.defaultTextFormat;
        }
    }
}

1. Une propriété label de type TextField est créée.
2. Le constructeur de classe appelle la fonction configureLabel().
3. La fonction configureLabel() crée tout d'abord un objet TextField et l'affecte à label, puis définit ses paramètres de la façon suivante :
   • Justifie le champ de texte à gauche ;
   • Active le remplissage d'arrière-plan ;
   • Active la bordure.
4. Ensuite, la méthode configureLable() crée la variable locale format et l'affecte à une nouvelle occurrence de TextFormat en définissant ses paramètres de la façon suivante :
   • Type de police = Verdana
   • Couleur de la police = rouge uni
   • Taille de la police = 10
   • Soulignement = true
5. La propriété defaultTextFormat de l'étiquette est définie sur format, et l'occurrence label vient s'ajouter à la liste d'affichage, qui affiche tout d'abord un champ de texte sans texte (sous forme de petit cadre avec un fond blanc) sur la scène.
6. Enfin (au niveau du constructeur), le texte de l'étiquette est défini sur « Hello World and welcome to the show », aux coordonnées x = 0, y = 0 en appelant setLabel().

 package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;


    public class TextFormatExample extends Sprite {
        private var label:TextField;

        public function TextFormatExample() {
            configureLabel();
            setLabel("Hello World and welcome to the show");
        }

        public function setLabel(str:String):void {
            label.text = str;
        }

        private function configureLabel():void {
            label = new TextField();
            label.autoSize = TextFieldAutoSize.LEFT;
            label.background = true;
            label.border = true;

            var format:TextFormat = new TextFormat();
            format.font = "Verdana";
            format.color = 0xFF0000;
            format.size = 10;
            format.underline = true;

            label.defaultTextFormat = format;
            addChild(label);
        }
    }
}