flash.events.Event (ActionScript 3.0)

	Propriété	Défini par
		bubbles : Boolean [lecture-seule] Indique si un événement peut se propager vers le haut (bubbling).	Event
		cancelable : Boolean [lecture-seule] Indique si le comportement associé à l’événement peut être annulé.	Event
		constructor : Object Référence à l'objet de classe ou à la fonction constructeur d'une occurrence donnée d'un objet.	Object
		currentTarget : Object [lecture-seule] L’objet qui traite activement l’objet Event avec un écouteur d’événements.	Event
		eventPhase : uint [lecture-seule] Phase actuelle du flux d’événements.	Event
		prototype : Object [static] Référence à l’objet prototype d’un objet de classe ou fonction.	Object
		target : Object [lecture-seule] Cible de l’événement.	Event
		type : String [lecture-seule] Type d’événement.	Event

	Méthode	Défini par
		Event(type:String, bubbles:Boolean = false, cancelable:Boolean = false) Crée un objet Event à transmettre en tant que paramètre aux écouteurs d’événements.	Event
		clone():Event Duplique une occurrence d'une sous-classe Event.	Event
		formatToString(className:String, ... arguments):String Fonction d’un utilitaire permettant d'implémenter la méthode toString() dans votre classe Event personnalisée.	Event
		hasOwnProperty(name:String):Boolean Indique si la propriété spécifiée d'un objet est définie.	Object
		isDefaultPrevented():Boolean Vérifie si preventDefault() a été appelée pour l’événement.	Event
		isPrototypeOf(theClass:Object):Boolean Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l'objet spécifié en tant que paramètre.	Object
		preventDefault():void Annule le comportement par défaut d’un événement si cette opération est possible.	Event
		propertyIsEnumerable(name:String):Boolean Indique si la propriété spécifiée existe et est énumérable.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Définit la disponibilité d'une propriété dynamique pour les opérations en boucle.	Object
		stopImmediatePropagation():void Bloque le traitement des écouteurs d’événement dans le nœud actuel et les suivants dans le flux d'événements.	Event
		stopPropagation():void Bloque le traitement des écouteurs d’événement dans les nœuds qui suivent le nœud actuel dans le flux d’événements.	Event
		toString():String Renvoie une chaîne répertoriant toutes les propriétés de l'objet Event.	Event
		valueOf():Object Renvoie la valeur primitive de l'objet spécifié.	Object

	Constante	Défini par
		ACTIVATE : String = "activate" [static] Définit la valeur de la propriété type d'un objet événement activate.	Event
		ADDED : String = "added" [static] Définit la valeur de la propriété type d'un objet événement added.	Event
		ADDED_TO_STAGE : String = "addedToStage" [static] Définit la valeur de la propriété type d'un objet événement addedToStage.	Event
		CANCEL : String = "cancel" [static] Définit la valeur de la propriété type d'un objet événement cancel.	Event
		CHANGE : String = "change" [static] Définit la valeur de la propriété type d'un objet événement change.	Event
		CLOSE : String = "close" [static] Définit la valeur de la propriété type d'un objet événement close.	Event
		COMPLETE : String = "complete" [static] Définit la valeur de la propriété type d'un objet événement complete.	Event
		CONNECT : String = "connect" [static] Définit la valeur de la propriété type d'un objet événement connect.	Event
		DEACTIVATE : String = "deactivate" [static] Définit la valeur de la propriété type d'un objet événement deactivate.	Event
		ENTER_FRAME : String = "enterFrame" [static] Définit la valeur de la propriété type d'un objet événement enterFrame.	Event
		FULLSCREEN : String = "fullScreen" [static] Définit la valeur de la propriété type d'un objet événement fullScreen.	Event
		ID3 : String = "id3" [static] Définit la valeur de la propriété type d'un objet événement id3.	Event
		INIT : String = "init" [static] Définit la valeur de la propriété type d'un objet événement init.	Event
		MOUSE_LEAVE : String = "mouseLeave" [static] Définit la valeur de la propriété type d'un objet événement mouseLeave.	Event
		OPEN : String = "open" [static] Définit la valeur de la propriété type d'un objet événement open.	Event
		REMOVED : String = "removed" [static] Définit la valeur de la propriété type d'un objet événement removed.	Event
		REMOVED_FROM_STAGE : String = "removedFromStage" [static] Définit la valeur de la propriété type d'un objet événement removedFromStage.	Event
		RENDER : String = "render" [static] Définit la valeur de la propriété type d'un objet événement render.	Event
		RESIZE : String = "resize" [static] Définit la valeur de la propriété type d'un objet événement resize.	Event
		SCROLL : String = "scroll" [static] Définit la valeur de la propriété type d'un objet événement scroll.	Event
		SELECT : String = "select" [static] Définit la valeur de la propriété type d'un objet événement select.	Event
		SOUND_COMPLETE : String = "soundComplete" [static] Définit la valeur de la propriété type d'un objet événement soundComplete.	Event
		TAB_CHILDREN_CHANGE : String = "tabChildrenChange" [static] Définit la valeur de la propriété type d'un objet événement tabChildrenChange.	Event
		TAB_ENABLED_CHANGE : String = "tabEnabledChange" [static] Définit la valeur de la propriété type d'un objet événement tabEnabledChange.	Event
		TAB_INDEX_CHANGE : String = "tabIndexChange" [static] Définit la valeur de la propriété type d'un objet événement tabIndexChange.	Event
		UNLOAD : String = "unload" [static] Définit la valeur de la propriété type d'un objet événement unload.	Event

