fl.controls.LabelButton (ActionScript 3.0)

Propriétés publiques

Masquer les propriétés publiques héritées

Afficher les propriétés publiques héritées

	Propriété		Défini par
		accessibilityProperties : AccessibilityProperties Options d’accessibilité actuelles de l’objet d’affichage.	DisplayObject
		alpha : Number Indique la valeur de transparence alpha de l'objet spécifié.	DisplayObject
		autoRepeat : Boolean Récupère ou définit une valeur booléenne qui indique si l'événement buttonDown est distribué plusieurs fois lorsque l'utilisateur maintient le bouton de la souris enfoncé sur le composant.	BaseButton
		blendMode : String Valeur de la classe BlendMode qui spécifie le mode de fondu à utiliser.	DisplayObject
		buttonMode : Boolean Spécifie le mode de bouton du sprite.	Sprite
		cacheAsBitmap : Boolean Si true est défini, Flash Player place en mémoire cache une version bitmap interne de l’objet d'affichage.	DisplayObject
		constructor : Object Référence à l'objet de classe ou à la fonction constructeur d'une occurrence donnée d'un objet.	Object
		contextMenu : ContextMenu Spécifie le menu contextuel associé à l’objet.	InteractiveObject
		doubleClickEnabled : Boolean Spécifie si l’objet reçoit les événements doubleClick.	InteractiveObject
		dropTarget : DisplayObject [lecture-seule] Spécifie l’objet d’affichage sur lequel le sprite est glissé ou sur lequel il a été déposé.	Sprite
		enabled : Boolean Lit ou définit une valeur qui indique si le composant peut accepter une entrée de l'utilisateur.	BaseButton
		filters : Array Tableau indexé contenant tous les objets filtre actuellement associés à l’objet d’affichage.	DisplayObject
		focusEnabled : Boolean Récupère ou définit une valeur booléenne indiquant si le composant peut recevoir le focus après un clic de l'utilisateur sur son entrée.	UIComponent
		focusManager : IFocusManager Récupère ou définit le FocusManager qui contrôle le focus pour ce composant et ses homologues.	UIComponent
		focusRect : Object Spécifie si l’objet affiche un rectangle de focus.	InteractiveObject
		graphics : Graphics [lecture-seule] Spécifie l’objet Graphics appartenant au sprite qui prend en charge les commandes de dessin vectoriel.	Sprite
		height : Number Récupère ou définit la hauteur du composant, en pixels.	UIComponent
		hitArea : Sprite Désigne un autre sprite qui fera office de zone active d'un sprite.	Sprite
		label : String Récupère ou définit l'étiquette de texte du composant.	LabelButton
		labelPlacement : String Position de l'étiquette par rapport à une icône spécifique.	LabelButton
		loaderInfo : LoaderInfo [lecture-seule] Renvoie un objet LoaderInfo qui contient des informations relatives au chargement du fichier auquel appartient cet objet d’affichage.	DisplayObject
		mask : DisplayObject L’objet d’affichage appelant est masqué par l’objet mask spécifié.	DisplayObject
		mouseChildren : Boolean Détermine si les enfants de l’objet prennent ou non en charge la souris.	DisplayObjectContainer
		mouseEnabled : Boolean Spécifie si l’objet reçoit les messages souris.	InteractiveObject
		mouseFocusEnabled : Boolean Récupère ou définit une valeur indiquant si le composant peut recevoir le focus après un clic de l'utilisateur sur son entrée.	UIComponent
		mouseX : Number [lecture-seule] Indique la coordonnée x de la position de la souris, en pixels.	DisplayObject
		mouseY : Number [lecture-seule] Indique la coordonnée y de la position de la souris, en pixels.	DisplayObject
		name : String Indique le nom d’occurrence de DisplayObject.	DisplayObject
		numChildren : int [lecture-seule] Renvoie le nombre d'enfants de l’objet.	DisplayObjectContainer
		opaqueBackground : Object Indique si l’objet d’affichage est opaque avec une couleur d'arrière-plan spécifique.	DisplayObject
		parent : DisplayObjectContainer [lecture-seule] Indique l’objet DisplayObjectContainer qui contient l’objet d’affichage.	DisplayObject
		prototype : Object [static] Référence à l’objet prototype d’un objet de classe ou fonction.	Object
		root : DisplayObject [lecture-seule] Pour un objet d’affichage résidant dans un fichier SWF chargé, la propriété root correspond à l’objet d’affichage de premier niveau dans la partie de la structure arborescente de la liste d’affichage représentée par ce fichier.	DisplayObject
		rotation : Number Indique la rotation de l'occurrence de DisplayObject, en degrés, à partir de son orientation d'origine.	DisplayObject
		scale9Grid : Rectangle Grille de mise à l’échelle en vigueur.	DisplayObject
		scaleX : Number Multiplie la largeur actuelle du composant par un facteur de redimensionnement.	UIComponent
		scaleY : Number Multiplie la hauteur actuelle du composant par un facteur de redimensionnement.	UIComponent
		scrollRect : Rectangle Cadre de délimitation du défilement de l’objet d’affichage.	DisplayObject
		selected : Boolean Lit ou définit une valeur booléenne qui indique si un bouton de basculement est en position activée ou désactivée.	LabelButton
		soundTransform : SoundTransform Contrôle le son à l’intérieur du sprite.	Sprite
		stage : Stage [lecture-seule] Scène de l’objet d’affichage.	DisplayObject
		tabChildren : Boolean Détermine si les enfants de l’objet prennent ou non en charge la tabulation.	DisplayObjectContainer
		tabEnabled : Boolean Indique si cet objet est spécifié dans l’ordre de tabulation.	InteractiveObject
		tabIndex : int Spécifie l'ordre de tabulation des objets dans un fichier SWF.	InteractiveObject
		textField : TextField Une référence au champ de texte interne du composant.	LabelButton
		textSnapshot : TextSnapshot [lecture-seule] Renvoie un objet TextSnapshot pour l’occurrence de DisplayObjectContainer.	DisplayObjectContainer
		toggle : Boolean Lit ou définit une valeur booléenne qui indique si un bouton peut être activé ou désactivé.	LabelButton
		transform : Transform Objet dont les propriétés se rapportent à la matrice, à la transformation des couleurs et aux limites des pixels d’un objet d’affichage.	DisplayObject
		useHandCursor : Boolean Valeur booléenne indiquant si le curseur en forme de main apparaît lorsque la souris survole un sprite dont la propriété buttonMode est réglée sur true.	Sprite
		version : String = "3.0.0.15" Numéro de version des composants.	UIComponent
		visible : Boolean Récupère ou définit une valeur indiquant si l'occurrence du composant actif est visible.	UIComponent
		width : Number Récupère ou définit la largeur du composant, en pixels.	UIComponent
		x : Number Récupère ou définit la coordonnée x représentant la position du composant le long de l'axe x au sein de son conteneur parent.	UIComponent
		y : Number Récupère ou définit la coordonnée y représentant la position du composant le long de l'axe y au sein de son conteneur parent.	UIComponent

