Objet ColorTransform contenant des valeurs qui règlent de façon universelle les couleurs de l’objet d’affichage.

Voir aussi

Objet ColorTransform représentant les transformations de couleur combinées qui s'appliquent à l’objet d’affichage et à l'ensemble de ses objets parent, jusqu'à la racine. Si différentes transformations de couleur s'appliquent à différents niveaux, elles sont concaténées dans un objet ColorTransform unique pour cette propriété.

Voir aussi

Objet Matrix représentant les matrices de transformation combinées qui s'appliquent à l’objet d’affichage et à l'ensemble de ses objets parent, jusqu'à la racine. Si différentes matrices de transformation s'appliquent à différents niveaux, elles sont concaténées en une seule matrice pour cette propriété.

Objet Matrix contenant des valeurs qui influent sur le redimensionnement, la rotation et la translation de l’objet d’affichage.

Voir aussi

Objet Rectangle qui définit le cadre de délimitation de l'objet d’affichage sur la scène.

1. Le constructeur TransformExample() crée un nouvel objet Sprite target.
2. Le constructeur TransformExample() appelle la méthode draw() qui dessine un carré dégradé dans l'icône animée (sprite).
3. Le constructeur TransformExample() ajoute un écouteur d'événements clic pour le sprite ; il est géré par le biais de la méthode clickHandler().
4. La méthode clickHandler() crée un objet Matrix, skewMatrix, qui est défini pour appliquer un effet d'inclinaison. Une autre matrice, tempMatrix, est attribuée à la matrice de transformation actuelle de l'icône animée, puis elle est combinée avec l'objet skewMatrix par le biais de la méthode concat(). Cette matrice est attribuée à la propriété transform.matrix de l'icône animée carrée. Chaque fois que l'utilisateur clique sur le carré, l'appel de la méthode clickHandler() modifie la forme du carré en l'inclinant.
5. Par ailleurs, la méthode clickHandler() crée un objet ColorTransform. La propriété redOffset du nouvel objet ColorTransform est définie sur la valeur actuelle de redOffset et est incrémentée de 25. De même, la propriété blueOffset est décrémentée de 25. Les couleurs de l'icône animée changent à chaque clic.

package {
    import flash.display.Sprite;
    import flash.display.GradientType;
    import flash.geom.Matrix;
    import flash.geom.ColorTransform;
    import flash.events.MouseEvent;

    public class TransformExample extends Sprite {
        public function TransformExample() { 
            var target:Sprite = new Sprite();
            draw(target);
            addChild(target);
            target.useHandCursor = true;
            target.buttonMode = true;
            target.addEventListener(MouseEvent.CLICK, clickHandler)
        }
        public function draw(sprite:Sprite):void {
            var red:uint = 0xFF0000;
            var green:uint = 0x00FF00;
            var blue:uint = 0x0000FF;
            var size:Number = 100;
            sprite.graphics.beginGradientFill(GradientType.LINEAR, [red, blue, green], [1, 0.5, 1], [0, 200, 255]);
            sprite.graphics.drawRect(0, 0, 100, 100);
        }
        public function clickHandler(event:MouseEvent):void {
            var skewMatrix:Matrix = new Matrix();
            skewMatrix.c = 0.25;
            var tempMatrix:Matrix = this.transform.matrix;
            tempMatrix.concat(skewMatrix);
            this.transform.matrix = tempMatrix;
            
            var rOffset:Number = this.transform.colorTransform.redOffset + 25;
            var bOffset:Number = this.transform.colorTransform.blueOffset - 25;
            this.transform.colorTransform = new ColorTransform(1, 1, 1, 1, rOffset, 0, bOffset, 0);            
        }
    }
}