Nombre d’éléments ou d’octets chargés lors du traitement de l’événement par l'écouteur.

Nombre total d'éléments ou d'octets qui seront chargés si le processus de chargement aboutit.

Crée un objet Event contenant des informations sur les événements progress. Les objets Event sont transmis en tant que paramètres aux écouteurs d’événements.

Crée une copie de l’objet ProgressEvent et définit la valeur de chaque propriété de sorte qu’elle corresponde à la valeur d’origine.

Renvoie une chaîne répertoriant toutes les propriétés de l'objet ProgressEvent. La chaîne est écrite au format suivant :

[ProgressEvent type=valeur bubbles=valeur cancelable=valeur bytesLoaded=valeur bytesTotal=valeur]

Définit la valeur de la propriété type d'un objet événement progress.

Les propriétés de cet événement sont les suivantes :

Voir aussi

Définit la valeur de la propriété type d'un objet événement socketData.

Les propriétés de cet événement sont les suivantes :

Voir aussi

1. Les propriétés downloadURL et fileName sont créées, et indiquent l'emplacement et le nom du fichier téléchargé.
2. Dans le constructeur ProgressEventExample, un nouvel objet FileReference nommé file est créé, puis transmis à la méthode configureListeners().
3. Les propriétés downloadURL et fileName sont ensuite transmises à la méthode file.download(), qui demande l'emplacement de téléchargement du fichier.
4. La méthode configureListeners() ajoute sept écouteurs d'événements et leurs méthodes d'abonnés associées :
   1. cancel / cancelHandler() est distribué si le téléchargement du fichier est annulé.
   2. complete / complereHandler() est distribué lorsque le téléchargement du fichier est terminé.
   3. ioError / ioErrorHandler() est distribué si le fichier téléchargé n'est pas disponible ou accessible.
   4. open / openHandler() est distribué lorsque l'opération de téléchargement démarre.
   5. progress / progressHandler() est distribué lorsque l'opération de téléchargement commence, puis lorsqu'elle se termine.
   6. securityError / securityErrorHandler est distribué si le paramètre de sécurité de lecture locale ne correspond pas au type d'accès aux données du fichier téléchargé (local versus réseau) ; voir les remarques ci-dessous.
   7. select / selectHandler() est distribué lorsque l'objet de téléchargement est sélectionné.

Remarques :

• vous devrez compiler le fichier SWF en définissant « Sécurité de lecture locale » sur « Accès au réseau uniquement ».
• Cet exemple requiert un fichier nommé SomeFile.pdf.
• Cet exemple couvre tous les événements disponibles pour l'objet FileReference. Cependant, la plupart des situations n'en nécessite qu'un sous-ensemble.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class ProgressEventExample extends Sprite {
        private var downloadURL:String = "http://www.[yourDomain].com/SomeFile.pdf";
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function ProgressEventExample() {
            var request:URLRequest = new URLRequest(downloadURL);
            file = new FileReference();
            configureListeners(file);
            file.download(request, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL);
        }
    }
}