El tipo de contenido MIME de cualquier dato POST.

Nota: los métodos FileReference.upload() y FileReference.download() no admiten el parámetro URLRequest.contentType.

Un objeto que contiene datos que se van a transmitir con la solicitud URL.

Esta propiedad se utiliza con la propiedad method. Si el valor de URLRequest.method es POST, los datos se transmiten con el objeto URLRequest y con el método HTTP POST.

Si el valor de URLRequest.method es GET, los datos definen variables que se enviarán con el objeto URLRequest y con el método HTTP GET.

La API URLRequest ofrece compatibilidad POST binaria y admite variables con codificación URL, así como compatibilidad con cadenas. El objeto de datos puede ser de tipo ByteArray, URLVariables o String.

El modo en que se utilicen los datos dependerá del tipo de objeto empleado:

• Si el objeto es ByteArray, los datos binarios del objeto ByteArray se utilizan como datos POST. En el caso de GET, no se admiten los datos de tipo ByteArray. Asimismo, los datos de tipo ByteArray no con compatibles con FileReference.upload() y FileReference.download().
• Si el objeto es URLVariables y el método es POST, las variables se codifican con formato x-www-form-urlencoded y la cadena resultante se utiliza como datos POST. Una excepción es la llamada a FileReference.upload(), en la que las variables se envían como campos separados en un envío multipart/form-data.
• Si el objeto es URLVariables y el método GET, el objeto URLVariables define las variables que se enviarán con el objeto URLRequest.
• En caso contrario, el objeto se convierte en una cadena y ésta se utiliza como datos POST o GET.

Los datos no se envían hasta que un método (por ejemplo, navigateToURL() o FileReference.upload()) utilice el objeto URLRequest.

Véase también

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

Controla si el método de envío HTTP es una operación GET o POST. Los valores válidos son URLRequestMethod.GET o URLRequestMethod.POST.

El valor predeterminado es URLRequestMethod.GET.

Véase también

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);

            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;

            navigateToURL(request);
        }
    }
}

La matriz de encabezados de solicitud HTTP que se añadirán a la solicitud HTTP. La matriz está formada por objetos URLRequestHeader. Cada objeto de la matriz debe ser un objeto URLRequestHeader que contenga una cadena de nombre y de valor, del modo siguiente:

  var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));
  

Flash Player impone ciertas restricciones a los encabezados de solicitud ; para más información, consulte la descripción de la clase URLRequestHeader.

Los métodos FileReference.upload() y FileReference.download() no admiten el parámetro URLRequest.requestHeaders.

Véase también

La URL que se va a solicitar. De forma predeterminada, la URL debe encontrarse exactamente en el mismo dominio que el archivo SWF que realiza la llamada, incluidos los subdominios. Por ejemplo, los archivos SWF de www.adobe.com y store.adobe.com se encuentran en dominios distintos. Para cargar datos desde un dominio distinto, coloque un archivo de política entre distintos dominios en el servidor que aloja el archivo SWF. Para obtener más información consulte la documentación sobre seguridad descrita en la clase URLRequest.

Nota: Flash Player Update 3 y las versiones posteriores admiten IPv6 (versión 6 del Protocolo de Internet). IPv6 es una versión del Protocolo de Internet que admite direcciones de 128 bits (una mejora con respecto al protocolo anterior IPv4 que admite direcciones de 32 bits). Es posible que tenga que activar IPv6 en sus interfaces de red. Para más información, consulte la Ayuda del sistema operativo que aloja los datos. Si se admite IPv6 en el sistema de host, puede especificar direcciones literales numéricas de IPv6 en URL entre corchetes ([]), como se muestra a continuación:

     rtmp://[2001:db8:ccc3:ffff:0:444d:555e:666f]:1935/test
     

Crea un objeto URLRequest. Si System.useCodePage es true, la solicitud se codifica con la página de códigos del sistema y no con Unicode. Si System.useCodePage es false, la solicitud se codifica con Unicode, y no con la página de códigos del sistema.

Véase también

Para ejecutar el ejemplo, coloque un archivo llamado XMLFile.xml en el mismo directorio que el archivo SWF.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {

        public function URLRequestExample() {
            var loader:URLLoader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}