Détails des propriétés

bubbles

propriété

bubbles:Boolean [lecture-seule]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Indique si un événement peut se propager vers le haut (bubbling). Si l'événement peut se propager vers le haut, cette valeur correspond àtrue ; dans tous les autres cas, elle correspond à false.

Lorsqu’un événement se produit, il se propage dans les trois phases du flux d’événements : La phase de capture, qui va du haut de la hiérarchie de la liste d’affichage au nœud précédant le nœud cible ; la phase cible, qui concerne uniquement le nœud cible ; la phase de propagation vers le haut (bubbling), qui remonte la hiérarchie de la liste d’affichage, en partant du nœud suivant le nœud cible.

Certains événements, tels que activate et unload, n’ont pas phase de propagation vers le haut. La propriété bubbles possède la valeur false pour les événements sans phase de propagation vers le haut (bubbling).

Implémentation
public function get bubbles():Boolean

Voir aussi

Objets événements

cancelable

propriété

cancelable:Boolean [lecture-seule]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Indique si le comportement associé à l’événement peut être annulé. Si tel est le cas, cette valeur correspond à true ; dans tous les autres cas, elle correspond à false.

Implémentation
public function get cancelable():Boolean

Voir aussi

Event.preventDefault()
Objets événements

currentTarget

propriété

currentTarget:Object [lecture-seule]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

L’objet qui traite activement l’objet Event avec un écouteur d’événements. Si un utilisateur clique sur un bouton OK par exemple, le nœud cible pourrait correspondre au nœud contenant ce bouton ou à l'un de ses ancêtres qui est associé à un écouteur d’événement pour cet événement.

Implémentation
public function get currentTarget():Object

Voir aussi

Objets événements

eventPhase

propriété

eventPhase:uint [lecture-seule]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Phase actuelle du flux d’événements. Cette propriété peut contenir les valeurs numériques suivantes :

1 Phase de capture (EventPhase.CAPTURING_PHASE).
2 Phase cible (EventPhase.AT_TARGET).
3 Phase de propagation vers le haut (bubbling) (EventPhase.BUBBLING_PHASE).

Implémentation
public function get eventPhase():uint

Voir aussi

Objets événements

target

propriété

target:Object [lecture-seule]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Cible de l’événement. Cette propriété contient le nœud cible. Si un utilisateur clique sur un bouton OK par exemple, le nœud cible correspond au nœud de la liste d’affichage qui contient ce bouton.

Implémentation
public function get target():Object

Voir aussi

Objets événements

type

propriété

type:String [lecture-seule]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Type d’événement. Le type respecte la casse.

Implémentation
public function get type():String

Voir aussi

Objets événements

Détails du constructeur

Event

()

Constructeur

public function Event(type:String, bubbles:Boolean = false, cancelable:Boolean = false)

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Crée un objet Event à transmettre en tant que paramètre aux écouteurs d’événements.

Paramètres

	`type:String` — Type de l’événement, accessible en tant que `Event.type`.

	`bubbles:Boolean` (default = `false`) — Détermine si l’objet Event prend part à la phase de propagation vers le haut (bubbling) du flux d’événements. La valeur par défaut est `false`.

	`cancelable:Boolean` (default = `false`) — Détermine si l’objet Event peut être annulé. La valeur par défaut est `false`.

