Indica la alineación del párrafo. Los valores válidos son constantes TextFormatAlign:

El valor predeterminado es TextFormatAlign.LEFT.

Véase también

Indica la sangría de bloque, expresada en píxeles. La sangría de bloque se aplica a un bloque de texto completo; es decir, a todas las líneas del texto. Por el contrario, la sangría normal (TextFormat.indent) sólo afecta a la primera línea de cada párrafo. Si esta propiedad tiene el valor null, el objeto TextFormat no especifica la sangría de bloque (que es 0).

Especifica si el texto está en negrita. El valor predeterminado es null, lo que indica que no se utiliza la negrita. Si el valor es true, el texto está en negrita.

Indica que el texto forma parte de una lista con viñetas. En una lista con viñetas, todos los párrafos de texto están sangrados. A la izquierda de la primera línea de cada párrafo se muestra un símbolo de viñeta. El valor predeterminado es null, lo que indica que no se utiliza ninguna lista con viñetas.

Indica el color del texto. Número que contiene tres componentes RGB de 8 bits; por ejemplo, 0xFF0000 es rojo y 0x00FF00, verde. El valor predeterminado es null, lo que indica que Flash Player utiliza el color negro (0x000000).

El nombre de la fuente del texto con este formato, expresado como una cadena. El valor predeterminado es null, lo que indica que Flash Player utiliza la fuente Times New Roman para el texto.

Indica la sangría desde el margen izquierdo hasta el primer carácter del párrafo. El valor predeterminado es null, que indica que no se utiliza ninguna sangría.

Véase también

Indica si el texto de este formato está en cursiva. El valor predeterminado es null, lo que indica que no se utiliza la cursiva.

Un valor booleano que indica si el ajuste de caracteres está activado (true) o desactivado (false). El kerning ajusta los píxeles entre determinadas parejas de caracteres para que puedan leerse mejor. Sólo debe utilizarse cuando sea necesario, por ejemplo, en los encabezados con fuentes grandes. El kerning sólo se admite en las fuentes incorporadas.

Determinadas fuentes, como Verdana y las fuentes con espacio fijo (como Courier New), no admiten el kerning.

El valor predeterminado es null, que indica que el kerning está desactivado.

Un entero que representa la cantidad de espacio vertical entre líneas (denominado interlineado). El valor predeterminado es null, lo que indica que el interlineado utilizado es 0.

El margen izquierdo del párrafo, expresado en píxeles. El valor predeterminado es null, lo que indica que el margen izquierdo es de 0 píxeles.

Un número que representa la cantidad de espacio distribuido uniformemente entre todos los caracteres. El valor especifica el número de píxeles que se añaden después de cada carácter durante el avance. El valor predeterminado es null, lo que indica que se utilizan 0 píxeles para el espaciado entre caracteres. Puede utilizar valores decimales como 1.75.

El margen derecho del párrafo, expresado en píxeles. El valor predeterminado es null, lo que indica que el margen derecho es de 0 píxeles.

El tamaño en puntos del texto con este formato de texto. El valor predeterminado es null, lo que indica que el tamaño en puntos utilizado es 12.

Especifica las tabulaciones personalizadas como una matriz de enteros no negativos. Cada tabulación se especifica en píxeles. Si no se han especificado tabulaciones personalizadas (null), la tabulación predeterminada es 4 (la anchura media de los caracteres).

Indica la ventana de destino en la que se muestra el hipervínculo. Si la ventana de destino es una cadena vacía, el texto se muestra en la ventana de destino predeterminada, _self. Puede elegir un nombre personalizado o uno de los cuatro nombres siguientes: La opción _self especifica el marco actual de la ventana actual, _blank especifica una ventana nueva, _parent especifica el nivel superior del marco actual y _top el marco del nivel más alto de la ventana actual. Si la propiedad TextFormat.url es una cadena vacía o tiene el valor null, puede obtener o definir esta propiedad, pero ésta no tendrá ningún efecto.

Véase también

Indica si el texto que utiliza este formato de texto está subrayado (true) o no (false). Este subrayado es similar al que se obtiene mediante la etiqueta <U>, aunque ésta última no es un subrayado real, ya que no omite los trazos descendentes correctamente. El valor predeterminado es null, que indica que no se utiliza ningún subrayado.

Indica la URL de destino para el texto en este formato de texto. Si la propiedad url es una cadena vacía, el texto no tiene hipervínculo. El valor predeterminado es null, lo que indica que el texto no tiene hipervínculo.

Nota: el texto con el formato de texto asignado debe definirse con la propiedad htmlText para que funcione el hipervínculo.

Véase también

Crea un objeto TextFormat con las propiedades especificadas. Puede cambiar las propiedades del objeto TextFormat para cambiar el formato de los campos de texto.

