Documentación de Flash CS3

Aprendizaje de ActionScript 2.0 en Adobe Flash > Trabajo con clips de película > Asignación de caché y desplazamiento de clips de película con ActionScript > Asignación de caché para un clip de película

Asignación de caché para un clip de película

Para asignar caché a una instancia de clip de película, necesita establecer la propiedad cacheAsBitmap en true. Una vez que haya establecido la propiedad cacheAsBitmap con el valor true, puede que observe que la instancia de clip de película ajusta automáticamente los píxeles a coordenadas enteras. Cuando pruebe el archivo SWF, debería apreciar un aumento considerable en la velocidad de representación de animaciones vectoriales complejas.

Si se dan una o varias de las siguientes condiciones, no se crea ninguna superficie (mapa de bits en caché) aunque cacheAsBitmap se haya establecido como true:

• El mapa de bits tiene una altura o una anchura superior a 2880 píxeles.
• El mapa de bits no puede asignarse (error de memoria insuficiente).

Para asignar caché a un clip de película:

1. Cree un nuevo documento de Flash y asigne al archivo el nombre cachebitmap.fla.
2. Escriba 24 en el cuadro de texto fps del inspector de propiedades (Ventana > Propiedades > Propiedades).
3. Cree o importe un gráfico vectorial complejo al archivo FLA.

   Para ver el origen de un gráfico vectorial complejo, CacheBitmap, visite la página de ejemplos de Flash en www.adobe.com/go/learn_fl_samples_es. Descargue el archivo zip Samples y vaya a la carpeta ActionScript2.0/CacheBitmap para acceder al ejemplo.

4. Seleccione el gráfico vectorial y luego Modificar > Convertir en símbolo.
5. Escriba star en el cuadro de texto Nombre y haga clic en Avanzado (si el cuadro de diálogo no está aún expandido).
6. Seleccione Exportar para ActionScript (que también selecciona Exportar en primer fotograma).
7. Introduzca star_id en el cuadro de texto Identificador.
8. Haga clic en Aceptar para crear el símbolo del clip de película, con el identificador de vinculación de Star.
9. Seleccione el fotograma 1 de la línea de tiempo y añada el siguiente código ActionScript en el panel Acciones:

   import mx.transitions.Tween;
   
   var star_array:Array = new Array();
   for (var i:Number = 0; i < 20; i++) {
       makeStar();
   }
   function makeStar():Void {
       var depth:Number = this.getNextHighestDepth();
       var star_mc:MovieClip = this.attachMovie("star_id", "star" + depth, depth);
       star_mc.onEnterFrame = function() {
           star_mc._rotation += 5;
       }
       star_mc._y = Math.round(Math.random() * Stage.height - star_mc._height / 2);
       var star_tween:Tween = new Tween(star_mc, "_x", null, 0, Stage.width, (Math.random() * 5) + 5, true);
       star_tween.onMotionFinished = function():Void  {
           star_tween.yoyo();
       };
       star_array.push(star_mc);
   }
   var mouseListener:Object = new Object();
   mouseListener.onMouseDown = function():Void {
       var star_mc:MovieClip;
       for (var i:Number = 0; i < star_array.length; i++) {
           star_mc = star_array[i];
           star_mc.cacheAsBitmap = !star_mc.cacheAsBitmap;
       }
   }
   Mouse.addListener(mouseListener);
   

10. Seleccione Control > Probar película para probar el documento.
11. Haga clic en cualquier parte del escenario para activar la caché de mapa de bits.

    Advertirá que la animación cambia de aparecer moviéndose a un fotograma por segundo, a una animación suave donde las instancias se animan hacia atrás y hacia adelante en el escenario. Cuando hace clic en el escenario, cambia el valor de cacheAsBitmap entre true y false.

Si activa y desactiva la caché, como se ha mostrado en el ejemplo anterior, se liberan los datos asignados a la caché. También puede aplicar este código a la instancia Button. Consulte cacheAsBitmap (propiedad Button.cacheAsBitmap) en Referencia del lenguaje ActionScript 2.0.

Para ver ejemplos de desplazamiento de clips de película, consulte scrollRect (propiedad MovieClip.scrollRect) en Referencia del lenguaje ActionScript 2.0. Para obtener información sobre el enmascaramiento del canal alfa, que requiere que establezca la propiedad cacheAsBitmap como true, consulte Enmascaramiento del canal alfa.

Para ver ejemplos que aplican la caché de mapa de bits a una instancia y al texto de desplazamiento, visite la página de ejemplos de Flash en www.adobe.com/go/learn_fl_samples_es. Están disponibles los siguientes ejemplos:

• cacheBitmap.fla - Descargue el archivo zip Samples y vaya a la carpeta ActionScript2.0/CacheBitmap.
• aliasing.fla - Descargue el archivo zip Samples y vaya a la carpeta ActionScript2.0/Advanced Anti-Aliasing para acceder a los ejemplos.

Flash CS3

Enviarme un mensaje de correo electrónico cuando se añadan comentarios a esta página | Informe de comentarios

Página actual: http://livedocs.adobe.com/flash/9.0_es/main/00000869.html

Añadir comentario