Documentación de Flash CS3

Programación con ActionScript 3.0 > Utilización de XML > Construcción y transformación de objetos XML

Construcción y transformación de objetos XML

Los métodos prependChild() y appendChild() permiten añadir una propiedad al principio o al final (respectivamente) de una lista de propiedades de un objeto XML, como se indica en el siguiente ejemplo:

var x1:XML = <p>Line 1</p> 
var x2:XML = <p>Line 2</p> 
var x:XML = <body></body>
x = x.appendChild(x1);
x = x.appendChild(x2);
x = x.prependChild(<p>Line 0</p>);
    // x == <body><p>Line 0</p><p>Line 1</p><p>Line 2</p></body>

Los métodos insertChildBefore() e insertChildAfter() permiten añadir una propiedad antes o después (respectivamente) de una propiedad especificada, como se indica a continuación:

var x:XML = 
    <body>
        <p>Paragraph 1</p> 
        <p>Paragraph 2</p>
    </body>
var newNode:XML = <p>Paragraph 1.5</p> 
x = x.insertChildAfter(x.p[0], newNode)
x = x.insertChildBefore(x.p[2], <p>Paragraph 1.75</p>)

Como se indica en el siguiente ejemplo, también se pueden utilizar operadores de llave ( { y } ) para pasar datos por referencia (desde otras variables) al construir objetos XML:

var ids:Array = [121, 122, 123]; 
var names:Array = [["Murphy","Pat"], ["Thibaut","Jean"], ["Smith","Vijay"]]
var x:XML = new XML("<employeeList></employeeList>");

for (var i:int = 0; i < 3; i++)
{
    var newnode:XML = new XML(); 
    newnode =
        <employee id={ids[i]}>
            <last>{names[i][0]}</last>
            <first>{names[i][1]}</first>
        </employee>;

    x = x.appendChild(newnode)
}

Se pueden asignar propiedades y atributos a un objeto XML utilizando el operador =, como se indica a continuación:

var x:XML = 
    <employee>
        <lastname>Smith</lastname>
    </employee>
x.firstname = "Jean";
x.@id = "239";

Esto establece el valor del objeto XML x en:

<employee id="239">
    <lastname>Smith</lastname>
    <firstname>Jean</firstname>
</employee>

Se pueden utilizar los operadores + y += para concatenar objetos XMLList.

var x1:XML = <a>test1</a> 
var x2:XML = <b>test2</b> 
var xList:XMLList = x1 + x2;
xList += <c>test3</c>

Esto establece el valor del objeto XMLList xList en:

<a>test1</a>
<b>test2</b>
<c>test3</c>

Flash CS3

Enviarme un mensaje de correo electrónico cuando se añadan comentarios a esta página | Informe de comentarios

Página actual: http://livedocs.adobe.com/flash/9.0_es/main/00000128.html