XML (ActionScript 3.0)

	Propriété	Défini par
		constructor : Object Référence à l'objet de classe ou à la fonction constructeur d'une occurrence donnée d'un objet.	Object
		ignoreComments : Boolean [static] Détermine si les commentaires XML sont ignorés lorsque les objets XML analysent les données XML source.	XML
		ignoreProcessingInstructions : Boolean [static] Détermine si les instructions de traitement XML sont ignorées lorsque les objets XML analysent les données XML source.	XML
		ignoreWhitespace : Boolean [static] Détermine si les caractères d’espace blanc placés au début et à la fin des nœuds de texte sont ignorés lors de l’analyse.	XML
		prettyIndent : int [static] Détermine la taille du retrait appliqué par les méthodes toString() et toXMLString() si la propriété XML.prettyPrinting est définie sur true.	XML
		prettyPrinting : Boolean [static] Détermine si les méthodes toString() et toXMLString() normalisent les caractères d’espace blanc entre certaines balises.	XML
		prototype : Object [static] Référence à l’objet prototype d’un objet de classe ou fonction.	Object

	Méthode	Défini par
		XML(value:Object) Crée un objet XML.	XML
		addNamespace(ns:Object):XML Ajoute un espace de nom à l’ensemble d’espaces de nom du domaine associé à l’objet XML.	XML
		appendChild(child:Object):XML Ajoute l’enfant indiqué à la fin des propriétés de l’objet XML.	XML
		attribute(attributeName:*):XMLList Renvoie la valeur XML de l’attribut dont le nom correspond au paramètre attributeName.	XML
		attributes():XMLList Renvoie une liste de valeurs d’attribut associée à l'objet XML indiqué.	XML
		child(propertyName:Object):XMLList Recense les enfants d’un objet XML.	XML
		childIndex():int Identifie la position d’index qui commence à zéro de cet objet XML dans le contexte de l’objet parent.	XML
		children():XMLList Recense les enfants de l’objet XML dans l’ordre dans lequel ils apparaissent.	XML
		comments():XMLList Recense les propriétés de l’objet XML qui contient des commentaires XML.	XML
		contains(value:XML):Boolean Compare l’objet XML au paramètre value spécifié.	XML
		copy():XML Renvoie une copie de l’objet XML spécifié.	XML
		defaultSettings():Object [static] Renvoie un objet avec les propriétés suivantes définies sur les valeurs par défaut : ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent et prettyPrinting.	XML
		descendants(name:Object = *):XMLList Renvoie tous les descendants (enfants, petits-enfants, arrière-petits-enfants, etc.) de l’objet XML associés au paramètre name indiqué.	XML
		elements(name:Object = *):XMLList Recense les éléments d’un objet XML.	XML
		hasComplexContent():Boolean Vérifie si l’objet XML intègre un contenu complexe.	XML
		hasOwnProperty(p:String):Boolean Vérifie si l’objet possède la propriété spécifiée par le paramètre p.	XML
		hasSimpleContent():Boolean Vérifie si l’objet XML intègre un contenu simple.	XML
		inScopeNamespaces():Array Recense les espaces de nom associés à l'objet XML, par rapport au parent de l’objet.	XML
		insertChildAfter(child1:Object, child2:Object):* Insère le paramètre child2 indiqué après le paramètre child1 dans cet objet XML et renvoie l’objet produit.	XML
		insertChildBefore(child1:Object, child2:Object):* Insère le paramètre child2 indiqué avant le paramètre child1 dans cet objet XML et renvoie l’objet produit.	XML
		isPrototypeOf(theClass:Object):Boolean Indique si une occurrence de la classe Object figure dans la chaîne de prototype de l'objet spécifié en tant que paramètre.	Object
		length():int Pour les objets XML, cette méthode renvoie toujours l’entier 1.	XML
		localName():Object Indique la partie nom local du nom complet de l’objet XML.	XML
		name():Object Indique le nom complet de l’objet XML.	XML
		namespace(prefix:String = null):* Si vous ne fournissez pas de paramètre, indique l’espace de nom associé au nom complet de cet objet XML.	XML
		namespaceDeclarations():Array Recense les déclarations d’espace de nom associées à l’objet XML dans le contexte de l’objet parent.	XML
		nodeKind():String Définit le type de nœud : texte, commentaire, instruction de traitement, attribut ou élément.	XML
		normalize():XML Pour l’objet XML et tous les objets XML descendants, fusionne les nœuds de texte adjacents et supprime les nœuds de texte vides.	XML
		parent():* Renvoie le parent de l’objet XML.	XML
		prependChild(value:Object):XML Insère une copie de l’objet child fourni dans l’élément XML avant toute propriété XML associée à cet élément.	XML
		processingInstructions(name:String = "*"):XMLList Si un paramètre name est spécifié, la méthode recense tous les enfants de l’objet XML qui contiennent des instructions de traitement portant le nom indiqué.	XML
		propertyIsEnumerable(p:String):Boolean Vérifie si la propriété p figurre dans le jeu de propriétés qui peut faire l'objet d'une itération avec une instruction for..in appliquée à l'objet XML.	XML
		removeNamespace(ns:Namespace):XML Supprime l’espace de nom indiqué pour cet objet et tous ses descendants.	XML
		replace(propertyName:Object, value:XML):XML Remplace les propriétés spécifiées par le paramètre propertyName par le paramètre value indiqué.	XML
		setChildren(value:Object):XML Remplace les propriétés enfant de l'objet XML par l'ensemble de propriétés XML spécifié, fourni dans le paramètre value.	XML
		setLocalName(name:String):void Remplace le nom local de l’objet XML par le paramètre name indiqué.	XML
		setName(name:String):void Règle le nom de l’objet XML sur le nom complet ou le nom d’attribut indiqué.	XML
		setNamespace(ns:Namespace):void Définit l’espace de nom associé à l’objet XML.	XML
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Définit la disponibilité d'une propriété dynamique pour les opérations en boucle.	Object
		setSettings(... rest):void [static] Définit les valeurs des propriétés XML suivantes : ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent et prettyPrinting.	XML
		settings():Object [static] Extrait les propriétés suivantes : ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent et prettyPrinting.	XML
		text():XMLList Renvoie un objet XMLList contenant toutes les propriétés XML de l’objet XML qui représente les nœuds de texte XML.	XML
		toString():String Renvoie l’objet XML sous forme de chaîne.	XML
		toXMLString():String Renvoie l’objet XML sous forme de chaîne.	XML
		valueOf():XML Renvoie l’objet XML.	XML

Détails des propriétés

ignoreComments

propriété

ignoreComments:Boolean [lecture-écriture]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Détermine si les commentaires XML sont ignorés lorsque les objets XML analysent les données XML source. Par défaut, les commentaires sont ignorés (true). Pour inclure les commentaires XML, réglez cette propriété sur false. La propriété ignoreComments n’est utilisée que lors de l’analyse XML et non pendant l'appel d'une méthode, telle que myXMLObject.child(*).toXMLString(). Si les données XML source contiennent des nœuds de commentaire, ils sont conservés ou éliminés lors de l'analyse XML.

Implémentation
public static function get ignoreComments():Boolean
public function set ignoreComments(value:Boolean):void

Voir aussi

XML.child()
XML.toXMLString()

Exemple

Cet exemple illustre l'effet de la définition de XML.ignoreComments sur false et sur true :

XML.ignoreComments = false;
var xml1:XML = 
        <foo>
            <!-- comment -->
        </foo>;
