Orientación con que se imprime la página. Esta propiedad es un valor de la clase PrintJobOrientation. Esta propiedad sólo está disponible tras realizar una llamada al método PrintJob.start().

Véase también

La altura del área real de la página que se puede imprimir, en puntos. Los márgenes establecidos por el usuario no se tienen en cuenta. Esta propiedad sólo está disponible tras realizar una llamada al método PrintJob.start().

Véase también

La anchura del área real de la página que se puede imprimir, en puntos. Los márgenes establecidos por el usuario no se tienen en cuenta. Esta propiedad sólo está disponible tras realizar una llamada al método PrintJob.start().

Véase también

Altura total del papel en puntos. Esta propiedad sólo está disponible tras realizar una llamada al método PrintJob.start().

Anchura total del papel en puntos. Esta propiedad sólo está disponible tras realizar una llamada al método PrintJob.start().

Crea un objeto PrintJob que se puede utilizar para imprimir una o varias páginas. Tras crear un objeto PrintJob, es necesario utilizar (en el orden siguiente) los métodos PrintJob.start(), PrintJob.addPage() y PrintJob.send() para enviar el trabajo de impresión a la impresora.

Por ejemplo, se puede reemplazar el texto del marcador de posición [params] de las llamadas al método my_pj.addPage() mediante parámetros personalizados del modo que se indica a continuación en el siguiente código:

 // create PrintJob object
 var my_pj:PrintJob = new PrintJob();

 // display Print dialog box, but only initiate the print job
 // if start returns successfully.
 if (my_pj.start()) {

    // add specified page to print job
    // repeat once for each page to be printed
    try {
      my_pj.addPage([params]);
    }
    catch(e:Error) {
      // handle error
    }
    try {
      my_pj.addPage([params]);
    }
    catch(e:Error) {
     // handle error
    }

    // send pages from the spooler to the printer, but only if one or more
    // calls to addPage() was successful. You should always check for successful
    // calls to start() and addPage() before calling send().
    my_pj.send();
 }
 

No puede crear un segundo objeto PrintJob mientras el primero continúa activo. Si crea un segundo objeto PrintJob (llamando a new PrintJob()), aunque continúe activo el primer objeto PrintJob, el segundo objeto no se creará. Por lo tanto, puede comprobar el valor my_pj antes de crear un segundo objeto PrintJob.

Véase también

Envía el objeto Sprite especificado como página individual a la cola de impresión. Antes de utilizar este método, es necesario crear un objeto PrintJob y, a continuación, utilizar PrintJob.start(). A continuación, después de llamar a PrintJob.addPage() una o varias veces para un trabajo de impresión, utilice PrintJob.send() para enviar las páginas de la cola de impresión a la impresora. Dicho de otro modo, tras crear un objeto PrintJob, utilice (en el orden siguiente) PrintJob.start(), PrintJob.addPage() y PrintJob.send() para enviar el trabajo de impresión a la impresora. Puede utilizar PrintJob.addPage() varias veces después de una sola llamada a PrintJob.start() para imprimir varias páginas al mismo tiempo.

Si PrintJob.addPage() obliga a Flash Player a emitir una excepción (por ejemplo, si no ha llamado a PrintJob.start() o el usuario ha cancelado el trabajo de impresión), las siguientes llamadas a PrintJob.addPage() fallarán. No obstante, si las llamadas anteriores a PrintJob.addPage() se han realizado correctamente, el comando final PrintJob.send() enviará las páginas que se han situado correctamente en la cola a la impresora.

Si el trabajo de impresión tarda más de 15 segundos en completar una operación PrintJob.addPage(), Flash Player emitirá una excepción en la siguiente llamada a Print.addPage().

Si pasa un valor para el parámetro printArea, las coordenadas x e y del objeto printArea corresponderán a la esquina superior izquierda (coordenadas 0,0) del área imprimible de la página. El área imprimible se describe mediante las propiedades de sólo lectura pageHeight y pageWidth definidas por PrintJob.start(). Dado que la impresión se alinea con la esquina superior izquierda del área imprimible de la página, si el área definida en printArea es superior al área imprimible de la página, la impresión se recortará por la derecha o por abajo (o por ambos lados) del área definida por printArea. Si no pasa un valor para printArea y el escenario es mayor que el área imprimible, se producirá el mismo tipo de recorte.

