Packageflash.display
Classepublic final class JointStyle
HéritageJointStyle Inheritance Object

Version du langage : ActionScript 3.0
Version du lecteur : Flash Player 9

La classe JointStyle est une énumération de valeurs constantes qui spécifient le style de liaison à utiliser pour tracer les lignes. Ces constantes sont utilisées en tant que valeurs du paramètre joints dans la méthode flash.display.Graphics.lineStyle(). Cette méthode prend en charge trois types de pointe : miter, round et bevel, comme indiqué dans l'exemple suivant :

Consulter les exemples

Voir aussi

flash.display.Graphics.lineStyle()

Propriétés publiques
 PropriétéDéfini par
 Inheritedconstructor : Object
Référence à l'objet de classe ou à la fonction constructeur d'une occurrence donnée d'un objet.
Object
 Inheritedprototype : Object
[static] Référence à l’objet prototype d’un objet de classe ou fonction.
Object
Méthodes publiques
 MéthodeDéfini par
 Inherited
hasOwnProperty(name:String):Boolean
Indique si la propriété spécifiée d'un objet est définie.
Object
 Inherited
isPrototypeOf(theClass:Object):Boolean
Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l'objet spécifié en tant que paramètre.
Object
 Inherited
propertyIsEnumerable(name:String):Boolean
Indique si la propriété spécifiée existe et est énumérable.
Object
 Inherited
setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void
Définit la disponibilité d'une propriété dynamique pour les opérations en boucle.
Object
 Inherited
toString():String
Renvoie la représentation sous forme de chaîne de l'objet spécifié.
Object
 Inherited
valueOf():Object
Renvoie la valeur primitive de l'objet spécifié.
Object
Constantes publiques
 ConstanteDéfini par
  BEVEL : String = "bevel"
[static] Spécifie des liaisons biseautées dans le paramètre joints de la méthode flash.display.Graphics.lineStyle().
JointStyle
  MITER : String = "miter"
[static] Spécifie des liaisons en pointe dans le paramètre joints de la méthode flash.display.Graphics.lineStyle().
JointStyle
  ROUND : String = "round"
[static] Spécifie des liaisons rondes dans le paramètre joints de la méthode flash.display.Graphics.lineStyle().
JointStyle
Détails de la constante
BEVELConstante
public static const BEVEL:String = "bevel"

Version du langage : ActionScript 3.0
Version du lecteur : Flash Player 9

Spécifie des liaisons biseautées dans le paramètre joints de la méthode flash.display.Graphics.lineStyle().

MITERConstante 
public static const MITER:String = "miter"

Version du langage : ActionScript 3.0
Version du lecteur : Flash Player 9

Spécifie des liaisons en pointe dans le paramètre joints de la méthode flash.display.Graphics.lineStyle().

ROUNDConstante 
public static const ROUND:String = "round"

Version du langage : ActionScript 3.0
Version du lecteur : Flash Player 9

Spécifie des liaisons rondes dans le paramètre joints de la méthode flash.display.Graphics.lineStyle().

Exemples Utilisation des exemples
JointStyleExample.as

L'exemple suivant utilise la classe JointStyleExample pour afficher le résultat de trois styles de joints distincts qui sont appliqués à trois ensembles de liaisons de lignes. Pour ce faire, procédez comme suit :
  1. Les propriétés de chaque ligne sont définies comme suit :
    • La longueur de ligne est définie sur 80 pixels.
    • La couleur de la bordure est définie sur orange.
    • La taille de la bordure est définie sur 30 pixels.
    • La couleur de surbrillance est définie sur gris.
    • La taille de la surbrillance est définie sur zéro pixels.
    • La valeur alpha est définie sur 1, ce qui rend la couleur unie.
    • L'indice de lissage des pixels est défini sur false (les traits ne sont pas transformés en pixels).
    • Le mode de mise à l'échelle de la ligne est défini sur normal. Ce mode porte sur l'épaisseur de la ligne.
    • Les extrémités de la bordure et la limite de pointe sont déclarées sans être définies, de façon à appliquer les valeurs par défaut.
  2. Le constructeur de classe crée trois ensembles de deux segments de ligne connectés. Les segments commencent à x = 0, y = 0 en appelant trois fois la méthode doDrawCorner() à l'aide des trois styles de liaison (miter, round et bevel). Chacun des trois appels à doDrawCorner() applique le style liaison et les propriétés énumérées précédemment pour dessiner deux segments de ligne connectés et les lignes de surbrillance correspondantes. Cette opération peut s'exécuter en créant un objet Shape, child, puis exploite les méthodes de la classe Graphics pour définir le style de ligne et dessiner les lignes et les surbrillances. Chaque occurrence de child s'ajoute à la liste d'affichage et est dessinée rapidement sur la scène.
  3. Les segments de ligne connectés sont redessinés avec la méthode refreshLayout() à y = 80 pixels et commence à x = 80 pixels, avec une séparation de 25 pixels entre les segments de ligne.
package {
    import flash.display.DisplayObject;
    import flash.display.Graphics;
    import flash.display.JointStyle;
    import flash.display.LineScaleMode;
    import flash.display.Shape;
    import flash.display.Sprite;

    public class JointStyleExample extends Sprite {
        private var size:uint                  = 80;
        private var borderColor:uint           = 0xFFCC00;
        private var borderSize:uint            = 30;
        private var highlightColor:uint        = 0x666666;
        private var highlightSize:uint         = 0;
        private var gutter:uint                = 25;
        private var borderAlpha:uint           = 1;
        private var borderPixelHinting:Boolean = false;
        private var borderScaleMode:String     = LineScaleMode.NORMAL;
        private var borderCaps:String;
        private var borderMiterLimit:uint;

        public function JointStyleExample() {
            doDrawCorner(JointStyle.MITER);
            doDrawCorner(JointStyle.ROUND);
            doDrawCorner(JointStyle.BEVEL);
            refreshLayout();
        }

        private function doDrawCorner(jointStyle:String):void {
            var halfSize:uint = Math.round(size / 2);
            var child:Shape = new Shape();
            child.graphics.lineStyle(borderSize,
                                     borderColor,
                                     borderAlpha,
                                     borderPixelHinting,
                                     borderScaleMode,
                                     borderCaps,
                                     jointStyle,
                                     borderMiterLimit);
            child.graphics.lineTo(0, 0);
            child.graphics.lineTo(size, 0);
            child.graphics.lineTo(halfSize, size);
            child.graphics.endFill();

            child.graphics.moveTo(0, 0);
            child.graphics.lineStyle(highlightSize, highlightColor);
            child.graphics.lineTo(0, 0);
            child.graphics.lineTo(size, 0);
            child.graphics.lineTo(halfSize, size);

            addChild(child);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject;
            var lastChild:DisplayObject = getChildAt(0);
            lastChild.x = size;
            lastChild.y = size;
            for (var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = gutter + lastChild.x + lastChild.width;
                child.y = size;
                lastChild = child;
            }
        }
    }
}



© 2004-2007 Adobe Systems Incorporated. Tous droits réservés.
Fri Oct 12 2007, 2:53 AM GMT-07:00

 

M'envoyer un message électronique lorsque des commentaires sont ajoutés à cette page | Rapport de commentaire

Page en cours: http://livedocs.adobe.com/flash/9.0_fr/ActionScriptLangRefV3/flash/display/JointStyle.html