Méthodes publiques

Masquer les méthodes publiques héritées

Afficher les méthodes publiques héritées

	Méthode		Défini par
		LabelButton() Crée une nouvelle occurrence du composant LabelButton.	LabelButton
		addChild(child:DisplayObject):DisplayObject Ajoute une occurrence enfant de DisplayObject à cette occurrence de DisplayObjectContainer.	DisplayObjectContainer
		addChildAt(child:DisplayObject, index:int):DisplayObject Ajoute une occurrence enfant de DisplayObject à cette occurrence de DisplayObjectContainer.	DisplayObjectContainer
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Enregistre un objet écouteur d’événement auprès d’un objet EventDispatcher afin que l’écouteur soit averti d’un événement.	EventDispatcher
		areInaccessibleObjectsUnderPoint(point:Point):Boolean Indique si les restrictions de sécurité entraîneraient l’omission des objets d’affichage de la liste renvoyée en appelant la méthode DisplayObjectContainer.getObjectsUnderPoint() avec le point « point » spécifié.	DisplayObjectContainer
		clearStyle(style:String):void Définit une propriété de style depuis cette occurrence de composant.	UIComponent
		contains(child:DisplayObject):Boolean Détermine si l’objet d'affichage spécifié est un enfant de l’occurrence de DisplayObjectContainer ou l’occurrence en tant que telle.	DisplayObjectContainer
		dispatchEvent(event:Event):Boolean Distribue un événement dans le flux d’événements.	EventDispatcher
		drawFocus(focused:Boolean):void Affiche ou masque l'indicateur de focus dans ce composant.	UIComponent
		drawNow():void Déclenche une opération de dessin immédiate, sans tout annuler comme le fait invalidateNow.	UIComponent
		getBounds(targetCoordinateSpace:DisplayObject):Rectangle Renvoie un rectangle qui définit la zone de l’objet d’affichage relativement au système de coordonnées de l’objet targetCoordinateSpace.	DisplayObject
		getChildAt(index:int):DisplayObject Renvoie l’occurrence enfant de l’objet d’affichage associée à l’index spécifié.	DisplayObjectContainer
		getChildByName(name:String):DisplayObject Renvoie l’objet d’affichage enfant portant le nom spécifié.	DisplayObjectContainer
		getChildIndex(child:DisplayObject):int Renvoie la position d’index d’une occurrence enfant de DisplayObject.	DisplayObjectContainer
		getFocus():InteractiveObject Récupère l'objet qui détient actuellement le focus.	UIComponent
		getObjectsUnderPoint(point:Point):Array Renvoie un tableau d’objets de niveau inférieur au point spécifié et qui sont les enfants (ou les petits-enfants, etc.) de l’occurrence de DisplayObjectContainer.	DisplayObjectContainer
		getRect(targetCoordinateSpace:DisplayObject):Rectangle Renvoie un rectangle qui définit les limites de l’objet d’affichage, en se basant sur le système de coordonnées défini par le paramètre targetCoordinateSpace, moins tout trait appliqué aux formes.	DisplayObject
		getStyle(style:String):Object Extrait une propriété de style définie dans la chaîne de recherche de style du composant.	UIComponent
		getStyleDefinition():Object [static] Récupère la texture de style par défaut du composant actif.	LabelButton
		globalToLocal(point:Point):Point Convertit l'objet point des coordonnées de scène (globales) vers les coordonnées de l’objet d’affichage (locales).	DisplayObject
		hasEventListener(type:String):Boolean Vérifie si des écouteurs sont enregistrés auprès de l'objet EventDispatcher pour un type spécifique d’événement.	EventDispatcher
		hasOwnProperty(name:String):Boolean Indique si la propriété spécifiée d'un objet est définie.	Object
		hitTestObject(obj:DisplayObject):Boolean Evalue l’objet d’affichage pour savoir s'il recouvre ou recoupe l’objet d'affichage obj.	DisplayObject
		hitTestPoint(x:Number, y:Number, shapeFlag:Boolean = false):Boolean Evalue l’objet d’affichage pour savoir s'il recouvre ou recoupe le point spécifié par les paramètres x et y.	DisplayObject
		invalidate(property:String, callLater:Boolean = true):void Marque une propriété comme non valide, puis redessine le composant dans la prochaine image, sauf spécification contraire.	UIComponent
		isPrototypeOf(theClass:Object):Boolean Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l'objet spécifié en tant que paramètre.	Object
		localToGlobal(point:Point):Point Convertit l'objet point des coordonnées de l’objet d’affichage (locales) vers les coordonnées de la scène (globales).	DisplayObject
		mergeStyles(... list):Object [static] Fusionne les styles de plusieurs classes en un seul objet.	UIComponent
		move(x:Number, y:Number):void Déplace le composant à la position spécifiée dans son parent.	UIComponent
		propertyIsEnumerable(name:String):Boolean Indique si la propriété spécifiée existe et est énumérable.	Object
		removeChild(child:DisplayObject):DisplayObject Supprime l’occurrence enfant de DisplayObject spécifiée de la liste d’enfants de l’occurrence de DisplayObjectContainer.	DisplayObjectContainer
		removeChildAt(index:int):DisplayObject Supprime une occurrence enfant de DisplayObject de la position d’index spécifiée dans la liste d’enfants de DisplayObjectContainer.	DisplayObjectContainer
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Supprime un écouteur de l’objet EventDispatcher.	EventDispatcher
		setChildIndex(child:DisplayObject, index:int):void Modifie la position d’un enfant existant dans le conteneur d’objet d'affichage.	DisplayObjectContainer
		setFocus():void Définit le focus sur ce composant.	UIComponent
		setMouseState(state:String):void Définit l'état de la souris par du code ActionScript.	BaseButton
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Définit la disponibilité d'une propriété dynamique pour les opérations en boucle.	Object
		setSize(width:Number, height:Number):void Définit le composant en fonction de la largeur et de la hauteur spécifiées.	UIComponent
		setStyle(style:String, value:Object):void Définit une propriété de style pour cette occurrence de composant.	UIComponent
		startDrag(lockCenter:Boolean = false, bounds:Rectangle = null):void Permet à l'utilisateur de faire glisser le sprite spécifié.	Sprite
		stopDrag():void Met fin à la méthode startDrag().	Sprite
		swapChildren(child1:DisplayObject, child2:DisplayObject):void Intervertit l'ordre z (ordre d’empilement du premier plan vers l’arrière-plan) des deux objets enfants spécifiés.	DisplayObjectContainer
		swapChildrenAt(index1:int, index2:int):void Intervertit l'ordre z (ordre d’empilement du premier plan vers l’arrière-plan) des objets enfants aux deux positions d’index spécifiées dans la liste d’enfants.	DisplayObjectContainer
		toString():String Renvoie la représentation sous forme de chaîne de l'objet spécifié.	Object
		validateNow():void Valide et met à jour les propriétés et la mise en forme de cet objet, puis le redessine si nécessaire.	UIComponent
		valueOf():Object Renvoie la valeur primitive de l'objet spécifié.	Object
		willTrigger(type:String):Boolean Vérifie si un écouteur d’événement est enregistré auprès de cet objet EventDispatcher ou de ses ancêtres pour le type d’événement spécifié.	EventDispatcher