Si desea redimensionar un objeto Sprite antes de imprimirlo, defina las propiedades (consulte flash.display.DisplayObject.scaleX y flash.display.DisplayObject.scaleY) antes de llamar a este método y vuelva a definir sus valores originales. La escala de un objeto Sprite no tiene relación con printArea. Es decir, si especifica un área de impresión de 50 x 50 píxeles, se imprimirán 2.500 píxeles. Si cambia la escala del objeto Sprite, se seguirán imprimiendo 2.500 píxeles, pero el objeto Sprite se imprimirá con el tamaño escalado.

La función de impresión de Flash Player admite las impresoras PostScript, entre otras. Las impresoras que no son PostScript convierten los vectores en mapas de bits.

Parámetros

Véase también

Envía páginas a la cola de impresión tras comprobar que PrintJob.start() y PrintJob.addPage() se han recibido correctamente. Las llamadas a PrintJob.send() no serán correctas si falla la llamada a PrintJob.start(), o bien si PrintJob.addpage() emite una excepción. Por lo tanto, debe comprobar que PrintJob.start() devuelve true y capturar cualquier excepción de PrintJob.addpage() antes de llamar a PrintJob.send(). Por ejemplo:

  var my_pj:PrintJob = new PrintJob();
    if (my_pj.start()) {
    try {
      my_pj.addPage([params]);
   }
    catch(e:Error) {
      // gestionar error 
   }
      my_pj.send();
  }
  

Véase también

Muestra el cuadro de diálogo Imprimir del sistema operativo, inicia el envío a la cola de impresión y define los valores de la propiedad de sólo lectura del objeto PrintJob. El cuadro de diálogo Imprimir permite al usuario cambiar la configuración de impresión. Si se devuelve correctamente el método PrintJob.start() (el usuario hace clic en Aceptar en el cuadro de diálogo Imprimir), se llenarán las siguientes propiedades de sólo lectura para representar la configuración de impresión del usuario actual:

Nota: si el usuario cancela el cuadro de diálogo Imprimir, no se llenarán las propiedades.

Una vez que el usuario hace clic en Aceptar en el cuadro de diálogo Imprimir, el reproductor comienza a enviar el trabajo de impresión a la cola del sistema operativo. Como el sistema operativo comienza a mostrar al usuario información sobre el progreso de la impresión, se debe llamar a PrintJob.addPage() y PrintJob.send() en cuanto sea posible para enviar páginas a la cola de impresión. Puede utilizar las propiedades de sólo lectura height, width y orientation que llena este método para dar formato a la impresión.

Para ver si el método devuelve true (cuando el usuario hace clic en Aceptar en el cuadro de diálogo Imprimir del sistema operativo) antes de realizar llamadas a PrintJob.addPage() y PrintJob.send():

  var my_pj:PrintJob = new PrintJob();
     if(my_pj.start()) {
       // las sentencias addPage() y send() van aquí 
     }
  

En la instancia del trabajo de impresión especificada, si alguno de los siguientes intervalos dura más de 15 segundos, la siguiente llamada a PrintJob.start() devolverá false:

• PrintJob.start() y el primer PrintJob.addPage()
• Un PrintJob.addPage() y el siguiente PrintJob.addPage()
• El último PrintJob.addPage() y PrintJob.send()

Véase también

1. Declare dos variables de tipo Sprite denominadas sheet1 y sheet2.
2. Llame a init(), lo que asignará una nueva instancia Sprite a sheet1 y sheet2 y, a continuación, llame a createSheet() utilizando argumentos diferentes.
3. createSheet() realiza lo siguiente:
   1. El objeto Sprite pasado se utiliza para dibujar un rectángulo con un fondo gris claro, un borde color negro de un píxel y unas dimensiones de 100 píxeles de ancho por 200 píxeles de alto en las coordenadas x = 0, y = 0.
   2. Se crea un objeto TextField denominado txt con las mismas dimensiones que Sprite, se define la propiedad wordWrap como true y se define la propiedad de texto como la cadena pasada como argumento a createSheet().
   3. Si el argumento Object pasado no tiene el valor null, cree una nueva instancia Sprite llamada img, que se utilizará para dibujar un rectángulo de color blanco con las propiedades de coordenadas y dimensiones del argumento Object pasado. El rectángulo blanco se añade a la lista de visualización del objeto Sprite utilizando addChild().
   4. Se añade TextField txt a la lista de visualización del objeto Sprite utilizando addChild().