Détails des méthodes

clone

()

méthode

public function clone():Event

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Duplique une occurrence d'une sous-classe Event.

Renvoie un nouvel objet Event, qui est une copie de l’occurrence d'origine de l’objet Event. En règle générale, vous n’appelez pas clone(). La classe EventDispatcher l’appelle automatiquement lorsque vous redistribuez un événement, en d’autres termes, lorsque vous appelez dispatchEvent(event) à partir du gestionnaire qui gère event.

Le nouvel objet Event comprend toutes les propriétés de l'objet d’origine.

Lorsque vous créez une classe Event personnalisée, vous devez bloquer la méthode Event.clone() héritée afin qu’elle duplique les propriétés de votre classe personnalisée. Si vous ne définissez pas toutes les propriétés que vous ajoutez à votre sous-classe Event, elles ne posséderont pas les valeurs correctes lorsque les écouteurs gèreront l’événement redistribué.

Dans cet exemple, PingEvent est une sous-classe de Event et implémente donc sa propre version de clone().

  class PingEvent extends Event { var URL:String; public override function clone():Event { return new PingEvent(type, bubbles, cancelable, URL); } }

Valeur renvoyée

Event — Nouvel objet Event identique à l'original.

Voir aussi

Objets événements

formatToString

()

méthode

public function formatToString(className:String, ... arguments):String

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Fonction d’un utilitaire permettant d'implémenter la méthode toString() dans votre classe Event personnalisée. Le blocage de la méthode toString() est recommandé, mais n’est pas obligatoire.

  class PingEvent extends Event { var URL:String; public override function toString():String { return formatToString("PingEvent", "type", "bubbles", "cancelable", "eventPhase", "URL"); } }

Paramètres

	`className:String` — Nom de votre classe Event personnalisée. Dans l'exemple précédent, le paramètre `className` est `PingEvent`.

	`... arguments` — Propriétés de la classe Event et propriétés que vous ajoutez à votre classe Event personnalisée. Dans l'exemple précédent, le paramètre `...arguments` comprend `type`, `bubbles`, `cancelable`, `eventPhase` et `URL`.

Valeur renvoyée

String — Nom de votre classe Event personnalisée et valeur de chaîne de votre paramètre ...arguments.

isDefaultPrevented

()

méthode

public function isDefaultPrevented():Boolean

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Vérifie si preventDefault() a été appelée pour l’événement. Si preventDefault() a été appelée, la valeur true est renvoyée ; dans le cas contraire, false est renvoyée.

Valeur renvoyée

Boolean — Si preventDefault() a été appelée, la valeur true est renvoyée ; dans le cas contraire, false est renvoyée.

Voir aussi

flash.events.Event.preventDefault()
Objets événements

preventDefault

()

méthode

public function preventDefault():void

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Annule le comportement par défaut d’un événement si cette opération est possible.

De nombreux événements sont associés à des comportements que Flash Player exécute par défaut. Par exemple, si un utilisateur tape un caractère dans un champ de texte, le comportement par défaut consiste à afficher le caractère dans le champ de texte. Comme le comportement par défaut de l’événement TextEvent.TEXT_INPUT peut être annulé, vous pouvez utiliser la méthode preventDefault() pour bloquer l’affichage du caractère.

Certains comportements par défaut ne peuvent pas être annulés, tel celui associé à l'événement Event.REMOVED, généré chaque fois que Flash Player est sur le point de supprimer un objet d'affichage dans la liste d’affichage. Le comportement par défaut (suppression de l’élément) ne pouvant pas être annulé, la méthode preventDefault() n’a aucun effet sur ce comportement par défaut.

Vous pouvez utiliser la propriété Event.cancelable pour vérifier s’il est possible d’annuler le comportement par défaut associé à un événement spécifique. Si la valeur de Event.cancelable est true, preventDefault() peut être utilisé pour annuler l'événement ; dans le cas contraire, preventDefault() n'a aucun effet.

Voir aussi

flash.events.Event.isDefaultPrevented()
Event.cancelable
Objets événements

stopImmediatePropagation

()

méthode

