Spécifie un objet d’affichage utilisé en tant qu’objet visuel associé à l’état Abaissé du bouton (l’état du bouton lorsque l’utilisateur clique sur l’objet hitTestState).

Voir aussi

Valeur booléenne spécifiant si un bouton est activé. Lorsqu'il est désactivé (la propriété enabled est alors réglée sur false), le bouton est visible mais vous ne pouvez pas cliquer dessus. La valeur par défaut est true. Cette propriété s'avère utile si vous souhaitez désactiver certains des boutons de navigation. Par exemple, il peut être souhaitable de désactiver un bouton dans la page actuellement affichée afin d'empêcher l’utilisateur de cliquer dessus et de recharger la page.

Spécifie un objet d’affichage utilisé en tant qu’objet de test de recherche pour le bouton. Pour un bouton de base, réglez la propriété hitTestState sur le même objet d’affichage que la propriété overState. Si vous ne réglez pas la propriété hitTestState, le bouton SimpleButton est inactif (il ne réagit pas aux événements de souris et de clavier).

Voir aussi

Spécifie un objet d’affichage utilisé en tant qu’objet visuel associé à l’état survol du bouton (l’état du bouton lorsque la souris est placée sur le bouton).

Voir aussi

Objet SoundTransform affecté au bouton. Un objet SoundTransform comprend les propriétés de réglage du volume, du déplacement panoramique, ainsi que des haut-parleurs gauche et droit. Il s’applique à tous les états du bouton. Cet objet SoundTransform n’affecte que les sons intégrés.

Voir aussi

Indique si d’autres objets d’affichage de type SimpleButton ou MovieClip peuvent recevoir des événements de relâchement de souris. La propriété trackAsMenu permet de créer des menus. Vous pouvez définir la propriété trackAsMenu sur n'importe quel objet SimpleButton ou MovieClip. Si la propriété trackAsMenu n'existe pas, la valeur du comportement par défaut devient false.

Vous pouvez modifier la propriété trackAsMenu à tout moment ; le bouton modifié accepte immédiatement le nouveau comportement.

Spécifie un objet d’affichage utilisé en tant qu’objet visuel associé à l’état relevé du bouton (l’état du bouton lorsque la souris n’est pas placée sur le bouton).

Voir aussi

Valeur booléenne qui, lorsqu'elle est réglée sur true, indique si Flash Player affiche un curseur en forme de main lorsque la souris survole un bouton. Si cette propriété est réglée sur false, le pointeur flèche s’affiche. La valeur par défaut est true.

Vous pouvez modifier la propriété useHandCursor à tout moment ; le bouton modifié accepte immédiatement le nouveau comportement du curseur.

Crée une occurrence de SimpleButton. Tout ou partie des objets d'affichage qui représentent les différents états de bouton peuvent être définis en tant que paramètres dans le constructeur.

1. Dans le constructeur SimpleButtonExample(), un nouvel objet CustomSimpleButton de type SimpleButton, appelé button, est créé, qui appelle ensuite la méthode de constructeur CustomSimpleButton. L'objet button est ajouté à la liste d'affichage. La couleur et la taille du bouton sont déterminées par les étapes suivantes.
2. Dans la classe CustomSimpleButton, les propriétés d'occurrence sont déclarées, puis utilisées pour contrôler la taille et la couleur d'arrière-plan de button en fonction de son état (orange dans son état normal, jaune sombre en cas de survol de la souris et bleu clair lorsque l'utilisateur clique sur l'un des boutons). Quel que soit l'état de button, la taille du carré est définie sur 80 pixels en utilisant la propriété size.
3. La fonction constructeur de la classe CustomSimpleButton définit les propriétés downState, overState, upState, hitTestState et useHandCursor avec quatre occurrences de la classe ButtonDisplayState.
4. Dans la classe ButtonDisplayState, le constructeur définit la valeur de la taille du carré et la couleur d'arrière-plan, puis appelle la méthode draw().
5. La méthode draw() redessine le carré avec la taille et la couleur d'arrière-plan définies dans le constructeur reposant sur l'état du bouton.

package {
    import flash.display.Sprite;

    public class SimpleButtonExample extends Sprite {
        public function SimpleButtonExample() {
            var button:CustomSimpleButton = new CustomSimpleButton();
            addChild(button);
        }
    }
}

import flash.display.DisplayObject;
import flash.display.Shape;
import flash.display.SimpleButton;

class CustomSimpleButton extends SimpleButton {
    private var upColor:uint   = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;
    private var size:uint      = 80;

    public function CustomSimpleButton() {
        downState      = new ButtonDisplayState(downColor, size);
        overState      = new ButtonDisplayState(overColor, size);
        upState        = new ButtonDisplayState(upColor, size);
        hitTestState   = new ButtonDisplayState(upColor, size * 2);
        hitTestState.x = -(size / 4);
        hitTestState.y = hitTestState.x;
        useHandCursor  = true;
    }
}

class ButtonDisplayState extends Shape {
    private var bgColor:uint;
    private var size:uint;

    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size    = size;
        draw();
    }

    private function draw():void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}