Indique si l’objet XMLSocket est actuellement connecté. Vous pouvez également vérifier si la connexion a abouti en vous enregistrant pour les événements connect et ioError.

Voir aussi

Crée un objet XMLSocket. L'objet XMLSocket n'est initialement pas connecté à un serveur. Vous devez appeler la méthode XMLSocket.connect() pour établir la connexion.

Voir aussi

Ferme la connexion spécifiée par l'objet XMLSocket. L’événement close se produit uniquement lorsque le serveur ferme la connexion. Il n'est pas distribué lorsque vous appelez la méthode close().

Voir aussi

Etablit une connexion à l’hôte Internet spécifié en utilisant le port TCP indiqué. A moins que vous n’utilisiez un fichier de régulation, vous ne pouvez, par défaut, vous connecter qu’à un port dont le numéro est supérieur ou égal à 1024.

Si vous spécifiez null pour le paramètre host, l'hôte contacté est celui où réside le fichier SWF appelant la méthode XMLSocket.connect(). Par exemple, si le fichier SWF a été téléchargé à partir du site www.adobe.com, le fait de spécifier null pour le paramètre host équivaut à entrer l'adresse IP de www.adobe.com.

Pour les fichiers SWF lus par une version antérieure à Flash Player 7, le paramètre host doit correspondre au superdomaine du fichier SWF envoyant cet appel. Par exemple, un fichier SWF à l'adresse www.adobe.com peut envoyer ou recevoir des variables provenant d'un fichier SWF à l'adresse store.adobe.com, car les deux fichiers résident dans le même superdomaine adobe.com.

Dans tous les fichiers SWF, quelle que soit leur version, exécutés dans Flash Player 7 ou une version ultérieure, le paramètre host doit se trouver exactement dans le même domaine. Par exemple, un fichier SWF situé à l'adresse www.adobe.com et publié pour Flash Player 5, mais s'exécutant dans Flash Player 7 ou une version ultérieure, ne peut envoyer et recevoir des variables que des fichiers SWF également situés dans www.adobe.com. Si vous souhaitez envoyer ou recevoir des variables d'un autre domaine, placez un fichier de régulation interdomaines sur le serveur qui héberge le fichier SWF auquel vous accédez.

Vous pouvez éviter qu'un fichier SWF n'utilise cette méthode en définissant le paramètre allowNetworking des balises object et embed dans la page HTML qui héberge le contenu SWF.

Pour plus d'informations, consultez les références suivantes :

• Le chapitre relatif à la sécurité du manuel Programmation d'ActionScript 3.0 et les derniers commentaires disponibles dans LiveDocs
• Le Livre blanc sur la sécurité de Flash Player 9

Paramètres

Voir aussi

Convertit l'objet ou les données XML spécifiés dans le paramètre object en une chaîne et la transmet au serveur, suivie d'un octet nul (0). Si object est un objet XML, la chaîne est la représentation textuelle XML de l'objet XML. L'opération d'envoi est asynchrone ; elle est immédiatement renvoyée, mais les données peuvent être transmises plus tard. La méthode XMLSocket.send() ne renvoie pas de valeur indiquant si les données ont bien été transmises.

Si vous ne connectez pas l'objet XMLSocket au serveur à l’aide de XMLSocket.connect(), l’opération XMLSocket.send() échoue.

Paramètres

Voir aussi

Distribué lorsque le serveur ferme la connexion socket. L’événement close se produit uniquement lorsque le serveur ferme la connexion. Il n'est pas distribué lorsque vous appelez la méthode XMLSocket.close().

Les propriétés de cet événement sont les suivantes :

Distribué après un appel de la méthode XMLSocket.connect() qui a abouti.

Les propriétés de cet événement sont les suivantes :

Distribué après l’envoi ou la réception de données brutes.

Les propriétés de cet événement sont les suivantes :

Distribué lorsqu'il se produit une erreur d'entrée/sortie entraînant l’échec d’une opération d’envoi ou de réception.

Les propriétés de cet événement sont les suivantes :

Distribué si un appel de la méthode XMLSocket.connect() tente une connexion à un serveur situé hors du sandbox de sécurité de l'appelant ou à un port inférieur à 1024.

Les propriétés de cet événement sont les suivantes :

Voir aussi

1. Le constructeur XMLSocketExample crée une occurrence de XMLSocket nommée socket et transmet le socket à la méthode ConfigureListeners() (décrite ci-dessous), puis appelle la méthode connect() de XMLSocket avec le nom d'hôte « localhost » et le numéro de port 8080.
2. La méthode configureListeners() est ensuite appelée, ce qui ajoute des écouteurs à chacun des événements XMLSocket pris en charge :
   • closeHandler() : écoute l'événement close, qui est distribué après la fermeture de la connexion réseau.
   • connectHandler() : écoute l'événement connect, qui est distribué à l'ouverture de la connexion réseau.
   • dataHandler() : écoute l'événement data, qui est distribué chaque fois que le XMLSocket reçoit de nouvelles données.
   • progressHandler() : écoute l'événement progress, qui est distribué à chaque appel de la méthode send() et pendant l'envoi.
   • securityErrorHandler() : écoute l'événement securityError, qui est distribué en cas de tentative d'accès au XMLSocket avec un paramètre de sécurité de lecture locale incorrect ou avec un numéro de port inférieur à 1024.
   • ioErrorHandler() : écoute l'événement ioError, qui se produit uniquement en cas d'échec d'une opération d'envoi ou de réception de données.

Remarques :

• Vous devrez compiler le fichier SWF en réglant « Sécurité de lecture locale » sur « Accès au réseau uniquement ».
• Pour que cet exemple fonctionne, vous aurez besoin d'un serveur s'exécutant sur [yourDomain] à l'aide du port 8080.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.XMLSocket;

    public class XMLSocketExample extends Sprite {
        private var hostName:String = "localhost";
        private var port:uint = 8080;
        private var socket:XMLSocket;

        public function XMLSocketExample() {
            socket = new XMLSocket();
            configureListeners(socket);
            socket.connect(hostName, port);
        }

        public function send(data:Object):void {
            socket.send(data);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CLOSE, closeHandler);
            dispatcher.addEventListener(Event.CONNECT, connectHandler);
            dispatcher.addEventListener(DataEvent.DATA, dataHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
        }

        private function closeHandler(event:Event):void {
            trace("closeHandler: " + event);
        }

        private function connectHandler(event:Event):void {
            trace("connectHandler: " + event);
        }

        private function dataHandler(event:DataEvent):void {
            trace("dataHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
    }
}