public function stopImmediatePropagation():void

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Bloque le traitement des écouteurs d’événement dans le nœud actuel et les suivants dans le flux d'événements. Cette méthode entre en vigueur immédiatement et affecte les écouteurs d’événement dans le nœud actuel. En revanche, la méthode stopPropagation() n’entre en vigueur qu’au terme du traitement de tous les écouteurs d’événement du nœud actuel.

Remarque : cette méthode n’annule pas le comportement associé à cet événement. Pour plus d’informations sur cette fonctionnalité, consultez preventDefault().

Voir aussi

flash.events.Event.stopPropagation()
flash.events.Event.preventDefault()
Objets événements

stopPropagation

()

méthode

public function stopPropagation():void

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Bloque le traitement des écouteurs d’événement dans les nœuds qui suivent le nœud actuel dans le flux d’événements. Cette méthode n’a aucune incidence sur les écouteurs d’événement du nœud actuel (currentTarget). En revanche, la méthode stopImmediatePropagation() bloque le traitement des écouteurs d’événement dans le nœud actuel et les suivants. D’autres appels de cette méthode sont sans effet. Cette méthode peut être appelée lors de toute phase du flux d’événements.

Remarque : cette méthode n’annule pas le comportement associé à cet événement. Pour plus d’informations sur cette fonctionnalité, consultez preventDefault().

Voir aussi

flash.events.Event.stopImmediatePropagation()
flash.events.Event.preventDefault()

toString

()

méthode

public function toString():String

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Renvoie une chaîne répertoriant toutes les propriétés de l'objet Event. La chaîne est écrite au format suivant :

[Event type=valeur bubbles=valeur cancelable=valeur]

Valeur renvoyée

String — Chaîne répertoriant toutes les propriétés de l'objet Event.

Voir aussi

Objets événements

Détails de la constante

ACTIVATE

Constante

public static const ACTIVATE:String = "activate"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d’un objet événement activate.

Remarque : cet événement ne passe pas par une « phase de capture » et est distribué directement à la cible, que cette dernière soit dans la liste d'affichage ou non.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Toute occurrence de DisplayObject à laquelle est associé un écouteur pour l’événement ACTIVATE.

Voir aussi

flash.events.EventDispatcher.activate
DEACTIVATE

ADDED

Constante

public static const ADDED:String = "added"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement added.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`true`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Occurrence de DisplayObject ajoutée à la liste d’affichage. La propriété `target` ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d'événements. Utilisez la propriété `currentTarget` pour accéder à l’objet de la liste d'affichage qui traite actuellement l'événement.

Voir aussi

flash.display.DisplayObject.added
ADDED_TO_STAGE
REMOVED
REMOVED_FROM_STAGE

ADDED_TO_STAGE

Constante

public static const ADDED_TO_STAGE:String = "addedToStage"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9.0.28.0

Définit la valeur de la propriété type d'un objet événement addedToStage.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Occurrence de DisplayObject ajoutée sur la scène à la liste d’affichage, directement ou par l'intermédiaire d'une arborescence secondaire qui contient l'occurrence DisplayObject. Si l'occurrence DisplayObject est ajoutée directement, l'événement `added` se produit avant cet événement.

Voir aussi

flash.display.DisplayObject.addedToStage
ADDED
REMOVED
REMOVED_FROM_STAGE

CANCEL

Constante

public static const CANCEL:String = "cancel"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement cancel.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Référence à l’objet pour lequel l'opération est annulée.

Voir aussi

flash.net.FileReference.cancel

CHANGE

Constante

public static const CHANGE:String = "change"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement change.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`true`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet dont la valeur a été modifiée. La propriété `target` ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d'événements. Utilisez la propriété `currentTarget` pour accéder à l’objet de la liste d'affichage qui traite actuellement l'événement.

Voir aussi

flash.text.TextField.change
flash.events.TextEvent.TEXT_INPUT

Constante

public static const CLOSE:String = "close"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement close.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet dont la connexion a été fermée.

Voir aussi

flash.net.Socket.close
flash.net.XMLSocket.close

COMPLETE

Constante

public static const COMPLETE:String = "complete"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement complete.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet réseau dont le chargement est terminé.

Voir aussi

flash.display.LoaderInfo.complete
flash.media.Sound.complete
flash.net.FileReference.complete
flash.net.URLLoader.complete
flash.net.URLStream.complete
Utilisation de données externes