trace(xml1.toXMLString()); // <foo><!-- comment --></foo>

XML.ignoreComments = true;
var xml2:XML = 
        <foo>
            <!-- example -->
        </foo>;
trace(xml2.toXMLString()); // <foo/>

ignoreProcessingInstructions

propriété

ignoreProcessingInstructions:Boolean [lecture-écriture]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Détermine si les instructions de traitement XML sont ignorées lorsque les objets XML analysent les données XML source. Par défaut, les instructions de traitement sont ignorées (true). Pour les inclure, réglez la propriété sur false. La propriété ignoreProcessingInstructions n’est utilisée que lors de l’analyse XML et non pendant l'appel de toute méthode telle que myXMLObject.child(*).toXMLString(). Si les données XML source contiennent des nœuds d’instructions de traitement, ils sont conservés ou éliminés lors de l'analyse XML.

Implémentation
public static function get ignoreProcessingInstructions():Boolean
public function set ignoreProcessingInstructions(value:Boolean):void

Voir aussi

XML.child()
XML.toXMLString()

Exemple

Cet exemple illustre l'effet de la définition de XML.ignoreProcessingInstructions sur false et sur true :

XML.ignoreProcessingInstructions = false;
var xml1:XML = 
        <foo>
            <?exampleInstruction ?>
        </foo>;
trace(xml1.toXMLString()); // <foo><?exampleInstruction ?></foo>

XML.ignoreProcessingInstructions = true;
var xml2:XML = 
        <foo>
            <?exampleInstruction ?>
        </foo>;
trace(xml2.toXMLString()); // <foo/>

ignoreWhitespace

propriété

ignoreWhitespace:Boolean [lecture-écriture]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Détermine si les caractères d’espace blanc placés au début et à la fin des nœuds de texte sont ignorés lors de l’analyse. Les espaces blancs sont ignorés par défaut (true). Si un nœud de texte est entièrement composé d’espaces blancs et que la propriété ignoreWhitespace est définie sur true, il n'est pas créé. Pour afficher les espaces blancs dans un nœud de texte, réglez la propriété ignoreWhitespace sur false.

Implémentation
public static function get ignoreWhitespace():Boolean
public function set ignoreWhitespace(value:Boolean):void

Exemple

Cet exemple illustre l'effet de la définition de XML.ignoreWhitespace sur false et sur true :

XML.ignoreWhitespace = false;
var xml1:XML = <foo>    </foo>;
trace(xml1.children().length()); // 1

XML.ignoreWhitespace = true;
var xml2:XML = <foo>    </foo>;
trace(xml2.children().length()); // 0

prettyIndent

propriété

prettyIndent:int [lecture-écriture]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Détermine la taille du retrait appliqué par les méthodes toString() et toXMLString() si la propriété XML.prettyPrinting est définie sur true. Les retraits sont appliqués à l’aide de caractères d’espace et non de caractères de tabulation. La valeur par défaut est 2.

Implémentation
public static function get prettyIndent():int
public function set prettyIndent(value:int):void

Voir aussi

prettyPrinting
toString()
toXMLString()

Exemple

Cet exemple illustre l'effet de la définiton de la propriété statique XML.prettyIndent :

var xml:XML = <foo><bar/></foo>;
XML.prettyIndent = 0;
trace(xml.toXMLString());

XML.prettyIndent = 1;
trace(xml.toXMLString());

XML.prettyIndent = 2;
trace(xml.toXMLString());

prettyPrinting

propriété

prettyPrinting:Boolean [lecture-écriture]

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Détermine si les méthodes toString() et toXMLString() normalisent les caractères d’espace blanc entre certaines balises. La valeur par défaut est true.

Implémentation
public static function get prettyPrinting():Boolean
public function set prettyPrinting(value:Boolean):void

Voir aussi

prettyIndent
toString()
toXMLString()

Exemple

Cet exemple illustre l'effet de la définiton de la propriété statique XML.prettyPrinting :

var xml:XML = <foo><bar/></foo>;
XML.prettyPrinting = false;
trace(xml.toXMLString());

XML.prettyPrinting = true;
trace(xml.toXMLString());

Détails du constructeur

XML

()

Constructeur

public function XML(value:Object)

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Crée un objet XML. Vous devez utiliser le constructeur pour créer un objet XML avant d'appeler une des méthodes de la classe XML.

La méthode toXMLString() permet de renvoyer une représentation sous forme de chaîne de l’objet XML, que son contenu soit simple ou complexe.

Paramètres

value:Object — Tout objet qui peut être converti en objet XML à l’aide de la fonction de niveau supérieur XML().

Voir aussi

top-level XML(), fonction
XML.toXMLString()
Objets XML

Détails des méthodes

addNamespace

()

méthode

AS3 function addNamespace(ns:Object):XML

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Ajoute un espace de nom à l’ensemble d’espaces de nom du domaine associé à l’objet XML. Si l’espace de nom figure déjà dans l'ensemble d’espaces de noms du domaine associé à l’objet XML (avec un préfixe qui correspond au paramètre spécifié), le préfixe correspondant est réglé sur undefined. Si le paramètre d’entrée est un objet Namespace, il est utilisé directement. S’il correspond à un objet QName, l’URI du paramètre d’entrée est utilisé pour créer un espace de nom. Dans le cas contraire, il est converti en chaîne et un espace de nom est généré à partir de la chaîne.

Paramètres

ns:Object — Espace de nom à ajouter à l’objet XML.

Valeur renvoyée

XML — Nouvel objet XML, auquel est ajouté l'espace de nom.

Voir aussi

Objets XML

Exemple

Cet exemple utilise un espace de nom défini dans un objet XML et l'applique à un autre objet XML :

var xml1:XML = <ns:foo xmlns:ns="www.example.com/ns" />;
var nsNamespace:Namespace = xml1.namespace();

var xml2:XML = <bar />;
xml2.addNamespace(nsNamespace);
trace(xml2.toXMLString()); // <bar xmlns:ns="www.example.com/ns"/>

appendChild

()

méthode

AS3 function appendChild(child:Object):XML

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Ajoute l’enfant indiqué à la fin des propriétés de l’objet XML. La méthode appendChild() accepte un objet XML, un objet XMLList ou tout autre type de données qui est ensuite converti en chaîne.

Utilisez l’opérateur delete (XML) pour supprimer les nœuds XML.

Paramètres

child:Object — Objet XML à ajouter.

Valeur renvoyée

XML — Objet XML produit.

Voir aussi

delete, opérateur (XML)
L'approche E4X concernant le traitement XML
Objets XML
Assemblage et transformation d'objets XML

Exemple

Cet exemple ajoute un nouvel élément à la fin de la liste enfant d'un objet XML :

var xml:XML = 
        <body>
            <p>hello</p>
        </body>;
        
xml.appendChild(<p>world</p>);    
trace(xml.p[0].toXMLString()); // <p>hello</p>
trace(xml.p[1].toXMLString()); // <p>world</p>

attribute

()

méthode

AS3 function attribute(attributeName:*):XMLList

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Renvoie la valeur XML de l’attribut dont le nom correspond au paramètre attributeName. Les attributs sont intégrés aux éléments XML. Dans l'exemple suivant, l'élément a un attribut appelé "gender" avec la valeur "boy" : <first gender="boy">John</first>.

Le paramètre attributeName peut correspondre à n’importe quel type de données, mais String est généralement utilisé. Si vous transmettez un objet autre que QName, le paramètre attributeName utilise la méthode toString() pour convertir le paramètre en chaîne.