Cualquier parámetro puede establecerse en null para indicar que no está definido. Todos los parámetros son opcionales; se considerará que los parámetros que se omitan tienen el valor null.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFormat;
    import flash.text.TextFieldAutoSize;
    import flash.events.MouseEvent;
    import flash.text.TextFormatAlign;

    public class TextFormat_constructorExample extends Sprite {
        private var contentTextField:TextField = new TextField();
        private var formatTextField:TextField = new TextField();
        private var newFormat:TextFormat = new TextFormat();

        public function TextFormat_constructorExample() {
            contentTextField.x = 10;
            contentTextField.y = 10;
            contentTextField.background = true;
            contentTextField.border = true;
            contentTextField.multiline = true;
            contentTextField.wordWrap = true;
            contentTextField.selectable = false;
            contentTextField.width = 250;
            contentTextField.height = 120;

            contentTextField.htmlText = "<p>The TextFormat class represents character formatting "
                + "information. Use the TextFormat class to create specific text formatting "
                + "for text fields." +
                " </p><br>" + "\tTab One" + "\tTab Two<br>";

            formatTextField.x = 10;
            formatTextField.y = 140;
            formatTextField.background = true;
            formatTextField.border = true;
            formatTextField.autoSize = TextFieldAutoSize.LEFT;

            formatTextField.text = "align: right\n" + "blockIndent: 10 pixels\n" + "bold:\n" + "bullet:\n" + "color: red\n"
                                + "font: Arial\n" + "indent: 20 pixels\n" + "italic:\n" + "leading: 5 spaces\n"
                                + "leftMargin: 20 pixels\n" + "letterSpacing: 4 pixels\n" + "rightMargin: 20 pixels\n"
                                + "size: 16 point\n" + "target: new window\n" + "tabStops: 50 and 150 pixel\n"
                                + "underline:\n" + "url: Adobe Flex page\n";

            formatTextField.addEventListener(MouseEvent.CLICK, formatTextFieldClickHandler);

            contentTextField.addEventListener(MouseEvent.CLICK, contentTextFieldClickHandler);

            this.addChild(contentTextField);
            this.addChild(formatTextField);
        }

        private function formatTextFieldClickHandler(e:MouseEvent):void {
                var value:String= "";
                var i:uint = 0;
                var index:int = formatTextField.getLineIndexAtPoint(e.localX, e.localY);
                var line:String = formatTextField.getLineText(index);;

                line = line.substr(0, (line.indexOf(":")));

                switch(line) {
                    case "align":
                        newFormat.align = TextFormatAlign.RIGHT;
                        break;
                    case "blockIndent":
                        newFormat.blockIndent = 10;
                        break;
                    case "bold":
                        newFormat.bold = true;
                        break;
                    case "bullet":
                        newFormat.bullet = true;
                        break;
                    case "color":
                        newFormat.color = 0xFF0000;
                        break;
                    case "font":
                        newFormat.font = "Arial";
                        break;
                    case "indent":
                        newFormat.indent = 20;
                        break;
                    case "italic":
                        newFormat.italic = true;
                        break;
                    case "leading":
                        newFormat.leading = 5;
                        break;
                    case "leftMargin":
                        newFormat.leftMargin = 20;
                        break;
                    case "letterSpacing":
                        newFormat.letterSpacing = 4;
                        break;
                    case "rightMargin":
                        newFormat.rightMargin = 20;
                        break;
                    case "size":
                        newFormat.size = 16;
                        break;
                    case "tabStops":
                        newFormat.tabStops = [50, 150];
                        break;
                    case "target":
                        newFormat.url = "http://www.adobe.com/products/flex/";
                        newFormat.target = "_blank";
                        break;
                    case "underline":
                        newFormat.underline = true;
                        break;
                    case "url":
                        newFormat.url = "http://www.adobe.com/products/flex/";
                        break;
                }

                contentTextField.setTextFormat(newFormat);
        }

        private function contentTextFieldClickHandler(e:MouseEvent):void {
            contentTextField.setTextFormat(contentTextField.defaultTextFormat);
            newFormat = contentTextField.defaultTextFormat;
        }
    }
}

1. Se crea una propiedad label de tipo TextField.
2. El constructor de la clase llama a la función configureLabel().
3. La función configureLabel() crea primero un nuevo objeto TextField y lo asigna a la propiedad label; a continuación, establece sus parámetros del modo siguiente:
   • Justifica a la izquierda el campo de texto.
   • Habilita el relleno de fondo.
   • Habilita el borde.
4. El método configureLable() crea la variable local format y la asigna a una nueva instancia de TextFormat con los parámetros establecidos del siguiente modo:
   • Tipo de fuente = Verdana
   • Color de fuente = continuo rojo
   • Tamaño de fuente = 10
   • Subrayado de fuente = true
5. La propiedad defaultTextFormat de la etiqueta se define como format y la instancia label se añade a la lista de visualización, que muestra inicialmente un campo de texto sin texto (un cuadro diminuto con un fondo blanco) en el escenario.
6. Por último (de nuevo en el constructor), se establece el texto de la etiqueta para que muestre "Hello World and welcome to the show" en las coordenadas x = 0, y = 0 mediante la llamada a setLabel().

 package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;


    public class TextFormatExample extends Sprite {
        private var label:TextField;

        public function TextFormatExample() {
            configureLabel();
            setLabel("Hello World and welcome to the show");
        }

        public function setLabel(str:String):void {
            label.text = str;
        }

        private function configureLabel():void {
            label = new TextField();
            label.autoSize = TextFieldAutoSize.LEFT;
            label.background = true;
            label.border = true;

            var format:TextFormat = new TextFormat();
            format.font = "Verdana";
            format.color = 0xFF0000;
            format.size = 10;
            format.underline = true;

            label.defaultTextFormat = format;
            addChild(label);
        }
    }
}