Indique le nombre d’octets chargés jusqu’ici au cours du chargement.

Indique le nombre total d'octets dans les données téléchargées. Cette propriété contient 0 lorsque le chargement est en cours et est renseignée au terme de ce dernier. Également, si un en-tête Content-Length est manquant, bytesTotal sera indéterminé.

Données reçues par le biais de l'opération de chargement. Cette propriété n'est renseignée qu'à la fin du chargement. Le format des données varie en fonction du paramétrage de la propriété dataFormat :

Si la propriété dataFormat est URLLoaderDataFormat.TEXT, les données reçues représentent une chaîne qui contient le texte du fichier chargé.

Si la propriété dataFormat est URLLoaderDataFormat.BINARY, les données reçues représentent un objet ByteArray qui contient des données binaires brutes.

Si la propriété dataFormat est URLLoaderDataFormat.VARIABLES, les données reçues représentent un objet URLVariables qui contient des variables d'URL codées.

Voir aussi

Contrôle si les données téléchargées sont reçues sous forme de texte (URLLoaderDataFormat.TEXT), de données binaires brutes (URLLoaderDataFormat.BINARY) ou de variables d'URL codées (URLLoaderDataFormat.VARIABLES).

Si la valeur de la propriété dataFormat est URLLoaderDataFormat.TEXT, les données reçues représentent une chaîne qui contient le texte du fichier chargé.

Si la valeur de la propriété dataFormat est URLLoaderDataFormat.BINARY, les données reçues représentent un objet ByteArray qui contient les données binaires brutes.

Si la valeur de la propriété dataFormat est URLLoaderDataFormat.VARIABLES, les données reçues représentent un objet URLVariables qui contient les variables d'URL codées.

La valeur par défaut est URLLoaderDataFormat.TEXT.

Voir aussi

Crée un objet URLLoader.

Voir aussi

Ferme l’opération de chargement en cours. Toute opération de chargement en cours prend immédiatement fin. Si aucune URL n’est en cours de transmission, une erreur de flux non valide est renvoyée.

Envoie et charge les données à partir de l'URL spécifiée. Les données peuvent être reçues sous forme de texte, de données binaires brutes ou de variables d'URL codées, selon la valeur définie pour la propriété dataFormat. Vous remarquerez que la valeur par défaut de la propriété dataFormat correspond à text. Si vous souhaitez envoyer des données à l'URL spécifiée, définissez la propriété data dans l'objet URLRequest.

Remarque : Si un fichier en cours de chargement contient des caractères non-ASCII (comme dans les langues autres que l'anglais), nous vous recommandons d'enregistrer le fichier avec codage UTF-8 ou UTF-16, plutôt que sous un format non-Unicode, ASCII par exemple.

Pour utiliser cette méthode, tenez compte du modèle de sécurité de Flash Player :

Pour Flash Player 9 et les versions ultérieures, vous pouvez éviter qu'un fichier SWF n'utilise cette méthode en définissant le paramètre allowNetworking des balises object et embed dans la page HTML qui héberge le contenu SWF.

Pour Flash Player 8 et les versions ultérieures :

• Le chargement de données n'est pas autorisé si le fichier SWF appelant est dans le sandbox local avec système de fichiers et que la ressource cible provient d'un sandbox de réseau.
• Le chargement de données n'est pas autorisé si le fichier SWF appelant provient d'un sandbox de réseau et que la ressource cible est locale.

Pour Flash Player 7 et les versions ultérieures, les sites Web permettent l'accès interdomaines à des ressources via un fichier de régulation interdomaines. Dans les fichiers SWF, quelle que soit leur version, exécutés dans Flash Player 7 ou une version ultérieure, l’url doit se trouver exactement dans le même domaine. Par exemple, un fichier SWF à l'adresse www.adobe.com peut charger uniquement des données provenant de sources situées aussi à l'adresse www.adobe.com.

Pour plus d'informations, consultez les références suivantes :

• Le chapitre relatif à la sécurité du manuel Programmation d'ActionScript 3.0 et les derniers commentaires disponibles dans LiveDocs
• Le Livre blanc sur la sécurité de Flash Player 9

Pour les fichiers SWF lus par une version antérieure à Flash Player 7, l’url doit correspondre au superdomaine du fichier SWF envoyant cet appel. Un superdomaine est dérivé par suppression du composant le plus à gauche de l'URL d'un fichier. Par exemple, un fichier SWF à l'adresse www.adobe.com peut charger des données provenant de sources à l'adresse store.adobe.com, car les deux fichiers se trouvent dans le même superdomaine intitulé adobe.com.

Paramètres

Voir aussi

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.xml.*;
    import flash.events.IOErrorEvent;
  
    public class URLLoader_loadExample extends Sprite {
        private var xmlTextField:TextField = new TextField();
        private var externalXML:XML;    
        private var loader:URLLoader;

        public function URLLoader_loadExample() {
            var request:URLRequest = new URLRequest("xmlFile.xml");

            loader = new URLLoader();
            
            try {
                loader.load(request);
            }
            catch (error:SecurityError)
            {
                trace("A SecurityError has occurred.");
            }

             loader.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            loader.addEventListener(Event.COMPLETE, loaderCompleteHandler);

            xmlTextField.x = 10;
            xmlTextField.y = 10;
            xmlTextField.background = true;
            xmlTextField.autoSize = TextFieldAutoSize.LEFT;

            addChild(xmlTextField);
        }

        private function loaderCompleteHandler(event:Event):void {

                try {
                    externalXML = new XML(loader.data);
                    readNodes(externalXML);    
                } catch (e:TypeError) {
                    trace("Could not parse the XML file.");
                }
        }

        private function readNodes(node:XML):void {

                for each (var element:XML in node.elements()) {
                    xmlTextField.appendText(element.attributes()[0] + "\n");

                    readNodes(element);
                }    
        }

        private function errorHandler(e:IOErrorEvent):void {
            xmlTextField.text = "Had problem loading the XML File.";
        }
    }
}