Synthèse	Défini par
activate	Distribué lorsque Flash Player a le focus du système d’exploitation et devient actif.	EventDispatcher
added	Distribué lorsqu’un objet d’affichage est ajouté à la liste d’affichage.	DisplayObject
addedToStage	Envoyé lorsqu'un objet d'affichage est ajouté dans la liste d'affichage de la scène, directement ou par l'intermédiaire d'une arborescence secondaire qui contient l'objet d'affichage.	DisplayObject
buttonDown	Distribué lorsque l’utilisateur clique sur le composant Button.	BaseButton
change	Distribué lorsque la valeur de la propriété selected change pour un composant Button à basculement.	BaseButton
click	Diffusé après la réception d'une entrée de la souris ou de la barre d'espace par le bouton bascule.	LabelButton
deactivate	Distribué lorsque Flash Player perd le focus du système d’exploitation et devient inactif.	EventDispatcher
doubleClick	Distribué lorsque l'utilisateur appuie sur le bouton principal d'un périphérique de pointage et le relâche deux fois de suite sur la même occurrence d'InteractiveObject si l'indicateur doubleClickEnabled de cet objet est réglé sur true.	InteractiveObject
enterFrame	Distribué lorsque la tête de lecture est placée sur une nouvelle image.	DisplayObject
focusIn	Distribué après la prise de focus par un objet d'affichage.	InteractiveObject
focusOut	Distribué après la perte de focus par un objet d'affichage.	InteractiveObject
hide	Distribué après que la visibilité du composant soit passée de visible à invisible.	UIComponent
keyDown	Distribué lorsque l’utilisateur appuie sur une touche.	InteractiveObject
keyFocusChange	Distribué lorsque l’utilisateur tente de déplacer le focus à l’aide du clavier.	InteractiveObject
keyUp	Distribué lorsque l’utilisateur relâche une touche.	InteractiveObject
labelChange	Distribué lorsque la valeur de l'étiquette change.	LabelButton
mouseDown	Distribué lorsque l’utilisateur appuie à l’aide du bouton du périphérique de pointage sur une occurrence de InteractiveObject dans la fenêtre Flash Player.	InteractiveObject
mouseFocusChange	Distribué lorsque l’utilisateur tente de déplacer le focus à l’aide d’un périphérique de pointage.	InteractiveObject
mouseMove	Distribué lorsque l’utilisateur déplace le périphérique de pointage placé sur une occurrence de InteractiveObject.	InteractiveObject
mouseOut	Distribué lorsque l’utilisateur éloigne un périphérique de pointage d’une occurrence de InteractiveObject.	InteractiveObject
mouseOver	Distribué lorsque l’utilisateur déplace un périphérique de pointage sur une occurrence de InteractiveObject dans la fenêtre Flash Player.	InteractiveObject
mouseUp	Distribué lorsque l’utilisateur relâche le bouton du périphérique de pointage sur une occurrence de InteractiveObject dans la fenêtre Flash Player.	InteractiveObject
mouseWheel	Distribué lorsque l’utilisateur fait tourner la molette de la souris sur une occurrence de InteractiveObject dans la fenêtre Flash Player.	InteractiveObject
move	Distribué à la suite du déplacement du composant.	UIComponent
removed	Distribué lorsqu’un objet d’affichage est sur le point d’être supprimé de la liste d’affichage.	DisplayObject
removedFromStage	Envoyé lorsqu'un objet d'affichage est sur le point d'être supprimé de la liste d'affichage de la scène, directement ou par l'intermédiaire de la suppression d'une arborescence secondaire qui contient l'objet d'affichage.	DisplayObject
render	Distribué lorsque la liste d’affichage est sur le point d’être mise à jour et rendue.	DisplayObject
resize	Distribué à la suite du redimensionnement du composant.	UIComponent
rollOut	Distribué lorsque l’utilisateur éloigne un périphérique de pointage d’une occurrence de InteractiveObject.	InteractiveObject
rollOver	Distribué lorsque l’utilisateur place un périphérique de pointage sur une occurrence de InteractiveObject.	InteractiveObject
show	Distribué après que la visibilité du composant soit passée de invisible à visible.	UIComponent
tabChildrenChange	Distribué lorsque la valeur de l’indicateur tabChildren de l’objet change.	InteractiveObject
tabEnabledChange	Distribué lorsque l’indicateur tabEnabled de l’objet change.	InteractiveObject
tabIndexChange	Distribué lorsque la valeur de la propriété tabIndex de l’objet change.	InteractiveObject

