Contient l’objet d'affichage racine du fichier SWF ou du fichier d’image (JPG, PNG ou GIF) qui a été chargé à l’aide de la méthode load() ou loadBytes().

Voir aussi

Renvoie un objet LoaderInfo qui correspond à l’objet en cours de chargement. Les objets LoaderInfo sont partagés entre l’objet Loader et l’objet chargé. L’objet LoaderInfo fournit des informations relatives à la progression du déroulement du chargement et des statistiques sur le fichier chargé.

Les événements liés au chargement sont distribués par l'objet LoaderInfo qui est référencé par la propriété contentLoaderInfo de l'objet Loader. La propriété contentLoaderInfo est définie sur un objet LoaderInfo valide, y compris avant le chargement du contenu, ce qui permet d'ajouter des écouteurs d'événements à l'objet avant l'opération de chargement.

Voir aussi

Crée un objet Loader qui permet de charger des fichiers (SWF, JPEG, GIF ou PNG). Appelez la méthode load() pour charger la ressource en tant qu’enfant de l’occurrence de Loader. Vous pouvez alors ajouter l’objet Loader à la liste d’affichage (par le biais de la méthode addChild() d’une occurrence de DisplayObjectContainer, par exemple). La ressource apparaît sur la scène au fur et à mesure de son chargement.

Vous pouvez également utiliser une occurrence de Loader sans l’intégrer à un conteneur d’objet d’affichage de la liste d’affichage. Si ce mode est activé, l’occurrence de Loader peut être utilisée pour charger un fichier SWF contenant d’autres modules d’une application.

Pour détecter la fin du chargement du fichier SWF, vous disposez des événements de l’objet LoaderInfo associés à la propriété contentLoaderInfo de l’objet Loader. A ce stade, vous pouvez exécuter le code du fichier SWF du module pour initialiser et démarrer ce dernier. En mode hors liste, l’occurrence de Loader peut également être utilisée pour charger un fichier SWF contenant des composants ou des ressources multimédias. Il est également possible d’utiliser les notifications d’événement associées à l’objet LoaderInfo pour détecter la fin du chargement des composants. L’application peut alors commencer à utiliser les composants et les ressources multimédias intégrés à la bibliothèque du fichier SWF en instanciant les classes ActionScript 3.0 qui représentent ces composants et ces ressources.

Pour déterminer le statut d'un objet Loader, supervisez les événements suivants que l'objet LoaderInfo a associé à la propriété contentLoaderInfo de l'objet Loader :

• L’événement open est distribué lorsque le chargement commence.
• L’événement ioError ou securityError est distribué s'il est impossible de charger le fichier ou s'il se produit une erreur lors du processus de chargement.
• L’événement progress est déclenché continuellement lors du chargement du fichier.
• L’événement complete est distribué lorsque le chargement d’un fichier est terminé, mais avant la mise à disposition des méthodes et des propriétés du clip qui vient d'être chargé.
• L’événement init est distribué après la mise à disposition des méthodes et des propriétés du fichier SWF chargé, afin de vous permettre de commencer à manipuler ce dernier. Cet événement est distribué avant le gestionnaire complete. Dans les fichiers SWF en diffusion continue, l’événement init risque de se produire bien avant l’événement complete. Dans la plupart des cas, utilisez le gestionnaire init.

Voir aussi

Annule une opération associée à la méthode load() qui est en cours d'exécution pour l'occurrence de Loader.

Voir aussi

Charge un fichier SWF, JPEG, JPEG progressif, GIF non animé ou PNG dans un objet enfant de l’objet Loader. Si vous chargez un fichier GIF animé, seule la première image est affichée. Puisque l’objet Loader ne peut contenir qu’un seul enfant, générer une nouvelle requête load() met fin à la requête précédente si elle est en attente et démarre un autre chargement.

Un fichier SWF ou une image chargé(e) dans un objet Loader hérite des propriétés position, rotation et scale (échelle) des objets d'affichage parent de l’objet Loader.

Utilisez unload() pour supprimer des animations ou des images chargées à l'aide de cette méthode ou pour annuler une opération de chargement en cours.

Pour utiliser la méthode load(), tenez compte du modèle de sécurité de Flash Player :

