Captura de entrada de texto -- Flash CS3

De manera predeterminada, la propiedad type de un campo de texto está establecida en dynamic. Si se establece la propiedad type en input mediante la clase TextFieldType, se puede obtener la entrada del usuario y guardar el valor para utilizarlo en otras partes de la aplicación. Los campos de entrada de texto son útiles para los formularios y para cualquier aplicación que requiera que el usuario defina un valor de texto para utilizarlo en otro lugar del programa.

Por ejemplo, el código siguiente crea un campo de entrada de texto llamado myTextBox. Cuando el usuario escribe texto en el campo, se activa el evento textInput. Un controlador de eventos denominado textInputCapture captura la cadena de texto introducido y se la asigna a una variable. Flash Player muestra el nuevo texto en otro campo de texto, denominado myOutputBox.

package
{
    import flash.display.Sprite;
    import flash.display.Stage;
    import flash.text.*;
    import flash.events.*;

    public class CaptureUserInput extends Sprite
    {
        private var myTextBox:TextField = new TextField();
        private var myOutputBox:TextField = new TextField();
        private var myText:String = "Type your text here.";

        public function CaptureUserInput()
        {
            captureText();
        }
        
        public function captureText():void
        {
            myTextBox.type = TextFieldType.INPUT;
            myTextBox.background = true;
            addChild(myTextBox);
            myTextBox.text = myText;
            myTextBox.addEventListener(TextEvent.TEXT_INPUT, textInputCapture);
        }
        
        public function textInputCapture(event:TextEvent):void
        {
            var str:String = myTextBox.text;
            createOutputBox(str);
        }
            
        public function createOutputBox(str:String):void
        {
            myOutputBox.background = true;
            myOutputBox.x = 200;
            addChild(myOutputBox);
            myOutputBox.text = str;
        }
        
    }
}