Styles

Masquer les styles hérités

Afficher les styles hérités

	Description	Défini par
disabledIcon	Type: Class Nom de la classe à utiliser comme icône lorsque le bouton n'est pas désactivé. La valeur par défaut est `null`.	LabelButton
disabledSkin	Type: Class Nom de la classe à utiliser comme enveloppe pour l'arrière-plan et la bordure lorsque le bouton n'est pas sélectionné et est désactivé. La valeur par défaut est `Button_disabledSkin`.	LabelButton
disabledTextFormat	Type: flash.text.TextFormat Objet TextFormat à utiliser pour le rendu de l'étiquette du composant lorsque le bouton est désactivé.	UIComponent
downIcon	Type: Class Nom de la classe à utiliser comme icône lorsque le bouton n'est pas sélectionné et que le bouton de la souris est enfoncé. La valeur par défaut est `null`.	LabelButton
downSkin	Type: Class Nom de la classe à utiliser comme enveloppe pour l'arrière-plan et la bordure lorsque le bouton n'est pas sélectionné et que le bouton de la souris est enfoncé. La valeur par défaut est `Button_downSkin`.	LabelButton
embedFonts	Type: Boolean Indique si des polices vectorielles incorporées sont utilisées pour le rendu du champ de texte. Si cette valeur est `true`, Flash Player procède au rendu du champ de texte à l'aide des polices vectorielles intégrées. Si cette valeur est `false`, Flash Player procède au rendu du champ de texte à l'aide des polices de périphérique. Si vous définissez la propriété `embedFonts` sur `true` pour un champ de texte, vous devez spécifier la police du texte par l'intermédiaire de la propriété `font` d'un objet TextFormat appliqué au champ de texte. Si la police spécifiée n'est pas intégrée dans le fichier SWF, le texte ne s'affiche pas. La valeur par défaut est `false`.	LabelButton
focusRectPadding	Type: Number Format: Length Remplissage qui sépare les limites extérieures du composant et les bords extérieurs de l'indicateur du focus, en pixels.	UIComponent
focusRectSkin	Type: Class Enveloppe à utiliser pour afficher les indicateurs de focus.	UIComponent
icon	Type: Class Nom de la classe à utiliser comme icône lorsqu'un bouton de basculement n'est pas sélectionné et que la souris ne le survole pas. La valeur par défaut est `null`.	LabelButton
overIcon	Type: Class Nom de la classe à utiliser comme icône lorsque le bouton n'est pas sélectionné et que la souris survole le composant. La valeur par défaut est `null`.	LabelButton
overSkin	Type: Class Nom de la classe à utiliser comme enveloppe pour l'arrière-plan et la bordure lorsque le bouton n'est pas sélectionné et que la souris survole le composant. La valeur par défaut est `Button_overSkin`.	LabelButton
repeatDelay	Type: Number Format: Time Nombre de millisecondes d'attente après la première diffusion de l'événement `buttonDown` et avant l'envoi d'un second événement `buttonDown`. La valeur par défaut est `500`.	LabelButton
repeatInterval	Type: Number Format: Time Intervalle, en millisecondes, entre les événements `buttonDown` distribués après le délai spécifié par le style `repeatDelay`. La valeur par défaut est `35`.	LabelButton
selectedDisabledIcon	Type: Class Nom de la classe à utiliser comme icône lorsque le bouton est sélectionné et désactivé. La valeur par défaut est `null`.	LabelButton
selectedDisabledSkin	Type: Class Nom de la classe à utiliser comme enveloppe pour l'arrière-plan et la bordure lorsqu'un bouton bascule est sélectionné et désactivé. La valeur par défaut est `Button_selectedDisabledSkin`.	LabelButton
selectedDownIcon	Type: Class Nom de la classe à utiliser comme icône lorsque le bouton est sélectionné et que le bouton de la souris est enfoncé. La valeur par défaut est `null`.	LabelButton
selectedDownSkin	Type: Class Nom de la classe à utiliser comme enveloppe pour l'arrière-plan et la bordure lorsqu'un bouton bascule est sélectionné et que le bouton de la souris est enfoncé. La valeur par défaut est `Button_selectedDownSkin`.	LabelButton
selectedOverIcon	Type: Class Nom de la classe à utiliser comme icône lorsque le bouton est sélectionné et que la souris survole le composant. La valeur par défaut est `null`.	LabelButton
selectedOverSkin	Type: Class Nom de la classe à utiliser comme enveloppe pour l'arrière-plan et la bordure lorsqu'un bouton bascule est sélectionné et que la souris survole le composant. La valeur par défaut est `Button_selectedOverSkin`.	LabelButton
selectedUpIcon	Type: Class Nom de la classe à utiliser comme icône lorsque le bouton est sélectionné et que le bouton de la souris est relevé. La valeur par défaut est `null`.	LabelButton
selectedUpSkin	Type: Class Nom de la classe à utiliser comme enveloppe pour l'arrière-plan et la bordure lorsqu'un bouton bascule est sélectionné et que la souris ne survole pas le composant. La valeur par défaut est `Button_selectedUpSkin`.	LabelButton
textFormat	Type: flash.text.TextFormat Objet TextFormat à utiliser pour le rendu de l'étiquette du composant.	UIComponent
textPadding	Type: Number Format: Length Espacement entre le texte et les bords du composant, et espacement entre le texte et l'icône, en pixels. La valeur par défaut est `5`.	LabelButton
upIcon	Type: Class Nom de la classe à utiliser comme icône lorsqu'un bouton de basculement n'est pas sélectionné et que la souris ne le survole pas. La valeur par défaut est `null`.	LabelButton
upSkin	Type: Class Nom de la classe à utiliser comme enveloppe pour l'arrière-plan et la bordure lorsque le bouton n'est pas sélectionné et que la souris ne survole pas le composant. La valeur par défaut est `Button_upSkin`.	LabelButton