• Vous pouvez charger du contenu à partir de toute source accessible.
• Le chargement n'est pas autorisé si le fichier SWF appelant est sur un sandbox réseau et que le fichier à charger est local.
• Si le contenu chargé est un fichier SWF, il ne peut pas être écrit par un fichier SWF appartenant à un autre sandbox de sécurité, à moins que des dispositions d’intercodage n’aient été approuvées par le biais d’un appel à la méthode Security.allowDomain() dans le fichier de contenu chargé.
• Les fichiers SWF écrits en langage ActionScript 1.0 ou 2.0, qui sont chargés en tant qu’objets AVM1Movie, ne peuvent pas intercoder les fichiers SWF écrits en langage ActionScript 3.0, qui sont chargés en tant qu’objets Sprite ou MovieClip. La classe LocalConnection vous permet de faire communiquer ces fichiers.
• Si le contenu chargé est une image, un fichier SWF situé en dehors du sandbox de sécurité ne peut pas accéder aux données correspondantes, à moins que le domaine de ce fichier n’ait été inclus dans un fichier de régulation interdomaine dans le domaine d’origine de l’image.
• Les clips situés dans le sandbox local avec système de fichier ne peuvent pas intercoder des clips dans le sandbox local avec accès au réseau (l'inverse est également impossible).
• Vous pouvez empêcher un fichier SWF d'utiliser cette méthode en définissant le paramètre allowNetworking des balises object et embed dans la page HTML qui comporte le contenu SWF.

Pour plus d'informations, consultez les références suivantes :

• Le chapitre relatif à la sécurité du manuel Programmation d'ActionScript 3.0 et les derniers commentaires disponibles dans LiveDocs
• Le Livre blanc sur la sécurité de Flash Player 9

Paramètres

Voir aussi

Charge des données binaires stockées dans un objet ByteArray.

Paramètres

Voir aussi

Supprime un enfant de l’objet Loader chargé à l’aide de la méthode load(). La valeur property de la propriéténull de l’objet LoaderInfo associé est réinitialisée. L’enfant n’est pas nécessairement détruit, car d’autres objets risquent de s'y référer. Il n’est cependant plus un enfant de l’objet Loader.

Avant de décharger un fichier SWF enfant, il est recommandé de fermer explicitement tout flux continu dans les objets enfants du fichier SWF, tels que les objets LocalConnection, NetConnection, NetStream et Sound. Si vous n’effectuez pas cette opération, la lecture de l’audio risque de continuer dans le fichier SWF enfant, bien que ce dernier soit déchargé. Pour fermer les flux continus dans le fichier SWF enfant, ajoutez un écouteur d’événement à l’enfant qui écoute l’événement unload. Lorsque le parent appelle Loader.unload(), l’événement unload est distribué à l'enfant. L'exemple suivant illustre cette opération :

function closeAllStreams(evt:Event) { 
    myNetStream.close();
    mySound.close();
    myNetConnection.close();
    myLocalConnection.close();
}

myMovieClip.loaderInfo.addEventListener(Event.UNLOAD, closeAllStreams);

Voir aussi

1. Une propriété url est créée pour désigner l'emplacement et le nom du fichier d'image.
2. Dans le constructeur LoaderExample, un nouvel objet Loader appelé loader est créé, qui est ensuite transmis à la méthode configureListeners(), décrite à l'étape 3.
3. Le constructeur crée une occurrence d'objet URLRequest, request, et transmet le paramètre url de façon à identifier le nom de fichier et son emplacement.
4. L'objet request est ensuite transmis à la méthode load() de l'objet loader, qui charge l'image dans la liste d'affichage.
5. Un écouteur d'événements clickHandler est enregistré pour l'événement click sur l'objet loader. Lorsque l'utilisateur clique avec la souris, l'image chargée est déchargée.
6. La méthode configureListeners() ajoute sept écouteurs d'événements à l'aide des méthodes suivantes :
   • La méthode completeHandler() s'exécute lorsque l'image termine son chargement.
   • La méthode httpStatusHandler() s'exécute lorsque l'image n'est pas chargée de façon locale et uniquement lorsque la requête réseau est rendue disponible et lorsque Flash Player peut la détecter.
   • La méthode initHandler() s'exécute avant la méthode completeHandler() et après la méthode progressHandler(). En général, l'événement init est plus utile lors du chargement des fichiers SWF.
   • La méthode ioErrorHandler() s'exécute si le fichier d'image n'est pas disponible ou n'est pas accessible.
   • La méthode openHandler() s'exécute lorsque le fichier d'image est ouvert en premier.
   • La méthode progressHandler() s'exécute lorsque le fichier d'image commence son chargement et s'exécute de nouveau à la fin de cette procédure.
   • La méthode unLoadHandler() s'exécute lorsque l'image est déchargée à l'aide de la méthode unload() lorsque l'utilisateur clique sur l'image.

N'oubliez pas les spécifications suivantes :

• Cet exemple implique le placement d'un fichier appelé Image.gif dans le même répertoire que le fichier SWF compilé. Utilisez une image dont la zone corresponde aux dimensions du fichier SWF principal.
• Cet exemple couvre tous les événements disponibles pour l'objet LoaderInfo. Cependant, la plupart des situations n'en nécessite qu'un sous-ensemble. En particulier, lors du chargement d'un fichier d'image unique, l'événement complete (voire l'événement ioError) suffisent lors du chargement d'une image locale.

package {
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.URLRequest;

    public class LoaderExample extends Sprite {
        private var url:String = "Image.gif";

        public function LoaderExample() {
            var loader:Loader = new Loader();
            configureListeners(loader.contentLoaderInfo);
            loader.addEventListener(MouseEvent.CLICK, clickHandler);

            var request:URLRequest = new URLRequest(url);
            loader.load(request);

            addChild(loader);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(Event.INIT, initHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(Event.UNLOAD, unLoadHandler);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function initHandler(event:Event):void {
            trace("initHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler: bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function unLoadHandler(event:Event):void {
            trace("unLoadHandler: " + event);
        }

        private function clickHandler(event:MouseEvent):void {
            trace("clickHandler: " + event);
            var loader:Loader = Loader(event.target);
            loader.unload();
        }
    }
}