4. De nuevo en el constructor, se llama al método de impresión activado (no convertido en comentario). Debido a que los métodos son muy similares, printOnePerPage() se describe a continuación.
5. printOnePerPage() realiza lo siguiente:
   1. Declarar un nuevo objeto PrintJob llamado pj y pagesToPrint como elemento uint.
   2. Abrir el cuadro de diálogo de impresión nativo del sistema operativo y esperar a que el usuario haga clic en Aceptar.
   3. Comprobar la orientación y, si Horizontal está seleccionado, generar un error y salir.
   4. Configurar la altura y anchura de la página para sheet1 y sheet2.
   5. Enviar sheet1 y sheet2 a la cola de impresión utilizando addPage().
   6. Si el número de páginas que se va a imprimir es > 0, imprimir todas las páginas en cola.
6. Se llama al método draw(), que modifica el tamaño de las dos propiedades Sprite para ajustarlas al escenario y cambia la posición de sheet2 para que se sitúe justo a la derecha de sheet1.

Nota: el constructor se ha configurado de modo que sea posible seleccionar, en función de las preferencias, uno de los tres métodos de impresión (una hoja por página, dos hojas por página o imprimir en la mitad superior de la página). Este ejemplo no funcionará correctamente a menos que se desactiven exactamente dos de los métodos de impresión mediante comentarios de código. El ejemplo se ha configurado de modo que se llame a printOnePerPage().

package {
    import flash.printing.PrintJob;
    import flash.printing.PrintJobOrientation;
    import flash.display.Stage;
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.geom.Rectangle;

    public class PrintJobExample extends Sprite {
        private var sheet1:Sprite;
        private var sheet2:Sprite;

        public function PrintJobExample() {
            init();
            printOnePerPage();
//            printTwoPerPage();
//            printTopHalf();
            draw();
        }

        private function init():void {
            sheet1 = new Sprite();
            createSheet(sheet1, "Once upon a time...", {x:10, y:50, width:80, height:130});

            sheet2 = new Sprite();
            createSheet(sheet2, "There was a great story to tell, and it ended quickly.\n\nThe end.", null);
        }

        private function createSheet(sheet:Sprite, str:String, imgValue:Object):void {
            sheet.graphics.beginFill(0xEEEEEE);
            sheet.graphics.lineStyle(1, 0x000000);
            sheet.graphics.drawRect(0, 0, 100, 200);
            sheet.graphics.endFill();

            var txt:TextField = new TextField();
            txt.height = 200;
            txt.width = 100;
            txt.wordWrap = true;
            txt.text = str;

            if(imgValue != null) {
                var img:Sprite = new Sprite();
                img.graphics.beginFill(0xFFFFFF);
                img.graphics.drawRect(imgValue.x, imgValue.y, imgValue.width, imgValue.height);
                img.graphics.endFill();
                sheet.addChild(img);
            }
            sheet.addChild(txt);
        }

        private function printOnePerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {
                if(pj.orientation == PrintJobOrientation.LANDSCAPE) {
                    throw new Error("Without embedding fonts you must print one sheet per page with an orientation of portrait.");
                }

                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth;

                try {
                    pj.addPage(sheet1);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                try {
                    pj.addPage(sheet2);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }

        private function printTwoPerPage():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print two sheets per page with an orientation of landscape.");
                }

                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets);
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }

        private function printTopHalf():void {
            var pj:PrintJob = new PrintJob();
            var pagesToPrint:uint = 0;
            if(pj.start()) {
                if(pj.orientation == PrintJobOrientation.PORTRAIT) {
                    throw new Error("Without embedding fonts you must print the top half with an orientation of landscape.");
                }

                sheet1.height = pj.pageHeight;
                sheet1.width = pj.pageWidth/2;
                sheet2.height = pj.pageHeight;
                sheet2.width = pj.pageWidth/2;

                var sheets:Sprite = new Sprite();
                sheets.addChild(sheet1);
                sheets.addChild(sheet2);
                sheets.getChildAt(1).x = sheets.getChildAt(0).width;
                try {
                    pj.addPage(sheets, new Rectangle(0, 0, sheets.width, sheets.height/2));
                    pagesToPrint++;
                }
                catch(e:Error) {
                    // do nothing
                }

                if(pagesToPrint > 0) {
                    pj.send();
                }
            }
        }


        private function draw():void {
            var sheetWidth:Number = this.stage.stageWidth/2;
            var sheetHeight:Number = this.stage.stageHeight;

            addChild(sheet1);
            sheet1.width = sheetWidth;
            sheet1.height = sheetHeight;

            addChild(sheet2);
            sheet2.width = sheetWidth;
            sheet2.height = sheetHeight;
            sheet2.x = sheet1.width;
        }
    }
}