Détails des propriétés

label

propriété

label:String [lecture-écriture]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9.0.28.0

Récupère ou définit l'étiquette de texte du composant. Par défaut, le texte de l'étiquette apparaît centré sur le bouton.

Remarque : la définition de cette propriété déclenche la distribution de l'objet événement labelChange.

La valeur par défaut est "Label".

Implémentation
public function get label():String
public function set label(value:String):void

Voir aussi

labelChange

labelPlacement

propriété

labelPlacement:String [lecture-écriture]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9.0.28.0

Position de l'étiquette par rapport à une icône spécifique.

Dans ActionScript, vous pouvez utiliser les constantes suivantes pour définir cette propriété :

ButtonLabelPlacement.RIGHT
ButtonLabelPlacement.LEFT
ButtonLabelPlacement.BOTTOM
ButtonLabelPlacement.TOP

La valeur par défaut est ButtonLabelPlacement.RIGHT.

Implémentation
public function get labelPlacement():String
public function set labelPlacement(value:String):void

Voir aussi

ButtonLabelPlacement

Exemple

L'exemple suivant créé une occurrence du composant Button et définit sa propriété labelPlacement sur ButtonLabelPlacement.BOTTOM :


import fl.controls.Button;
import fl.controls.ButtonLabelPlacement;