Si une référence de nom complet s’impose, vous pouvez transmettre un objet QName. Un objet QName définit un espace de nom et le nom local, que vous pouvez utiliser pour définir le nom complet d’un attribut. De ce fait, appeler attribute(qname) n’est pas équivalent à appeler attribute(qname.toString()).

Paramètres

attributeName:* — Nom de l’attribut.

Valeur renvoyée

XMLList — Objet XMLList ou objet XMLList vide. Renvoie un objet XMLList vide si vous n’avez pas défini la valeur d’un attribut.

Voir aussi

XML.attributes()
QName
Namespace
XML.elements()
identificateur d'attribut, opérateur (@)
Objets XML
Parcours de structures XML

Exemple

Cet exemple porte sur un objet QName transmis par la méthode attribute(). La propriété localName est attr et la propriété namespace est ns.

var xml:XML = <ns:node xmlns:ns = "http://uri" ns:attr = '7' />       
var qn:QName = new QName("http://uri", "attr");
trace(xml.attribute(qn)); // 7

Pour renvoyer un attribut avec un nom qui correspond à un mot ActionScript réservé, utilisez la méthode attribute() et non pas l'opérateur d'identificateur d'attribut (@), comme dans l'exemple suivant :

var xml:XML = <example class="first" />
trace(xml.attribute("class"));

attributes

()

méthode

AS3 function attributes():XMLList

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Renvoie une liste de valeurs d’attribut associée à l'objet XML indiqué. Utilisez la méthode name() en conjonction avec la méthode attributes() pour renvoyer le nom d’un attribut. Utilisez @* pour renvoyer le nom de tous les attributs.

Valeur renvoyée

XMLList — Liste de valeurs d’attributs.

Voir aussi

XML.attribute()
XML.name()
@, opérateur
Objets XML
Parcours de structures XML

Exemple

L'exemple suivant renvoie le nom de l'attribut :

var xml:XML=<example id='123' color='blue'/>
trace(xml.attributes()[1].name()); //color

Cet exemple renvoie les noms de tous les attributs :

 
var xml:XML = <example id='123' color='blue'/>
var attNamesList:XMLList = xml.@*;

trace(attNamesList is XMLList); // true
trace(attNamesList.length()); // 2

for (var i:int = 0; i < attNamesList.length(); i++)
{ 
    trace(typeof (attNamesList[i])); // xml
    trace(attNamesList[i].nodeKind()); // attribute
    trace(attNamesList[i].name()); // id and color
}

child

()

méthode

AS3 function child(propertyName:Object):XMLList

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Recense les enfants d’un objet XML. Un enfant XML est un élément, un nœud de texte, un commentaire ou une instruction de traitement XML.

Le paramètre propertyName permet de recenser le contenu d’un enfant XML spécifique. Par exemple, pour renvoyer le contenu d’un enfant appelé <first>, utilisez child.name("first"). Vous pouvez générer le même résultat à partir du numéro d'index de l'enfant. Le numéro d’index identifie la position de l’enfant dans la liste d’enfants XML. Par exemple, name.child(0) renvoie le premier enfant d'une liste.

Utilisez un astérisque (*) pour extraire tous les enfants dans un document XML. Exemple : doc.child("*").

La méthode length() associée au paramètre astérisque (*) de la méthode child() permet de produire le nombre total d’enfants. Exemple : numChildren = doc.child("*").length().

Paramètres

propertyName:Object — Nom de l’élément ou entier de l’objet XML enfant.

Valeur renvoyée

XMLList — Objet XMLList contenant les nœuds enfant qui correspondent au paramètre d’entrée.

Voir aussi

XML.elements()
XMLList, classe
XML.length()
Objets XML
Parcours de structures XML

Exemple

Cet exemple porte sur l'utilisation de la méthode child() pour identifier les éléments enfant avec le nom spécifié :

var xml:XML = 
        <foo>
            <bar>text1</bar>
            <bar>text2</bar>
        </foo>;
trace(xml.child("bar").length());  // 2
trace(xml.child("bar")[0].toXMLString()); // <bar>text1</bar>
trace(xml.child("bar")[1].toXMLString()); // <bar>text2</bar>

childIndex

()

méthode

AS3 function childIndex():int

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Identifie la position d’index qui commence à zéro de cet objet XML dans le contexte de l’objet parent.

Valeur renvoyée

int — Position de l’objet. Renvoie -1 et des entiers positifs.

Voir aussi

Objets XML

Exemple

Cet exemple indique comment utiliser la méthode childIndex() :

var xml:XML = 
            <foo>
                <bar />
                text
                <bob />
            </foo>;
trace(xml.bar.childIndex()); // 0
trace(xml.bob.childIndex()); // 2

children

()

méthode

AS3 function children():XMLList

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Recense les enfants de l’objet XML dans l’ordre dans lequel ils apparaissent. Un enfant XML est un élément, un nœud de texte, un commentaire ou une instruction de traitement XML.

Valeur renvoyée

XMLList — Objet XMLList contenant les enfants de l’objet XML.

Voir aussi

Objets XML

Exemple

Cet exemple indique comment utiliser la méthode children() :

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var xml:XML = 
        <foo id="22">
            <bar>44</bar>
            text
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml.children().length()); // 4
trace(xml.children()[0].toXMLString()); // <bar>44</bar>
trace(xml.children()[1].toXMLString()); // text
trace(xml.children()[2].toXMLString()); // <!-- comment -->
trace(xml.children()[3].toXMLString()); // <?instruction ?>

comments

()

méthode

AS3 function comments():XMLList

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Recense les propriétés de l’objet XML qui contient des commentaires XML.

Valeur renvoyée

XMLList — Objet XMLList des propriétés qui contiennent des commentaires.

Voir aussi

Objets XML

Exemple

Cet exemple indique comment utiliser la méthode comments() :

XML.ignoreComments = false;
var xml:XML = 
        <foo>
            <!-- example -->
            <!-- example2 -->
        </foo>;
trace(xml.comments().length()); // 2
trace(xml.comments()[1].toXMLString()); // <!-- example2 -->

contains

()

méthode

AS3 function contains(value:XML):Boolean

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Compare l’objet XML au paramètre value spécifié.

Paramètres

value:XML — Valeur à comparer à l’objet XML en cours.

Valeur renvoyée

Boolean — Renvoie true si l’objet XML correspond au paramètre value, false dans le cas contraire.

Voir aussi

Objets XML

Exemple

Cet exemple indique comment utiliser la méthode contains() :

var xml:XML = 
        <order>
            <item>Rice</item>
            <item>Kung Pao Shrimp</item>
        </order>;
trace(xml.item[0].contains(<item>Rice</item>)); // true
trace(xml.item[1].contains(<item>Kung Pao Shrimp</item>)); // true
trace(xml.item[1].contains(<item>MSG</item>)); // false

copy

()

méthode

AS3 function copy():XML

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Renvoie une copie de l’objet XML spécifié. Cette copie est une duplication de l’arborescence entière de nœuds. L’objet XML copié ne possède pas de parent et renvoie null si vous tentez d’appeler la méthode parent().

Valeur renvoyée

XML — Copie de l’objet.

Voir aussi

Objets XML

Exemple

Cet exemple indique que la méthode copy() crée une nouvelle occurrence d'un objet XML. Lorsque vous modifiez la copie, l'original reste inchangé :

var xml1:XML = <foo />;
var xml2:XML = xml1.copy();
xml2.appendChild(<bar />);
trace(xml1.bar.length()); // 0
trace(xml2.bar.length()); // 1