CONNECT

Constante

public static const CONNECT:String = "connect"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement connect.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet Socket ou XMLSocket qui a établi une connexion réseau.

Voir aussi

flash.net.Socket.connect
flash.net.XMLSocket.connect

DEACTIVATE

Constante

public static const DEACTIVATE:String = "deactivate"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement deactivate.

Remarque : cet événement ne passe pas par une « phase de capture » et est distribué directement à la cible, que cette dernière soit dans la liste d'affichage ou non.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Toute occurrence de DisplayObject à laquelle est associé un écouteur pour l’événement DEACTIVATE.

Voir aussi

flash.events.EventDispatcher.deactivate
ACTIVATE

ENTER_FRAME

Constante

public static const ENTER_FRAME:String = "enterFrame"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement enterFrame.

Remarque : cet événement ne passe pas par une « phase de capture » et est distribué directement à la cible, que cette dernière soit dans la liste d'affichage ou non.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Toute occurrence de DisplayObject à laquelle est associé un écouteur pour l’événement ENTER_FRAME.

Voir aussi

flash.display.DisplayObject.enterFrame

FULLSCREEN

Constante

public static const FULLSCREEN:String = "fullScreen"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement fullScreen.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet Stage.

Voir aussi

flash.display.Stage.fullScreen

ID3

Constante

public static const ID3:String = "id3"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement id3.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet son chargeant le fichier MP3 pour lequel les données ID3 sont maintenant disponibles. La propriété `target` ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d'événements. Utilisez la propriété `currentTarget` pour accéder à l’objet de la liste d'affichage qui traite actuellement l'événement.

Voir aussi

flash.media.Sound.id3

INIT

Constante

public static const INIT:String = "init"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement init.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet LoaderInfo associé au fichier SWF en cours de chargement.

Voir aussi

flash.display.LoaderInfo.init

MOUSE_LEAVE

Constante

public static const MOUSE_LEAVE:String = "mouseLeave"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement mouseLeave.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet Stage. La propriété `target` ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d'événements. Utilisez la propriété `currentTarget` pour accéder à l’objet de la liste d'affichage qui traite actuellement l'événement.

Voir aussi

flash.display.Stage.mouseLeave
flash.events.MouseEvent

OPEN

Constante

public static const OPEN:String = "open"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement open.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet réseau qui a ouvert une connexion.

Voir aussi

flash.display.LoaderInfo.open
flash.media.Sound.open
flash.net.FileReference.open
flash.net.URLLoader.open
flash.net.URLStream.open

REMOVED

Constante

public static const REMOVED:String = "removed"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement removed.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`true`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Occurrence de DisplayObject à supprimer de la liste d’affichage. La propriété `target` ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d'événements. Utilisez la propriété `currentTarget` pour accéder à l’objet de la liste d'affichage qui traite actuellement l'événement.

Voir aussi

flash.display.DisplayObject.removed
ADDED
ADDED_TO_STAGE
REMOVED_FROM_STAGE

REMOVED_FROM_STAGE

Constante

public static const REMOVED_FROM_STAGE:String = "removedFromStage"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9.0.28.0

Définit la valeur de la propriété type d'un objet événement removedFromStage.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Occurrence de DisplayObject retirée de la liste d’affichage de la scène, directement ou par l'intermédiaire d'une arborescence secondaire qui contient l'occurrence DisplayObject. Si l'occurrence DisplayObject est retirée directement, l'événement `removed` se produit avant cet événement.

Voir aussi

flash.display.DisplayObject.removedFromStage
ADDED
REMOVED
ADDED_TO_STAGE

RENDER

Constante

public static const RENDER:String = "render"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement render.

Remarque : cet événement ne passe pas par une « phase de capture » et est distribué directement à la cible, que cette dernière soit dans la liste d'affichage ou non.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; le comportement par défaut ne peut pas être annulé.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Toute occurrence de DisplayObject à laquelle est associé un écouteur pour l’événement RENDER.

Voir aussi

flash.display.DisplayObject.render
flash.display.Stage.invalidate()

RESIZE

Constante

public static const RESIZE:String = "resize"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement resize.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet Stage.

Voir aussi

flash.display.Stage.resize

SCROLL

Constante