var myButton:Button = new Button();
myButton.label = "ButtonLabelPlacement.BOTTOM";
myButton.labelPlacement = ButtonLabelPlacement.BOTTOM;
myButton.setStyle("icon", myLibraryAsset);
myButton.setSize(200, 100);
myButton.move(10, 10);
addChild(myButton);

selected

propriété

selected:Boolean [lecture-écriture]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9.0.28.0

Lit ou définit une valeur booléenne qui indique si un bouton de basculement est en position activée ou désactivée. La valeur true indique qu'il est activé et false le contraire. Cette propriété ne peut être définie que si la propriété toggle est définie sur true.

Dans le cas d'un composant CheckBox, cette valeur indique si une coche apparaît dans la case. Dans le cas d'un composant RadioButton, cette valeur indique si le composant est sélectionné.

L'utilisateur peut modifier cette propriété en cliquant sur le composant, mais vous pouvez également la définir par programmation.

Si la propriété toggle est définie sur true, la modification de cette valeur déclenche également un événement change.

La valeur par défaut est false.

Implémentation
public function get selected():Boolean
public function set selected(value:Boolean):void

Exemple

L'exemple suivant montre comment créer un bouton bascule à l'aide de la propriété toggle et en écoutant l'événement change pour déterminer le moment où un bouton est sélectionné :


import fl.controls.Button;

var myButton:Button = new Button();
myButton.toggle = true;
myButton.move(10, 10);
myButton.addEventListener(Event.CHANGE, changeHandler);
addChild(myButton);

function changeHandler(event:Event):void {
    trace("Button toggled (selected:" + event.currentTarget.selected + ")");
}

textField

propriété

