Packageflash.filters
Classepublic class BitmapFilter
HéritageBitmapFilter Inheritance Object
Sous-classes BevelFilter, BlurFilter, ColorMatrixFilter, ConvolutionFilter, DisplacementMapFilter, DropShadowFilter, GlowFilter, GradientBevelFilter, GradientGlowFilter

Version du langage : ActionScript 3.0
Version du lecteur : Flash Player 9

La classe BitmapFilter est la classe de base pour tous les effets de filtrage d’image.

Les classes BevelFilter, BlurFilter, ColorMatrixFilter, ConvolutionFilter, DisplacementMapFilter, DropShadowFilter, GlowFilter, GradientBevelFilter et GradientGlowFilter étendent toutes la classe BitmapFilter. Vous pouvez appliquer ces effets de filtre aux objets d’affichage.

Vous ne pouvez pas directement instancier ni étendre BitmapFilter.

Consulter les exemples


Propriétés publiques
 PropriétéDéfini par
 Inheritedconstructor : Object
Référence à l'objet de classe ou à la fonction constructeur d'une occurrence donnée d'un objet.
Object
 Inheritedprototype : Object
[static] Référence à l’objet prototype d’un objet de classe ou fonction.
Object
Méthodes publiques
 MéthodeDéfini par
  
clone():BitmapFilter
Renvoie un objet BitmapFilter qui est une copie exacte de l'objet BitmapFilter d'origine.
BitmapFilter
 Inherited
hasOwnProperty(name:String):Boolean
Indique si la propriété spécifiée d'un objet est définie.
Object
 Inherited
isPrototypeOf(theClass:Object):Boolean
Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l'objet spécifié en tant que paramètre.
Object
 Inherited
propertyIsEnumerable(name:String):Boolean
Indique si la propriété spécifiée existe et est énumérable.
Object
 Inherited
setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void
Définit la disponibilité d'une propriété dynamique pour les opérations en boucle.
Object
 Inherited
toString():String
Renvoie la représentation sous forme de chaîne de l'objet spécifié.
Object
 Inherited
valueOf():Object
Renvoie la valeur primitive de l'objet spécifié.
Object
Détails des méthodes
clone()méthode
public function clone():BitmapFilter

Version du langage : ActionScript 3.0
Version du lecteur : Flash Player 9

Renvoie un objet BitmapFilter qui est une copie exacte de l'objet BitmapFilter d'origine.

Valeur renvoyée
BitmapFilter — Objet BitmapFilter.
Exemples Utilisation des exemples
BitmapFilterExample.as

L'exemple suivant montre comment plusieurs filtres peuvent être appliqués à un objet DisplayObject donné et suivis à l'aide de la propriété filters. 
package {
    import flash.display.Sprite;
    import flash.filters.*;

    public class BitmapFilterExample extends Sprite {
        public function BitmapFilterExample() {
            trace(this.filters.length);             // 0

            var tmpFilters:Array = this.filters;
            tmpFilters.push(FilterFactory.createFilter(FilterFactory.BEVEL_FILTER));
            tmpFilters.push(FilterFactory.createFilter(FilterFactory.GLOW_FILTER));
            this.filters = tmpFilters;

            trace(this.filters.length);             // 2
            trace(this.filters[0] is BitmapFilter); // true
            trace(this.filters[0] is BevelFilter);  // true
            trace(this.filters[1] is BitmapFilter); // true
            trace(this.filters[1] is GlowFilter);   // true
        }
    }
}

import flash.filters.*;
class FilterFactory {
    public static var BEVEL_FILTER:String = "BevelFilter";
    public static var BevelFilterConstructor:Class = BevelFilter;

    public static var BLUR_FILTER:String = "BlurFilter";
    public static var BlurFilterConstructor:Class = BlurFilter;

    public static var COLOR_MATRIX_FILTER:String = "ColorMatrixFilter";
    public static var ColorMatrixFilterConstructor:Class = ColorMatrixFilter;

    public static var CONVOLUTION_FILTER:String = "ConvolutionFilter";
    public static var ConvolutionFilterConstructor:Class = ConvolutionFilter;

    public static var DISPLACEMENT_MAP_FILTER:String = "DisplacementMapFilter";
    public static var DisplacementMapFilterConstructor:Class = DisplacementMapFilter;

    public static var DROP_SHADOW_FILTER:String = "DropShadowFilter";
    public static var DropShadowFilterConstructor:Class = DropShadowFilter;

    public static var GLOW_FILTER:String = "GlowFilter";
    public static var GlowFilterConstructor:Class = GlowFilter;

    public static var GRADIENT_BEVEL_FILTER:String = "GradientBevelFilter";
    public static var GradientBevelFilterConstructor:Class = GradientBevelFilter;

    public static var GRADIENT_GLOW_FILTER:String = "GradientGlowFilter";
    public static var GradientGlowFilterConstructor:Class = GradientGlowFilter;

    public static function createFilter(type:String):BitmapFilter {
        return new FilterFactory[type + "Constructor"]();   
    }
}



© 2004-2007 Adobe Systems Incorporated. Tous droits réservés.
Fri Oct 12 2007, 2:53 AM GMT-07:00

 

M'envoyer un message électronique lorsque des commentaires sont ajoutés à cette page | Rapport de commentaire

Page en cours: http://livedocs.adobe.com/flash/9.0_fr/ActionScriptLangRefV3/flash/filters/BitmapFilter.html