defaultSettings

()

méthode

AS3 static function defaultSettings():Object

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Renvoie un objet avec les propriétés suivantes définies sur les valeurs par défaut : ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent et prettyPrinting. Les valeurs par défaut sont les suivantes :

ignoreComments = true
ignoreProcessingInstructions = true
ignoreWhitespace = true
prettyIndent = 2
prettyPrinting = true

Remarque : cette méthode ne doit pas être appliquée à une occurrence de la classe XML, mais à XML, comme illustré dans le code suivant : var df:Object = XML.defaultSettings().

Valeur renvoyée

Object — Objet dont les propriétés sont réglées sur leur valeur par défaut.

Voir aussi

XML.ignoreComments
XML.ignoreProcessingInstructions
XML.ignoreWhitespace
XML.prettyIndent
XML.prettyPrinting
XML.setSettings()
XML.settings()
Objets XML

Exemple

L'exemple ci-dessous illustre les points suivants : comment appliquer des paramètres personnalisés (pour l'inclusion de commentaires et d'instructions de traitement) avant de définir un objet XML ; comment ensuite rétablir les paramètres par défaut avant de définir un autre objet XML ; et enfin comment définir de nouveau les paramètres par défaut (pour définir d'autres objets XML) :

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

descendants

()

méthode

AS3 function descendants(name:Object = *):XMLList

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Renvoie tous les descendants (enfants, petits-enfants, arrière-petits-enfants, etc.) de l’objet XML associés au paramètre name indiqué. Le paramètre name est facultatif. Le paramètre name peut être un objet QName, un type de données String ou tout autre type de données converti ensuite au type de données String.

Pour renvoyer tous les descendants, utilisez le paramètre « * ». Si aucun paramètre n’est transmis, la chaîne « * » est transmise et renvoie tous les descendants de l’objet XML.

Paramètres

name:Object (default = *) — Nom de l’élément pour lequel établir une correspondance.

Valeur renvoyée

XMLList — Objet XMLList contenant tous les descendants correspondants. S’il n’existe pas de descendants, la méthode renvoie un objet XMLList vide.

Voir aussi

accesseur de descendance (..) operator

Exemple

Pour renvoyer les descendants sous des noms qui correspondent aux mots réservés ActionScript, utilisez la méthode descendants() de préférence à l'opérateur de descendance (..), comme indiqué dans l'exemple suivant :

var xml:XML = 
  <enrollees>
    <student id="239">
        <class name="Algebra" />
        <class name="Spanish 2"/>
    </student>
    <student id="206">
        <class name="Trigonometry" />
        <class name="Spanish 2" />
    </student>
  </enrollees>
trace(xml.descendants("class"));

Cet exemple illustre le fait que la méthode descendants() renvoie un objet XMLList qui contient tous les objets descendants, ce qui inclut les enfants, les petits enfants, etc. :

XML.ignoreComments = false;
var xml:XML = 
        <body>
            <!-- comment -->
            text1
            <a>
                <b>text2</b>
            </a>
        </body>;
trace(xml.descendants("*").length()); // 5
trace(xml.descendants("*")[0]); // // <!-- comment -->
trace(xml.descendants("*")[1].toXMLString()); // text1
trace(xml.descendants("a").toXMLString()); // <a><b>text2</b></a>
trace(xml.descendants("b").toXMLString()); // <b>text2</b>

elements

()

méthode

AS3 function elements(name:Object = *):XMLList

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Recense les éléments d’un objet XML. Un élément se compose d’une balise de début et d’une balise de fin, telle que <first></first>. Le paramètre name est facultatif. Le paramètre name peut être un objet QName, un type de données String ou tout autre type de données converti ensuite au type de données String. Utilisez le paramètre name pour recenser un élément spécifique. Par exemple, l'élément first renvoie John dans cet exemple : <first>John</first>.

Pour recenser tous les éléments, utilisez le paramètre astérisque (*). L’astérisque est également le paramètre par défaut.

La méthode length() associée au paramètre astérisque permet d’extraire le nombre total d’éléments. Par exemple, numElement = addressbook.elements("*").length().

Paramètres

name:Object (default = *) — Nom de l’élément. Un nom d’élément est entouré de chevrons. Par exemple, "first" correspond à name dans cet exemple : <first></first>.

Valeur renvoyée

XMLList — Objet XMLList qui comporte le contenu de l’élément. Le contenu d’un élément est compris entre la balise de début et la balise de fin. Si vous utilisez l’astérisque (*) pour appeler tous les éléments, les balises et le contenu sont renvoyés.

Voir aussi

XML.child()
XMLList, classe
XML.length()
XML.attribute()
point XML (.) operator
Objets XML

Exemple

L'exemple suivant indique que la méthode elements() renvoie uniquement une liste d'éléments — sans commentaire, propriété de texte ou instruction de traitement :

var xml:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
            text
            <a>1</a>
            <b>2</b>
        </foo>;
trace(xml.elements("*").length()); // 2
trace(xml.elements("*")[0].toXMLString()); // <a>1</a>
trace(xml.elements("b").length()); // 1
trace(xml.elements("b")[0].toXMLString()); // <b>2</b>

Pour renvoyer les descendants sous des noms qui correspondent aux mots réservés ActionScript, utilisez la méthode elements() de préférence à l'opérateur point (.) du code XML, comme indiqué dans l'exemple suivant :

var xml:XML =
 <student id="206">
    <class name="Trigonometry" />
    <class name="Spanish 2" />
 </student>
trace(xml.elements("class"));

hasComplexContent

()

méthode

AS3 function hasComplexContent():Boolean

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Vérifie si l’objet XML intègre un contenu complexe. Le contenu d’un objet XML est complexe s’il possède des éléments enfant. Les objets XML qui représentent des attributs, des commentaires, des instructions de traitement et des nœuds de texte n’intègrent pas un contenu complexe. Le contenu d’un objet qui intègre ces entités peut néanmoins être considéré comme complexe si l’objet possède des éléments enfant.

Valeur renvoyée

Boolean — Renvoie true si l’objet XML intègre un contenu complexe, false dans le cas contraire.

Voir aussi

XML.hasSimpleContent()
Objets XML

Exemple

L'exemple suivant porte sur un objet XML, avec une propriété appelée a qui a un contenu simple et une autre propriété a qui a du contenu complexe :

var xml:XML = 
        <foo>
            <a>
                text
            </a>
            <a>
                <b/>
            </a>
        </foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true

trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false

hasOwnProperty

()

méthode

AS3 function hasOwnProperty(p:String):Boolean

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Vérifie si l’objet possède la propriété spécifiée par le paramètre p.

Paramètres

p:String — Propriété pour laquelle établir une correspondance.

Valeur renvoyée

Boolean — Renvoie true si la propriété existe, false dans le cas contraire.

Voir aussi

Objets XML

Exemple

L'exemple suivant utilise la méthode hasOwnProperty() pour s'assurer que la propriété (b) existe avant d'évaluer une expression (b == "11") qui utilise cette propriété :

var xml:XML = 
        <foo>
            <a />
            <a>
                <b>10</b>
            </a>
            <a>
                <b>11</b>
            </a>
        </foo>;
trace(xml.a.(hasOwnProperty("b") && b == "11"));

Si la dernière ligne de cet exemple était remplacée par ce qui suit, Flash Player renverrait une exception dans la mesure où le premier élément appelé a ne comporte pas de propriété b :

trace(xml.a.(b == "11"));

