Objet BitmapData référencé.

Contrôle si l’objet Bitmap est accroché ou non au pixel le plus proche. La classe PixelSnapping inclut les valeurs possibles :

• PixelSnapping.NEVER — L’accrochage au pixel est désactivé.
• PixelSnapping.ALWAYS — L’image est toujours accrochée au pixel le plus proche, quelle que soit la transformation appliquée.
• PixelSnapping.AUTO — L’image bitmap est accrochée au pixel le plus proche si elle est dessinée sans rotation ni inclinaison et que son facteur de redimensionnement est compris entre 99,9 % et 100,1 %. Si ces conditions sont remplies, l’image bitmap est dessinée à l’échelle 100 % et accrochée au pixel le plus proche. En interne, cette valeur permet de dessiner l’image aussi rapidement que possible à l’aide de la fonctionnalité de rendu vectoriel.

Contrôle si le·bitmap est lissé lorsqu’elle est dimensionnée. Si le paramètre est défini sur true, le·bitmap est lissé. S’il est défini sur false, le·bitmap n’est pas lissé.

Initialise un objet Bitmap pour qu’il fasse référence à l’objet BitmapData spécifié.

	bitmapData:BitmapData (default = null) — Objet BitmapData référencé.
	pixelSnapping:String (default = "auto") — Indique si l’objet Bitmap est accroché ou non au pixel le plus proche.
	smoothing:Boolean (default = false) — Indique si le·bitmap est lissé lorsqu’elle est dimensionnée. Les exemples ci-dessous illustrent le même bitmap multiplié par trois, smoothing étant réglé sur false (gauche) et true (droite) :

1. Une propriété url est créée pour désigner l'emplacement et le nom du fichier d'image.
2. Le constructeur de classe appelle la méthode configureAssets(), qui en retour appelle la méthode completeHandler().
3. configureAssets() crée un objet Loader, qui crée à son tour un écouteur d'événements, qui est transmis lorsque completeHandler() termine la manipulation de l'image.
4. Ensuite, la méthode buildChild() crée une occurrence d'objet URLRequest, request, et transmet le paramètre url de façon à identifier le nom de fichier et son emplacement.
5. L'objet request est ensuite transmis à la méthode loader.load(), qui charge l'image en mémoire à l'aide d'un objet d'affichage.
6. L'image est ensuite placée dans la liste d'affichage, qui affiche rapidement l'image aux coordonnées x = 0, y = 0.
7. La méthode completeHandler() effectue ensuite les opérations suivantes :
   1. Crée un deuxième objet Loader, ainsi qu'un objet Bitmap, qui est initialisé avec l'objet Loader.
   2. Crée un deuxième objet Bitmap, duplicate, qui appelle en retour la méthode duplicateImage(), qui crée elle-même un double de l'image d'origine.
   3. Crée un objet BitmapData qui est associé à l'objet BitmapData de l'objet duplicate.
   4. Crée un objet Rectangle qui est initialisé avec les mêmes coordonnées, la même largeur et hauteur, que l'image d'origine.
   5. Crée un objet Point, qui emploie par défaut les coordonnées x = 0, y = 0.
   6. Crée les variables suivantes :
      • operation : applique la nouvelle couleur lorsque la valeur de seuil est >= à l'original.
      • threshold : la valeur de comparaison des pixels est définie sur gris clair, avec un alpha de 0xCC.
      • color : la couleur des pixels qui répondent aux critères imposés, soit jaune uni dans ce cas.
      • mask : le contraire exact de la couleur (bleu transparent).
      • copySource : défini sur false, indique que les valeurs des pixels ne sont pas copiées dans l'événement si la valeur de seuil n'est pas acceptable. Cette valeur n'a aucune signification, car l'image est dupliquée et seuls les pixels qui répondent aux critères de seuil sont modifiés.
   7. Appelle la méthode threshold() à l'aide des variables précédentes. L'équation de seuil qui en résulte figure ci-dessous : if (current pixel Value & 0x000000FF) >= (0xCCCCCCCC & 0x000000FF) then set pixel to 0xFFFFFF00.

Remarques :

• Vous devrez compiler le fichier SWF en réglant « Sécurité de lecture locale » sur « Accès aux fichiers locaux uniquement ».
• Pour exécuter cet exemple, il est nécessaire de placer un fichier intitulé Image.txt dans le même répertoire que votre fichier SWF.
• Il est recommandé d'utiliser une image qui ne dépasse pas 80 pixels de largeur.

package {
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.Sprite;
    import flash.events.*;
    import flash.geom.Point;
    import flash.geom.Rectangle;
    import flash.net.URLRequest;

    public class BitmapExample extends Sprite {
        private var url:String = "Image.gif";
        private var size:uint = 80;

        public function BitmapExample() {
            configureAssets();
        }

        private function configureAssets():void {
            var loader:Loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler);
            loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

            var request:URLRequest = new URLRequest(url);
            loader.x = size * numChildren;
            loader.load(request);
            addChild(loader);
        }

        private function duplicateImage(original:Bitmap):Bitmap {
            var image:Bitmap = new Bitmap(original.bitmapData.clone());
            image.x = size * numChildren;
            addChild(image);
            return image;
        }

        private function completeHandler(event:Event):void {
            var loader:Loader = Loader(event.target.loader);
            var image:Bitmap = Bitmap(loader.content);

            var duplicate:Bitmap = duplicateImage(image);
            var bitmapData:BitmapData = duplicate.bitmapData;
            var sourceRect:Rectangle = new Rectangle(0, 0, bitmapData.width, bitmapData.height);
            var destPoint:Point = new Point();
            var operation:String = ">=";
            var threshold:uint = 0xCCCCCCCC;
            var color:uint = 0xFFFFFF00;
            var mask:uint = 0x000000FF;
            var copySource:Boolean = true;

            bitmapData.threshold(bitmapData,
                                 sourceRect,
                                 destPoint,
                                 operation,
                                 threshold,
                                 color,
                                 mask,
                                 copySource);
        }
        
        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("Unable to load image: " + url);
        }
    }
}