public static const SCROLL:String = "scroll"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement scroll.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet Textfield que l’utilisateur a fait défiler. La propriété `target` ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d'événements. Utilisez la propriété `currentTarget` pour accéder à l’objet de la liste d'affichage qui traite actuellement l'événement.

Voir aussi

flash.text.TextField.scroll

SELECT

Constante

public static const SELECT:String = "select"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement select.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	Objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet FileReference sur lequel un élément a été sélectionné.

Voir aussi

flash.net.FileReference.select

SOUND_COMPLETE

Constante

public static const SOUND_COMPLETE:String = "soundComplete"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement soundComplete.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet Sound dont la lecture d’un son est terminée.

Voir aussi

flash.media.SoundChannel.soundComplete

TAB_CHILDREN_CHANGE

Constante

public static const TAB_CHILDREN_CHANGE:String = "tabChildrenChange"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement tabChildrenChange.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`true`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet dont l’indicateur tabChildren a changé. La propriété `target` ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d'événements. Utilisez la propriété `currentTarget` pour accéder à l’objet de la liste d'affichage qui traite actuellement l'événement.

Voir aussi

flash.display.InteractiveObject.tabChildrenChange

TAB_ENABLED_CHANGE

Constante

public static const TAB_ENABLED_CHANGE:String = "tabEnabledChange"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement tabEnabledChange.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`true`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet InteractiveObject dont l’indicateur tabEnabled a changé. La propriété `target` ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d'événements. Utilisez la propriété `currentTarget` pour accéder à l’objet de la liste d'affichage qui traite actuellement l'événement.

Voir aussi

flash.display.InteractiveObject.tabEnabledChange

TAB_INDEX_CHANGE

Constante

public static const TAB_INDEX_CHANGE:String = "tabIndexChange"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement tabIndexChange.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`true`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet dont l’indicateur tabIndex a changé. La propriété `target` ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d'événements. Utilisez la propriété `currentTarget` pour accéder à l’objet de la liste d'affichage qui traite actuellement l'événement.

Voir aussi

flash.display.InteractiveObject.tabIndexChange

UNLOAD

Constante

public static const UNLOAD:String = "unload"

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit la valeur de la propriété type d'un objet événement unload.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`target`	Objet LoaderInfo associé au fichier SWF en cours de déchargement ou de remplacement.

Voir aussi

flash.display.LoaderInfo.unload

Exemples Utilisation des exemples

EventExample.as

L'exemple suivant utilise la classe EventExample et la classe personnalisée Square pour montrer comment gérer un événement qui peut se propager vers le haut (bubbling).

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;

    public class EventExample extends Sprite {
        
        public function EventExample() {
            var square_0:Square = new Square(300, 0x336633);
            addChild(square_0);
            
            var square_1:Square = new Square(250, 0x669966);
            square_0.addChild(square_1);

            var square_2:Square = new Square(200, 0x66CC66);
            square_1.addChild(square_2);

            var square_3:Square = new Square(150, 0xAA0000);
            square_3.shouldBubble = false;
            square_2.addChild(square_3);

            var square_4:Square = new Square(100, 0x66FF66);
            square_3.addChild(square_4);

            var square_5:Square = new Square(50, 0xCC0000);
            square_5.shouldBubble = false;
            square_4.addChild(square_5);

            this.addEventListener(MouseEvent.CLICK, clickHandler);
        }
        
        private function clickHandler(e:Event):void {
            trace(">> stage: " + e.type + " event from " + e.target.name + " called on " + this.name);
            trace(">> --------------------------------------------");
        }
    }
}

import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;

class Square extends Sprite {
    private var sideLen:int;
    private var color:Number;
    public var shouldBubble:Boolean = true;

    public function Square(sideLen:int, color:Number) {
        this.sideLen = sideLen;
        this.color = color;
        init();
        draw();
    }
        
    private function init():void {
        buttonMode = true;
        this.addEventListener(MouseEvent.CLICK, firstClickHandler);
        this.addEventListener(MouseEvent.CLICK, secondClickHandler);
        this.addEventListener(MouseEvent.CLICK, thirdClickHandler);
    }
        
    private function draw():void {
        this.graphics.beginFill(color);
        this.graphics.drawRect(0, 0, sideLen, sideLen);
    }
        