public var textField:TextField

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9.0.28.0

Une référence au champ de texte interne du composant.

toggle

propriété

toggle:Boolean [lecture-écriture]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9.0.28.0

Lit ou définit une valeur booléenne qui indique si un bouton peut être activé ou désactivé. La valeur true indique que c'est possible, tandis que false indique le contraire.

Si cette valeur est true, un clic sur le bouton l'active ou le désactive. Vous pouvez obtenir ou définir cet état par programmation en utilisant la propriété selected.

Si cette valeur est false, le bouton ne demeure pas en état appuyé lorsque l'utilisateur le relâche. Dans ce cas, sa propriété selected a toujours la valeur false.

Remarque : lorsque toggle est défini sur false, selected devient false, dans la mesure où seul un bouton de ce type peut être sélectionné.

La valeur par défaut est false.

Implémentation
public function get toggle():Boolean
public function set toggle(value:Boolean):void

Exemple

L'exemple suivant créé une occurrence du composant Button bascule en définissant sa propriété toggle sur true et en écoutant la distribution de son événement change :


import fl.controls.Button;

var myButton:Button = new Button();
myButton.toggle = true;
myButton.selected = true;
myButton.label = "selected:" + myButton.selected;
myButton.width = 120;
myButton.move(10, 10);
myButton.addEventListener(Event.CHANGE, changeHandler);
addChild(myButton);

function changeHandler(event:Event):void {
    var myBtn:Button = event.currentTarget as Button;
    myBtn.label = "selected:" + myBtn.selected;
}

Détails du constructeur

LabelButton

()

Constructeur

public function LabelButton()

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9.0.28.0

Crée une nouvelle occurrence du composant LabelButton.

Détails des méthodes

getStyleDefinition

()

méthode

public static function getStyleDefinition():Object

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9.0.28.0

Récupère la texture de style par défaut du composant actif. La texture de style contient le type adapté au composant, qui dépend du style utilisé par ce dernier. Par exemple, le style disabledTextFormat contient la valeur null ou un objet TextFormat. Vous pouvez utiliser ces styles et appeler setStyle() pour le composant actif. Le code suivant ignore le style par défaut disabledTextFormat dans le composant spécifié :

componentInstance.setStyle("disabledTextFormat", new TextFormat());

Valeur renvoyée

Object — Objet de styles par défaut.

Voir aussi

fl.core.UIComponent.getStyle()
fl.core.UIComponent.setStyle()
fl.managers.StyleManager

Exemple

L'exemple suivant crée un navigateur de styles pour différentes classes de composant :

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

Détails des événements

click

Evénement

Type d'objet événement: flash.events.MouseEvent
MouseEvent.type property = flash.events.MouseEvent.CLICK

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9.0.28.0

Diffusé après la réception d'une entrée de la souris ou de la barre d'espace par le bouton bascule.

Définit la valeur de la propriété type d'un objet événement click.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`true`
`buttonDown`	`true` si le bouton principal de la souris est enfoncé ; `false` dans tous les autres cas.
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`ctrlKey`	`true` si la touche Ctrl est activée ; `false` si elle ne l'est pas.
`currentTarget`	L’objet qui traite activement l’objet Event avec un écouteur d’événements.
`localX`	Coordonnée horizontale à laquelle l’événement s’est produit par rapport au sprite conteneur.
`localY`	Coordonnée verticale à laquelle l’événement s’est produit par rapport au sprite conteneur.
`shiftKey`	`true` si la touche Maj est activée ; `false` si elle ne l'est pas.
`stageX`	Coordonnée horizontale à laquelle l’événement s’est produit, par rapport aux coordonnées globales de la scène.
`stageY`	Coordonnée verticale à laquelle l’événement s’est produit, par rapport aux coordonnées globales de la scène.
`target`	Occurrence d'InteractiveObject sous le périphérique de pointage. La propriété `target` ne correspond pas toujours à l’objet de la liste d’affichage qui est associé à l’écouteur d'événements. Utilisez la propriété `currentTarget` pour accéder à l’objet de la liste d'affichage qui traite actuellement l'événement.

Exemple

L'exemple suivant créé une occurrence du composant Button et écoute la distribution de l'événement click :


import fl.controls.Button;

var myButton:Button = new Button();
myButton.label = "Click me";
myButton.addEventListener(MouseEvent.CLICK, clickHandler);
myButton.move(10, 10);
addChild(myButton);

function clickHandler(event:MouseEvent):void {
    trace("clicked (localX:" + event.localX + ", localY:" + event.localY + ")");
}

labelChange

Evénement

Type d'objet événement: fl.events.ComponentEvent
ComponentEvent.type property = fl.events.ComponentEvent.LABEL_CHANGE

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9.0.28.0