Distribué après le décodage de toutes les données reçues et leur placement dans la propriété data de l'objet URLLoader. Il est possible d'accéder aux données reçues une fois cet événement distribué.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Distribué si un appel de la méthode URLLoader.load() tente d'accéder à des données via HTTP et si l'environnement Flash Player actuel est capable de détecter et de renvoyer le code d'état de la requête. (Certains environnements de navigateur ne sont pas capables de fournir cette information.) Vous remarquerez que l'événement httpStatus (le cas échéant) est envoyé avant (et en complément de) tout événement complete ou error.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Distribué si un appel de la méthode URLLoader.load() provoque une erreur fatale qui met fin au téléchargement.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Distribué lorsque l'opération de téléchargement commence suite à un appel de la méthode URLLoader.load().

Les propriétés de cet événement sont les suivantes :

Voir aussi

Distribué à la réception des données au fur et à mesure du téléchargement.

Notez qu’avec un objet URLLoader, il est impossible d’accéder aux données avant la fin de leur téléchargement. L’événement progress indique donc uniquement la progression du téléchargement. Pour accéder aux données avant la fin de leur téléchargement, utilisez un objet URLStream.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Distribué si un appel de la méthode URLLoader.load() tente de charger des données d'un serveur en dehors d'un sandbox de sécurité.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Remarque : pour exécuter cet exemple, placez un fichier nommé urlLoaderExample.txt dans le même répertoire que votre fichier SWF. Ce fichier ne doit contenir que la ligne de texte suivante : answer=42&question=unknown

Le code de l’exemple effectue les opérations suivantes :

1. La fonction constructeur crée une occurrence d'URLLoader nommée loader et une occurrence d'URLRequest nommée request, qui contient l'emplacement et le nom du fichier à charger.
2. L'objet loader est transmis à la méthode configureListeners(), qui ajoute des écouteurs à chacun des événements URLLoader pris en charge.
3. L'objet request est ensuite transmis à la méthode loader.load(), qui charge le fichier texte.
4. Lorsque l'URLLoader a terminé de chargé le fichier texte, l'événement Event.COMPLETE se produit et déclenche la méthode completeHandler(). La méthode completeHandler() crée un objet URLVariables à partir du texte chargé depuis le fichier. L'objet URLVariables convertit les paires nom/valeur d'URL codées en propriétés ActionScript pour faciliter la manipulation des données chargées.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLLoaderExample extends Sprite {
        public function URLLoaderExample() {
            var loader:URLLoader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("urlLoaderExample.txt");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
    
            var vars:URLVariables = new URLVariables(loader.data);
            trace("The answer is " + vars.answer);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}