    private function firstClickHandler(e:Event):void {
        trace(">> 1e: " + e.type + " event from " + e.target.name + " called on " + this.name);
        if(!shouldBubble) {
            e.stopPropagation();
        }
    }

    private function secondClickHandler(e:Event):void {
        trace(">> 2e: " + e.type + " event from " + e.target.name + " called on " + this.name);
        if(!shouldBubble) {
            e.stopImmediatePropagation();
            trace(">> --------------------------------------------");
        }
    }

    private function thirdClickHandler(e:Event):void {
        trace(">> 3e: " + e.type + " event from " + e.target.name + " called on " + this.name);
    }
}

EventExample2.as

L'exemple suivant crée une démonstration interactive de la différence entre les événements ADDED et ADDED_TO_STAGE, ainsi que de la différence entre les événements REMOVED et REMOVED_FROM_STAGE. Le fait de cliquer sur un sprite entraîne sa suppression de la scène et la suppression de tout ce qu'il contient. Par exemple, le fait de cliquer sur le sprite le plus grand entraîne le déclenchement d'un événement REMOVED ainsi que de trois événements REMOVED_FROM_STAGE.

 package {
    import flash.display.Sprite;
    import flash.events.*;

    public class EventExample2 extends Sprite {
        public function EventExample2():void {
            var parentSprite:Sprite = createSprite("parentSprite",200);
            var childSprite:Sprite = createSprite("childSprite",100);
            var childOfChildSprite:Sprite = createSprite("childOfChildSprite",50);
            
            trace(":: Adding to Stage ::");
            this.addChild(parentSprite);
            trace(":: Adding to Stage ::");
            parentSprite.addChild(childSprite);
            trace(":: Adding to Stage ::");
            childSprite.addChild(childOfChildSprite);
        }
        private function createSprite(name:String,size:uint):Sprite {
            trace(":: Creating Sprite ::");
            var newSprite:Sprite = new Sprite();
            newSprite.name = name;
            newSprite.graphics.beginFill(0xFFFFFF * Math.random(),1);
            newSprite.graphics.drawRect(0,0,size,size);
            newSprite.graphics.endFill();
            newSprite.addEventListener(Event.ADDED, spriteAdded);
            newSprite.addEventListener(Event.ADDED_TO_STAGE, spriteAddedToStage);
            newSprite.addEventListener(Event.REMOVED, spriteRemoved);
            newSprite.addEventListener(Event.REMOVED_FROM_STAGE, spriteRemovedFromStage);
            newSprite.addEventListener(MouseEvent.CLICK, remove);
            return newSprite;
        }
        private function remove(event:Event) {
            if(event.target == event.currentTarget) {
                trace(":: Removing Clicked Sprite ::");
                var target:Sprite = Sprite(event.target);
                target.parent.removeChild(target);
            }
        }
        private function spriteRemovedFromStage(event:Event):void {
            trace("REMOVED_FROM_STAGE: " + event.target.name + " : " + event.currentTarget.name);
        }
        private function spriteRemoved(event:Event):void {
            trace("REMOVED: " + event.target.name + " from " + event.currentTarget.name);
        }
        private function spriteAddedToStage(event:Event):void {
            trace("ADDED_TO_STAGE: " + event.target.name + " : " + event.currentTarget.name);
        }
        private function spriteAdded(event:Event):void {
            trace("ADDED: " + event.target.name + " within " + event.currentTarget.name);
        }
    }
}

Page en cours: http://livedocs.adobe.com/flash/9.0_fr/ActionScriptLangRefV3/flash/events/Event.html

Guide de référence du langage et des composants ActionScript 3.0		Tous les packages \| Toutes les classes \| Eléments du langage \| Index \| Annexes \| Conventions \| Cadres Aucune image
Event	Propriétés \| Méthodes \| Constantes \| Exemples

Package	flash.events
Classe	public class Event
Héritage	Event Object
Sous-classes	ActivityEvent, CaptionChangeEvent, CaptionTargetEvent, ColorPickerEvent, ComponentEvent, ContextMenuEvent, DataChangeEvent, FocusEvent, HTTPStatusEvent, KeyboardEvent, LayoutEvent, ListEvent, MetadataEvent, MotionEvent, MouseEvent, NetStatusEvent, ProgressEvent, ScrollEvent, SliderEvent, SoundEvent, StatusEvent, SyncEvent, TextEvent, TimerEvent, TweenEvent, VideoEvent