Distribué lorsque la valeur de l'étiquette change.

Définit la valeur de la propriété type d'un objet événement labelChange.

Les propriétés de cet événement sont les suivantes :

Propriété	Valeur
`bubbles`	`false`
`cancelable`	`false` ; il n’existe aucun comportement par défaut à annuler.
`currentTarget`	Objet qui traite activement l’objet de l'événement avec un écouteur d’événement.
`target`	Objet qui a diffusé l’événement. La cible n'est pas toujours l'objet écoutant l'événement. Pour accéder à l'objet qui écoute l'événement, utilisez la propriété `currentTarget`.

Exemple

L'exemple suivant créé une occurrence du composant Button et écoute la distribution de l'événement labelChange à chaque changement de la propriété label du bouton :


import fl.controls.Button;
import fl.events.ComponentEvent;

var myButton:Button = new Button();
myButton.addEventListener(ComponentEvent.LABEL_CHANGE, labelChangeHandler);
myButton.label = "Click me";
myButton.move(10, 10);
addChild(myButton);

function labelChangeHandler(event:ComponentEvent):void {
    trace("labelChange: " + event.currentTarget.label);
}

Exemples Utilisation des exemples

LabelButtonExample.as

Cet exemple étend les fonctionnalités de la classe LabelButton pour créer une icône affichant une info-bulle lorsque la souris la survole.

Pour exécuter l'exemple, procédez comme suit :

Ajoutez les composants List et Button dans la bibliothèque.
Créez un symbole d'icône et nommez-le MyIcon.
Dans les propriétés de symbole de MyIcon, activez l'option « Exporter pour ActionScript ».
Enregistrez ce code sous le nom LabelButtonExample.as, dans le même répertoire que votre fichier FLA.
Définissez la classe Document dans le fichier FLA sur LabelButtonExample.

package
{ 
    import flash.display.Sprite;
    import flash.events.Event;
    import fl.data.DataProvider;
    import fl.controls.List;
    import fl.controls.ComboBox;
    import fl.core.UIComponent;
    import fl.events.ListEvent;
    
    public class LabelButtonExample extends Sprite
    {
        public function LabelButtonExample() {
            var myIcon:IconWithToolTip = new IconWithToolTip();
            myIcon.setStyle("icon", MyIcon);
            myIcon.iconDescription = "Icon Description";
            myIcon.move(50,50);
            addChild(myIcon);
        }
    }
}

IconWithToolTip.as

Enregistrez ce code dans le fichier IconWithToolTip.as, dans le même répertoire que votre fichier FLA :

package {
    import fl.controls.LabelButton;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;
    
    public class IconWithToolTip extends LabelButton
    {
        public var iconDescription:String = "";
        private var toolTip:TextField;
        private var format:TextFormat;
        
        public function IconWithToolTip() {
            addEventListener(MouseEvent.MOUSE_OVER,showToolTip);
            addEventListener(MouseEvent.MOUSE_OUT,hideToolTip);
            format = new TextFormat();
            format.font = "Verdana";
            format.size = 10;
            format.bold = true;
            createToolTip();
        }

        private function createToolTip():void {
            toolTip = new TextField();
            toolTip.background = true;
            toolTip.backgroundColor = 0xFFCC66;
            toolTip.border = true;
            toolTip.borderColor = 0x000000;
            toolTip.multiline = false;
            toolTip.autoSize = TextFieldAutoSize.CENTER;
            toolTip.visible = false;
            addChild(toolTip);            
        }

        private function showToolTip(e:MouseEvent):void {
            toolTip.text = iconDescription;
            toolTip.x = 20;
            toolTip.y = 0;
            toolTip.visible = true;
            toolTip.setTextFormat(format);
        }

        private function hideToolTip(e:MouseEvent):void {
            toolTip.visible = false;    
        }
    }
}

Page en cours: http://livedocs.adobe.com/flash/9.0_fr/ActionScriptLangRefV3/fl/controls/LabelButton.html

Guide de référence du langage et des composants ActionScript 3.0		Tous les packages \| Toutes les classes \| Eléments du langage \| Index \| Annexes \| Conventions \| Cadres Aucune image
LabelButton	Propriétés \| Méthodes \| Evénements \| Styles \| Exemples

Package	fl.controls
Classe	public class LabelButton
Héritage	LabelButton BaseButton UIComponent Sprite DisplayObjectContainer InteractiveObject DisplayObject EventDispatcher Object
Implémente	IFocusManagerComponent
Sous-classes	Button, CellRenderer, CheckBox, HeaderRenderer, RadioButton