L'exemple suivant utilise la méthode hasOwnProperty() pour s'assurer que la propriété (item) existe avant d'évaluer une expression (item.contains("toothbrush")) qui utilise cette propriété :

var xml:XML = 
        <orders>
            <order id='1'>
                <item>toothbrush</item>
                <item>toothpaste</item>
            </order>
            <order>
                <returnItem>shoe polish</returnItem>
            </order>
        </orders>;
trace(xml.order.(hasOwnProperty("item") && item.contains("toothbrush")));

hasSimpleContent

()

méthode

AS3 function hasSimpleContent():Boolean

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Vérifie si l’objet XML intègre un contenu simple. Un objet XML intègre un contenu simple s’il représente un nœud de texte, un nœud d'attribut ou un élément XML sans élément enfant. Les objets XML qui représentent des commentaires et des instructions de traitement n’intègrent pas un contenu simple.

Valeur renvoyée

Boolean — Renvoie true si l’objet XML intègre un contenu simple, false dans le cas contraire.

Voir aussi

XML.hasComplexContent()
Objets XML

Exemple

L'exemple suivant porte sur un objet XML, avec une propriété appelée a qui a un contenu simple et une autre propriété a qui a du contenu complexe :

var xml:XML = 
        <foo>
            <a>
                text
            </a>
            <a>
                <b/>
            </a>
        </foo>;
trace(xml.a[0].hasComplexContent()); // false
trace(xml.a[1].hasComplexContent()); // true

trace(xml.a[0].hasSimpleContent()); // true
trace(xml.a[1].hasSimpleContent()); // false

inScopeNamespaces

()

méthode

AS3 function inScopeNamespaces():Array

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Recense les espaces de nom associés à l'objet XML, par rapport au parent de l’objet.

Valeur renvoyée

Array — Tableau d'objets Namespace.

Voir aussi

Objets XML

insertChildAfter

()

méthode

AS3 function insertChildAfter(child1:Object, child2:Object):*

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Insère le paramètre child2 indiqué après le paramètre child1 dans cet objet XML et renvoie l’objet produit. Si le paramètre child1 est réglé sur null, la méthode insère le contenu de child2 avant tous les enfants de l’objet XML (en d’autres termes, après none). Si child1 est fourni, mais qu’il n’existe pas dans l’objet XML, celui-ci n’est pas modifié et undefined est renvoyé.

Si vous appelez cette méthode pour un enfant XML qui n’est pas un élément (texte, attributs, commentaires, pi, etc.), undefined est renvoyé.

Utilisez l’opérateur delete (XML) pour supprimer les nœuds XML.

Paramètres

	`child1:Object` — Objet dans l’objet source que vous insérez avant `child2`.

	`child2:Object` — Objet à insérer.

Valeur renvoyée

* — Objet XML produit ou undefined.

Voir aussi

XML.insertChildBefore()
delete, opérateur (XML)
Objets XML
Assemblage et transformation d'objets XML

Exemple

L'exemple suivant ajoute un nouvel élément à la fin des éléments enfant d'un objet XML :

var xml:XML = 
        <menu>
            <item>burger</item>
            <item>soda</item>
        </menu>;
xml.insertChildAfter(xml.item[0], <saleItem>fries</saleItem>);
trace(xml);

Le code trace() suivant est renvoyé :

 <menu>
 	<item>burger</item>
 	<saleItem>fries</saleItem>
 	<item>soda</item>
 </menu>

insertChildBefore

()

méthode

AS3 function insertChildBefore(child1:Object, child2:Object):*

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Insère le paramètre child2 indiqué après le paramètre child1 dans cet objet XML et renvoie l’objet produit. Si le paramètre child1 est réglé sur null, la méthode insère le contenu de child2 après tous les enfants de l’objet XML (en d’autres termes, avant none). Si child1 est fourni, mais qu’il n’existe pas dans l’objet XML, celui-ci n’est pas modifié et undefined est renvoyé.

Si vous appelez cette méthode pour un enfant XML qui n’est pas un élément (texte, attributs, commentaires, pi, etc.), undefined est renvoyé.

Utilisez l’opérateur delete (XML) pour supprimer les nœuds XML.

Paramètres

	`child1:Object` — Objet de l’objet source que vous insérez après `child2`.

	`child2:Object` — Objet à insérer.

Valeur renvoyée

* — Objet XML produit ou undefined.

Voir aussi

XML.insertChildAfter()
delete, opérateur (XML)
Objets XML
Assemblage et transformation d'objets XML

Exemple

L'exemple suivant ajoute un nouvel élément à la fin des éléments enfant d'un objet XML :

var xml:XML = 
        <menu>
            <item>burger</item>
            <item>soda</item>
        </menu>;
xml.insertChildBefore(xml.bar[0], <saleItem>fries</saleItem>);
trace(xml);

Le code trace() suivant est renvoyé :

<menu>
 	<saleItem>fries</saleItem>
 	<item>burger</item>
 	<item>soda</item>
 </menu>

length

()

méthode

AS3 function length():int

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Pour les objets XML, cette méthode renvoie toujours l’entier 1. La méthode length() de la classe XMLList renvoie la valeur 1 si l’objet XMLList ne contient qu’une seule valeur.

Valeur renvoyée

int — Renvoie toujours 1 pour tout objet XML.

Voir aussi

Objets XML

localName

()

méthode

AS3 function localName():Object

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Indique la partie nom local du nom complet de l’objet XML.

Valeur renvoyée

Object — Nom local exprimé sous forme de chaîne ou null.

Voir aussi

Objets XML

Exemple

L'exemple suivant illustre l'utilisation de la méthode localName().

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
trace(xml.localName()); // Envelope

name

()

méthode

AS3 function name():Object

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Indique le nom complet de l’objet XML.

Valeur renvoyée

Object — Le nom complet correspond à QName ou null.

Voir aussi

XML.attributes()
identificateur d'attribut
Objets XML

Exemple

L'exemple suivant illustre l'utilisation de la méthode name() pour obtenir le nom qualifié d'un objet XML :

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
trace(xml.name().localName); // Envelope
trace(xml.name().uri); // "http://www.w3.org/2001/12/soap-envelope"

L'exemple suivant illustre l'utilisation de la méthode name() lorsqu'elle est appelée sur une propriété XML, sur un élément de texte et sur un attribut :

var xml:XML = 
        <foo x="15" y="22">
            text
        </foo>;
        
trace(xml.name().localName); // foo
trace(xml.name().uri == ""); // true
trace(xml.children()[0]); // text
trace(xml.children()[0].name()); // null
trace(xml.attributes()[0]); // 15
trace(xml.attributes()[0].name()); // x

namespace

()

méthode

AS3 function namespace(prefix:String = null):*

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Si vous ne fournissez pas de paramètre, indique l’espace de nom associé au nom complet de cet objet XML. Si vous spécifiez un paramètre prefix, la méthode renvoie l’espace de nom correspondant au paramètre prefix qui figure dans le domaine associé à l’objet XML. S'il n’existe pas d'espace de nom de ce type, la méthode renvoie undefined.

Paramètres

prefix:String (default = null) — Préfixe pour lequel établir une correspondance.

Valeur renvoyée

* — Renvoie null, undefined ou un espace de nom.

Voir aussi

Objets XML

Exemple

L'exemple suivant utilise la méthode namespace() pour obtenir l'espace de nom d'un objet XML et l'affecter à un objet Namespace appelé soap qui est ensuite utilisé pour identifier une propriété de l'objet xml (xml.soap::Body[0]) :

