Permite al usuario avanzar o retroceder un fotograma de un archivo SWF en tiempo de ejecución (no se muestra en archivos SWF de un solo fotograma).

Permite al usuario definir un archivo SWF para que se inicie automáticamente cuando llegue al último fotograma (no se muestra en archivos SWF de un solo fotograma).

Permite al usuario iniciar un archivo SWF interrumpido (no se muestra en archivos SWF de un solo fotograma).

Permite al usuario enviar la imagen del fotograma mostrado a una impresora.

Permite al usuario establecer la resolución del archivo SWF en tiempo de ejecución.

Permite al usuario definir un archivo SWF para que se reproduzca desde el primer fotograma al seleccionarlo, en cualquier momento (no se muestra en archivos SWF de un solo fotograma).

Permite a usuarios con Shockmachine instalado guardar un archivo SWF.

Permite al usuario ampliar y reducir un archivo SWF en tiempo de ejecución.

Crea un nuevo objeto ContextMenuBuiltInItems para poder establecer las propiedades de modo que Flash Player muestre u oculte cada elemento de menú.

1. Se declara una propiedad myContextMenu y, a continuación, se asigna a un nuevo objeto ContextMenu.
2. Se llama al método removeDefaultItems(), que elimina todos los elementos incorporados en el menú contextual salvo Print.
3. Se llama al método addCustomMenuItems(), que coloca el elemento de menú Hello World en la matriz customItems a través del método push() de la clase Array.
4. A continuación, el elemento de menú Hello World se añade a la lista de elementos del menú contextual del escenario.
5. Se añade al centro del escenario un objeto TextField con el texto "Right Click" utilizando addChild() a través de createLabel().

package {
    import flash.ui.ContextMenu;
    import flash.ui.ContextMenuItem;
    import flash.ui.ContextMenuBuiltInItems;
    import flash.display.Sprite;
    import flash.text.TextField;

    public class ContextMenuBuiltInItemsExample extends Sprite {
        private var myContextMenu:ContextMenu;

        public function ContextMenuBuiltInItemsExample() {
            myContextMenu = new ContextMenu();
            removeDefaultItems();
            addCustomMenuItems();
            this.contextMenu = myContextMenu;
            addChild(createLabel());
        }

        private function removeDefaultItems():void {
            myContextMenu.hideBuiltInItems();

            var defaultItems:ContextMenuBuiltInItems = myContextMenu.builtInItems;
            defaultItems.print = true;
        }

        private function addCustomMenuItems():void {
            var item:ContextMenuItem = new ContextMenuItem("Hello World");
            myContextMenu.customItems.push(item);
        }

        private function createLabel():TextField {
            var txtField:TextField = new TextField();
            txtField.text = "Right Click";
            txtField.x = this.stage.stageWidth/2 - txtField.width/2;
            txtField.y = this.stage.stageHeight/2 - txtField.height/2;
            return txtField;
        }
    }
}