Type de contenu MIME de n'importe quelles données POST.

Remarque : les méthodes FileReference.upload() et FileReference.download() ne prennent pas en charge le paramètre URLRequest.contentType.

Objet contenant des données à transmettre avec la demande d’URL.

Cette propriété s’utilise avec la propriété method. Si la valeur de URLRequest.method correspond à POST, les données sont transmises avec l’objet URLRequest par le biais de la méthode HTTP POST.

Si la valeur de URLRequest.method correspond à GET, les données définissent des variables à envoyer avec l’objet URLRequest par le biais de la méthode HTTP GET.

L'API URLRequest offre une prise en charge POST binaire et gère les variables de code URL, ainsi que les chaînes. Les objets de données peuvent être de type ByteArray, URLVariables ou String.

L’utilisation des données varie en fonction du type d’objet :

• Si l’objet est de type ByteArray, les données binaires correspondantes sont utilisées en tant que données POST. GET ne gère pas les données de type ByteArray. En outre, ces données ne sont pas prises en charge par FileReference.upload() et FileReference.download().
• Si l’objet est de type URLVariables et que la méthode est POST, les variables sont codées au format x-www-form-urlencoded et la chaîne résultante sert de données POST. Un appel de FileReference.upload() constitue une exception : les variables sont incluses en tant que champs distincts dans un envoi multipart/form-data.
• Si l’objet est de type URLVariables et que la méthode correspond à GET, l’objet définit des variables à envoyer avec l’objet URLRequest.
• Dans tous les autres cas, l’objet est converti en une chaîne, qui est utilisée comme données POST ou GET.

Les données ne sont pas envoyées tant qu’une méthode, telle que navigateToURL() ou FileReference.upload(), utilise l’objet URLRequest.

Voir aussi

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

Détermine si la méthode de soumission du formulaire HTTP est une opération GET ou POST. Les valeurs gérées sont URLRequestMethod.GET ou URLRequestMethod.POST.

La valeur par défaut est URLRequestMethod.GET.

Voir aussi

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;
            
            navigateToURL(request);
        }
    }
}

Tableau d'en-tête de requête HTTP à ajouter à la fin de la requête HTTP. Le tableau se compose d’objets URLRequestHeader. Tous les objets du tableau doivent être de type URLRequestHeader et contenir une chaîne de nom et une chaîne de valeur, comme suit :

  var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));
  

Flash Player impose certaines restrictions sur les en-têtes de requête. Pour en savoir plus, consultez la description de la classe URLRequestHeader.

Les méthodes FileReference.upload() et FileReference.download() ne prennent pas en charge le paramètre URLRequest.requestHeaders.

Voir aussi

URL à demander. Par défaut, l’URL doit se trouver dans exactement le même domaine que le fichier SWF appelant, sous-domaines compris. Les fichiers SWF qui figurent aux adresses www.adobe.com et store.adobe.com, par exemple, sont dans des domaines différents. Pour charger des données à partir d'un autre domaine, placez un fichier de régulation interdomaines dans le serveur qui héberge le fichier SWF. Pour plus d’informations, reportez-vous aux informations relatives à la sécurité dans la description de la classe URLRequest.

Remarque : Flash Player Mise à jour 3 et les versions ultérieures supportent IPv6 (Internet Protocol version 6). IPv6 est une version du protocole IP (Internet Protocol) qui prend en charge les adresses 128 bits (amélioration du protocole IPv4 précédent qui prend en charge les adresses 32 bits). Vous devrez peut-être activer IPv6 sur vos interfaces de mise en réseau. Pour plus d'informations, consultez l'Aide du système d'exploitation hébergeant les données. Si IPv6 est pris en charge sur le système hébergeant, vous pouvez spécifier des adresses littérales IPv6 numériques dans les URL entre crochets ([]), comme suit :

     rtmp://[2001:db8:ccc3:ffff:0:444d:555e:666f]:1935/test
     

Crée un objet URLRequest. Si System.useCodePage correspond à true, la requête est codée via la page de code système, plutôt que le format Unicode. Si System.useCodePage correspond à false, la requête est codée via le format Unicode, plutôt que la page de code système.

Voir aussi

Pour exécuter cet exemple, placez un fichier nommé XMLFile.xml dans le même répertoire que votre fichier SWF.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {

        public function URLRequestExample() {
            var loader:URLLoader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}