var xml:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">

                        <soap:Body xmlns:wx = "http://example.com/weather">
                <wx:forecast>
                    <wx:city>Quito</wx:city>
                </wx:forecast>
            </soap:Body>
        </soap:Envelope>;
        
var soap:Namespace = xml.namespace();
trace(soap.prefix); // soap
trace(soap.uri); // http://www.w3.org/2001/12/soap-envelope

var body:XML = xml.soap::Body[0];
trace(body.namespace().prefix); // soap
trace(xml.namespace().uri); // http://www.w3.org/2001/12/soap-envelope
trace(body.namespace("wx").uri); // "http://example.com/weather"

L'exemple suivant utilise la méthode namespace() pour obtenir l'espace de nom par défaut d'un nœud, ainsi que l'espace de nom pour un préfixe spécifique ("dc") :

var xml:XML = 
        <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
            xmlns:dc="http://purl.org/dc/elements/1.1/" 
            xmlns="http://purl.org/rss/1.0/">
                <!-- ... -->
        </rdf:RDF>;
                    
trace(xml.namespace()); // http://www.w3.org/1999/02/22-rdf-syntax-ns#
trace(xml.namespace("dc")); // http://purl.org/dc/elements/1.1/
trace(xml.namespace("foo")); // undefined

namespaceDeclarations

()

méthode

AS3 function namespaceDeclarations():Array

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Recense les déclarations d’espace de nom associées à l’objet XML dans le contexte de l’objet parent.

Valeur renvoyée

Array — Tableau d'objets Namespace.

Voir aussi

XML.namespace()
Objets XML

Exemple

L'exemple suivant renvoie les déclarations d'espace de nom d'un objet XML :

var xml:XML = 
        <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
            xmlns:dc="http://purl.org/dc/elements/1.1/" 
            xmlns="http://purl.org/rss/1.0/">

            <!-- ... -->
            
        </rdf:RDF>;
                    
for (var i:uint = 0; i < xml.namespaceDeclarations().length; i++) {
    var ns:Namespace = xml.namespaceDeclarations()[i]; 
    var prefix:String = ns.prefix;
    if (prefix == "") {
        prefix = "(default)";
    }
    trace(prefix + ":", ns.uri);
}

Le code trace() suivant est renvoyé :

rdf: http://www.w3.org/1999/02/22-rdf-syntax-ns# dc: http://purl.org/dc/elements/1.1/ (default): http://purl.org/rss/1.0/

nodeKind

()

méthode

AS3 function nodeKind():String

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit le type de nœud : texte, commentaire, instruction de traitement, attribut ou élément.

Valeur renvoyée

String — Type de nœud utilisé.

Voir aussi

identificateur d'attribut
Objets XML

Exemple

Cet exemple suit les cinq types de nœud :

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;

var xml:XML = 
    <example id="10">
        <!-- this is a comment -->
        <?test this is a pi ?>
        and some text
    </example>;

trace(xml.nodeKind()); // element
trace(xml.children()[0].nodeKind()); // comment
trace(xml.children()[1].nodeKind()); // processing-instruction
trace(xml.children()[2].nodeKind()); // text
trace(xml.@id[0].nodeKind()); // attribute

normalize

()

méthode

AS3 function normalize():XML

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Pour l’objet XML et tous les objets XML descendants, fusionne les nœuds de texte adjacents et supprime les nœuds de texte vides.

Valeur renvoyée

XML — Objet XML normalisé produit.

Voir aussi

Objets XML

Exemple

L'exemple suivant illustre l'effet de l'appel de la méthode normalize() :

var xml:XML = <body></body>;
xml.appendChild("hello");
xml.appendChild(" world");
trace(xml.children().length()); // 2
xml.normalize();
trace(xml.children().length()); // 1

parent

()

méthode

AS3 function parent():*

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Renvoie le parent de l’objet XML. Si l’objet XML ne possède pas de parent, la méthode renvoie undefined.

Valeur renvoyée

* — Objet XML parent. Renvoie String ou null.

Voir aussi

Objets XML
Parcours de structures XML

Exemple

L'exemple suivant utilise la méthode parent() pour identifier l'élément parent d'un élément spécifique dans une structure XML :

var xml:XML = 
    <body>
        <p id="p1">Hello</p>
        <p id="p2">Test:
            <ul>
                <li>1</li>
                <li>2</li>
            </ul>
        </p>
    </body>;
var node:XML = xml.p.ul.(li.contains("1"))[0]; // == <ul> ... </ul>
trace(node.parent().@id); // p2

prependChild

()

méthode

AS3 function prependChild(value:Object):XML

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Insère une copie de l’objet child fourni dans l’élément XML avant toute propriété XML associée à cet élément.

Utilisez l’opérateur delete (XML) pour supprimer les nœuds XML.

Paramètres

value:Object — Objet à insérer.

Valeur renvoyée

XML — Objet XML produit.

Voir aussi

opérateur delete (XML)
Objets XML
Assemblage et transformation d'objets XML

Exemple

L'exemple suivant utilise la méthode prependChild() pour ajouter un élément au début de la liste d'enfants d'un objet XML :

var xml:XML = 
        <body>
            <p>hello</p>
        </body>;
        
xml.prependChild(<p>world</p>);    
trace(xml.p[0].toXMLString()); // <p>world</p>
trace(xml.p[1].toXMLString()); // <p>hello</p>

processingInstructions

()

méthode

AS3 function processingInstructions(name:String = "*"):XMLList

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Si un paramètre name est spécifié, recense tous les enfants de l’objet XML qui contiennent des instructions de traitement portant le name indiqué. Si aucun paramètre n’est spécifié, la méthode recense tous les enfants de l’objet XML qui contiennent des instructions de traitement.

Paramètres

name:String (default = "*") — Nom des instructions de traitement pour lesquelles établir une correspondance.

Valeur renvoyée

XMLList — Liste d’objets enfants correspondants.

Voir aussi

Objets XML

Exemple

L'exemple suivant utilise la méthode processingInstructions() pour obtenir un tableau d'instructions de traitement pour un objet XML :

XML.ignoreProcessingInstructions = false;
var xml:XML =
    <body>
            foo
            <?xml-stylesheet href="headlines.css" type="text/css" ?>
            <?instructionX ?>
            
    </body>;

trace(xml.processingInstructions().length()); // 2
trace(xml.processingInstructions()[0].name()); // xml-stylesheet

propertyIsEnumerable

()

méthode

AS3 function propertyIsEnumerable(p:String):Boolean

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Vérifie si la propriété p figurre dans le jeu de propriétés qui peut faire l'objet d'une itération avec une instruction for..in appliquée à l'objet XML. Ne renvoie true que si toString(p) == "0".

Paramètres

p:String — Propriété à vérifier.

Valeur renvoyée

Boolean — Si la propriété peut faire l'objet d'une itération dans une instruction for..in, puis true ; sinon false.

Voir aussi

Objets XML

Exemple

L'exemple suivant indique que, pour un objet XML, la méthode propertyNameIsEnumerable() ne renvoie la valeur true que pour la valeur 0, tandis que pour un objet XMLList, la valeur renvoyée est true pour chaque valeur d'index valide pour l'objet XMLList :

var xml:XML = 
        <body>
             <p>Hello</p>
               <p>World</p>
        </body>;

trace(xml.propertyIsEnumerable(0)); // true
trace(xml.propertyIsEnumerable(1)); // false

for (var propertyName:String in xml) {
    trace(xml[propertyName]);
}

var list:XMLList = xml.p;
trace(list.propertyIsEnumerable(0)); // true
trace(list.propertyIsEnumerable(1)); // true
trace(list.propertyIsEnumerable(2)); // false

for (var propertyName:String in list) { 
    trace(list[propertyName]);
}

removeNamespace

()

méthode

AS3 function removeNamespace(ns:Namespace):XML

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Supprime l’espace de nom indiqué pour cet objet et tous ses descendants. La méthode removeNamespaces() ne supprime pas un espace de nom s'il est référencé par le nom complet de l’objet ou celui des attributs de l’objet.

Paramètres

ns:Namespace — Espace de nom à supprimer.

Valeur renvoyée

XML — Copie de l'objet XML produit.

Voir aussi

Objets XML

Exemple

L'exemple suivant indique comment supprimer une déclaration d'espace de nom à partir d'un objet XML :

var xml:XML = 
    <rdf:RDF xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#" 
        xmlns:dc="http://purl.org/dc/elements/1.1/" 
        xmlns="http://purl.org/rss/1.0/">
    
        <!-- ... -->
        
    </rdf:RDF>;

trace(xml.namespaceDeclarations().length); // 3
trace(xml.namespaceDeclarations()[0] is String); // 
var dc:Namespace = xml.namespace("dc");
xml.removeNamespace(dc);
trace(xml.namespaceDeclarations().length); // 2

replace

()

méthode

AS3 function replace(propertyName:Object, value:XML):XML

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Remplace les propriétés spécifiées par le paramètre propertyName par le paramètre value indiqué. Si aucune propriété ne correspond à propertyName, l’objet XML n’est pas modifié.

Paramètres

	`propertyName:Object` — Peut être une valeur numérique, un nom incomplet d’ensemble d’éléments XML, un nom complet d’ensemble d’éléments XML ou le caractère générique astérisque (« * »). Utilisez un nom incomplet pour identifier les éléments XML dans l’espace de nom par défaut.

	`value:XML` — Valeur de remplacement, qui peut être un objet XML, un objet XMLList ou toute valeur pouvant être convertie par le biais de `toString()`.

Valeur renvoyée

XML — Objet XML produit, dans lequel les propriétés correspondantes ont été remplacées.

Voir aussi

Objets XML

Exemple

L'exemple suivant illustre l'appel à la méthode replace() avec un entier en tant que premier paramètre :

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace(1, <p>Bob</p>);
trace(xml);

Le résultat du code trace() est le suivant :


 <body>
 	<p>Hello</p>
 	<p>Bob</p>
 	<hr/>
 </body>

L'exemple suivant appelle la méthode replace() avec une chaîne en tant que premier paramètre :

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace("p", <p>Hi</p>); 
trace(xml);

Le résultat du code trace() est le suivant :


 <body>
 	<p>Hi</p>
 	<hr/>
 </body>;

L'exemple suivant illustre l'appel à la méthode replace() avec un QName en tant que premier paramètre :

var xml:XML = 
    <ns:body xmlns:ns = "myNS">
        <ns:p>Hello</ns:p>
        <ns:p>World</ns:p>
        <hr/>
    </ns:body>;

var qname:QName = new QName("myNS", "p");
xml.replace(qname, <p>Bob</p>);
trace(xml);

Le résultat du code trace() est le suivant :


 <ns:body xmlns:ns = "myNS">
 	<p>Bob</p>
 	<hr/>
 </ns:body>

L'exemple suivant illustre l'appel à la méthode replace() avec la chaîne "*" en tant que premier paramètre :

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
        <hr/>
    </body>;

xml.replace("*", <img src = "hello.jpg"/>);
trace(xml);

Le résultat du code trace() est le suivant :


 <body>
 	<img src="hello.jpg"/>
 </body>

setChildren

()

méthode

AS3 function setChildren(value:Object):XML

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Remplace les propriétés enfant de l'objet XML par l'ensemble de propriétés XML spécifié, fourni dans le paramètre value.

Paramètres

value:Object — Propriétés XML de remplacement (objet XML unique ou objet XMLList).

Valeur renvoyée

XML — Objet XML produit.

Voir aussi

Objets XML

Exemple

L'exemple suivant illustre l'appel de la méthode setChildren(), tout d'abord en utilisant un objet XML en tant que paramètre, puis utilise un objet XMLList en tant que paramètre :

var xml:XML = 
    <body>
        <p>Hello</p>
        <p>World</p>
    </body>;

var list:XMLList = xml.p;

xml.setChildren(<p>hello</p>);
trace(xml);

//    <body>
//        <p>hello</p>
//    </body>

xml.setChildren(list);
trace(xml);

//    <body>
//        <p>Hello</p>
//        <p>World</p>
//    </body>

setLocalName

()

méthode

AS3 function setLocalName(name:String):void

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Remplace le nom local de l’objet XML par le paramètre name indiqué.

Paramètres

name:String — Nom de remplacement du nom local.

Voir aussi

Objets XML

Exemple

L'exemple suivant utilise la méthode setLocalName() pour modifier le nom local d'un élément XML :

var xml:XML = 
    <ns:item xmlns:ns="http://example.com">
        toothbrush
    </ns:item>;
    
xml.setLocalName("orderItem");
trace(xml.toXMLString()); // <ns:orderItem xmlns:ns="http://example.com">toothbrush</ns:orderItem>

setName

()

méthode

AS3 function setName(name:String):void

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Règle le nom de l’objet XML sur le nom complet ou le nom d’attribut indiqué.

Paramètres

name:String — Nouveau nom de l’objet.

Voir aussi

Objets XML

Exemple

L'exemple suivant utilise la méthode setName() pour modifier le nom local d'un élément XML :

var xml:XML = 
    <item>
        toothbrush
    </item>;
    
xml.setName("orderItem");
trace(xml.toXMLString()); // <orderItem>toothbrush</orderItem>

setNamespace

()

méthode

AS3 function setNamespace(ns:Namespace):void

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit l’espace de nom associé à l’objet XML.

Paramètres

ns:Namespace — Nouvel espace de nom.

Voir aussi

Objets XML

Exemple

L'exemple suivant utilise l'espace de nom soap défini dans un objet XML et l'applique à l'espace de nom d'un autre objet XML (xml2) :

var xml1:XML = 
        <soap:Envelope xmlns:soap="http://www.w3.org/2001/12/soap-envelope"
            soap:encodingStyle="http://www.w3.org/2001/12/soap-encoding">
            <!-- ... -->
        </soap:Envelope>;
var ns:Namespace = xml1.namespace("soap");

var xml2:XML = 
    <Envelope>
        <Body/>
    </Envelope>;
    
xml2.setNamespace(ns);

trace(xml2);

setSettings

()

méthode

AS3 static function setSettings(... rest):void

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Définit les valeurs des propriétés XML suivantes : ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent et prettyPrinting. Les réglages par défaut, appliqués si vous ne spécifiez pas de paramètre setObj, sont les suivants :

XML.ignoreComments = true
XML.ignoreProcessingInstructions = true
XML.ignoreWhitespace = true
XML.prettyIndent = 2
XML.prettyPrinting = true

Remarque : cette méthode ne doit pas être appliquée à une occurrence de la classe XML, mais à XML, comme illustré dans le code suivant : XML.setSettings().

Paramètres

... rest — Objet doté des propriétés suivantes :

ignoreComments
ignoreProcessingInstructions
ignoreWhitespace
prettyIndent
prettyPrinting

Voir aussi

ignoreComments
ignoreProcessingInstructions
ignoreWhitespace
prettyIndent
prettyPrinting
defaultSettings()
settings()
Paramètres de fonction
Objets XML

Exemple

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

settings

()

méthode

AS3 static function settings():Object

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Extrait les propriétés suivantes : ignoreComments, ignoreProcessingInstructions, ignoreWhitespace, prettyIndent et prettyPrinting.

Valeur renvoyée

Object — Objet doté des propriétés XML suivantes :

ignoreComments
ignoreProcessingInstructions
ignoreWhitespace
prettyIndent
prettyPrinting

Voir aussi

XML.ignoreComments
XML.ignoreProcessingInstructions
XML.ignoreWhitespace
XML.prettyIndent
XML.prettyPrinting
XML.defaultSettings()
XML.setSettings()

Exemple

XML.ignoreComments = false;
XML.ignoreProcessingInstructions = false;
var customSettings:Object = XML.settings();

var xml1:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml1.toXMLString());
//    <foo>
//        <!-- comment -->
//         <?instruction ?>
//    </foo>

XML.setSettings(XML.defaultSettings());
var xml2:XML = 
        <foo>
            <!-- comment -->
            <?instruction ?>
        </foo>;
trace(xml2.toXMLString());

text

()

méthode

AS3 function text():XMLList

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Renvoie un objet XMLList contenant toutes les propriétés XML de l’objet XML qui représente les nœuds de texte XML.

Valeur renvoyée

XMLList — Liste des propriétés.

Voir aussi

Objets XML

Exemple

L'exemple suivant utilise la méthode text() pour obtenir les nœuds texte d'un objet XML :

var xml:XML =
        <body>
            text1
            <hr/>
            text2
        </body>;
trace(xml.text()[0]); // text1
trace(xml.text()[1]); // text2

toString

()

méthode

AS3 function toString():String

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Renvoie l’objet XML sous forme de chaîne. Les règles de cette conversion varient selon que l’objet XML intègre un contenu simple ou complexe :

Si l'objet XML comporte un contenu simple, toString() renvoie le contenu de la chaîne de l'objet XML en éliminant les éléments suivants : la balise initiale, les attributs, les déclarations d'espace de nom et la balise de fin.

Si l’objet XML intègre un contenu complexe, toString() renvoie une chaîne codée au format XML qui représente l’objet XML entier, y compris la balise de début, les attributs, les déclarations d’espace de nom et la balise de fin.

Pour renvoyer à chaque fois l’objet XML entier, utilisez la méthode toXMLString().

Valeur renvoyée

String — Représentation sous forme de chaîne de l’objet XML.

Voir aussi

XML.hasSimpleContent()
XML.hasComplexContent()
XML.toXMLString()
Conversion de type XML

Exemple

L'exemple suivant indique ce que la méthode toString() renvoie lorsque l'objet XML a un contenu simple :

var test:XML = <type name="Joe">example</type>;
trace(test.toString()); //example

L'exemple suivant indique ce que la méthode toString() renvoie lorsque l'objet XML a un contenu complexe :

var test:XML = 
<type name="Joe">
    <base name="Bob"></base>
    example
</type>;
trace(test.toString());
  // <type name="Joe">
  // <base name="Bob"/>
  // example
  // </type>

toXMLString

()

méthode

AS3 function toXMLString():String

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Renvoie l’objet XML sous forme de chaîne. A l’encontre de la méthode toString(), la méthode toXMLString() renvoie toujours la balise de début, les attributs et la balise de fin de l’objet XML, que son contenu soit simple ou complexe. (La méthode toString() supprime ces éléments si l’objet XML intègre un contenu simple.)

Valeur renvoyée

String — Représentation sous forme de chaîne de l’objet XML.

Voir aussi

XML.toString()
Objets XML
Conversion de type XML

Exemple

L'exemple suivant illustre la différence entre l'utilisation de la méthode toString() (qui s'applique à tous les paramètres d'une méthode trace(), par défaut) et celle de la méthode toXMLString() :

var xml:XML =
        <p>hello</p>;
trace(xml); // hello
trace(xml.toXMLString()); // <p>hello</p>

valueOf

()

méthode

AS3 function valueOf():XML

Version du langage :

ActionScript 3.0

Version du lecteur :

Flash Player 9

Renvoie l’objet XML.

Valeur renvoyée

XML — Valeur primitive d’une occurrence de XML.

Voir aussi

Objets XML

Exemple

L'exemple suivant indique que la valeur renvoyée par la méthode valueOf() est identique à l'objet XML source :

var xml:XML = <p>hello</p>;
trace(xml.valueOf() === xml); // true

Exemples Utilisation des exemples

XMLExample.as

L'exemple suivant crée tout d'abord une variable XML, puis y ajoute des nœuds. Ensuite, les propriétés XML permettent de trouver et imprimer des nœuds XML. Vous pouvez constater que le symbole « arrobase » (@) est utilisé dans plusieurs des appels trace() pour rechercher des informations en fonction du nom d'attribut.

package {
    import flash.display.Sprite;

    public class XmlExample extends Sprite {        
        public function XmlExample() {
            var employees:XML =
                <employees>
                    <employee ssn="123-123-1234">
                        <name first="John" last="Doe"/>
                        <address>
                            <street>11 Main St.</street>
                            <city>San Francisco</city>
                            <state>CA</state>
                            <zip>98765</zip>
                        </address>
                    </employee>
                    <employee ssn="789-789-7890">
                        <name first="Mary" last="Roe"/>
                        <address>
                            <street>99 Broad St.</street>
                            <city>Newton</city>
                            <state>MA</state>
                            <zip>01234</zip>
                        </address>
                    </employee>
                </employees>;

            trace(employees.employee[0].address.zip);   // 98765

            trace(employees.employee[1].@ssn);          // 789-789-7890

            trace(employees.employee.name);             // <name first="John" last="Doe"/>
                                                        // <name first="Mary" last="Roe"/>

            trace(employees..zip[0]);                   // 98765

            trace(employees..@ssn[1]);                  // 789-789-7890

            trace(employees..name);                     // <name first="John" last="Doe"/>
                                                        // <name first="Mary" last="Roe"/>

            trace(employees.employee[0].address.*);     // <street>11 Main St.</street>    
                                                        // <city>San Francisco</city>
                                                        // <state>CA</state>
                                                        // <zip>98765</zip>
            var node:String = "zip";
            trace(employees.employee[0].address[node]); // 98765
            
            var attribute:String = "ssn";
            trace(employees.employee[1].@[attribute]);  // 789-789-7890
            
            for each (var num:XML in employees..@ssn) {
                trace(num);                             // 123-123-1234
            }                                           // 789-789-7890
            
            var ssnToFind:String = "789-789-7890";
            trace(employees.employee.(@ssn == ssnToFind).toXMLString());
                                                        // <employee ssn="789-789-7890">
                                                        // <name first="Mary" last="Roe"/>
                                                        // <address>
                                                        // <street>99 Broad St.</street>
                                                        // <city>Newton</city>
                                                        // <state>MA</state>
                                                        // <zip>01234</zip>
                                                        // </address>
                                                        // </employee>
        }
    }
}

Page en cours: http://livedocs.adobe.com/flash/9.0_fr/ActionScriptLangRefV3/XML.html

Guide de référence du langage et des composants ActionScript 3.0		Tous les packages \| Toutes les classes \| Eléments du langage \| Index \| Annexes \| Conventions \| Images Aucune image
XML	Propriétés \| Méthodes \| Exemples

Package	Niveau supérieur
Classe	public final dynamic class XML
Héritage	XML Object