Indica el número de bytes cargados hasta ese momento durante la operación de carga.

Indica el número total de bytes de los datos descargados. Esta propiedad contiene 0 si la operación de carga está en curso y se llena cuando la operación ha finalizado. Asimismo, un encabezado Content-Length que falte dará como resultado que bytesTotal sea indeterminado.

Los datos recibidos de la operación de carga. Esta propiedad se llena únicamente al finalizar la operación de carga. El formato de los datos depende del establecimiento de la propiedad dataFormat:

Si la propiedad dataFormat es URLLoaderDataFormat.TEXT, los datos recibidos son una cadena con el texto del archivo cargado.

Si la propiedad dataFormat es URLLoaderDataFormat.BINARY, los datos recibidos son un objeto ByteArray con los datos binarios sin formato.

Si la propiedad dataFormat es URLLoaderDataFormat.VARIABLES, los datos recibidos son un objeto URLVariables con las variables con codificación URL.

Véase también

Controla si los datos cargados se reciben como texto (URLLoaderDataFormat.TEXT), como datos binarios sin formato (URLLoaderDataFormat.BINARY) o como variables con codificación URL (URLLoaderDataFormat.VARIABLES).

Si el valor de la propiedad dataFormat es URLLoaderDataFormat.TEXT, los datos recibidos son una cadena con el texto del archivo cargado.

Si el valor de la propiedad dataFormat es URLLoaderDataFormat.BINARY, los datos recibidos son un objeto ByteArray con los datos binarios sin formato.

Si el valor de la propiedad dataFormat es URLLoaderDataFormat.VARIABLES, los datos recibidos son un objeto URLVariables con las variables con codificación URL.

El valor predeterminado es URLLoaderDataFormat.TEXT.

Véase también

Crea un objeto URLLoader.

Véase también

Cierra la operación de carga en curso. Se detendrá inmediatamente cualquier operación de carga en curso. Si no se transmite ninguna URL en ese momento, se emitirá un error de transmisión no válida.

Envía y carga datos desde la URL especificada. Los datos se pueden recibir como texto, como datos binarios sin formato o como variables con codificación, en función del valor establecido para la propiedad dataFormat. Tenga en cuenta que el valor predeterminado de la propiedad dataFormat es text. Si quiere enviar datos a la URL especificada, puede establecer la propiedad data en el objeto URLRequest.

Nota: si un archivo que se está cargando contiene caracteres no ASCII (como ocurre en muchos idiomas, no así en inglés), se recomienda que guarde el archivo con codificación UTF-8 o UTF-16, en lugar de utilizar un formato no Unicode, como ASCII.

Cuando utilice este método, tenga en cuenta el modelo de seguridad de Flash Player:

En Flash Player 9 y versiones posteriores, se puede impedir que un archivo SWF utilice este método si define el parámetro allowNetworking de las etiquetas object y embed de la página HTML que aloja el contenido SWF.

Flash Player 8 y versiones anteriores:

• No se permite la carga de datos si el archivo SWF que realiza la llamada se encuentra en el entorno limitado local con el sistema de archivos y el recurso se encuentra en un entorno limitado de red.
• Tampoco se permite la carga de datos si el archivo SWF que realiza la llamada se encuentra en un entorno limitado de red y el recurso de destino es local.

Para Flash Player 7 y versiones posteriores, los sitios Web pueden permitir el acceso de distintos dominios a un recurso mediante un archivo de política de varios dominios. En archivos SWF de cualquier versión que se ejecuten en Flash Player 7 y posterior, url debe estar exactamente en el mismo dominio. Por ejemplo, un archivo SWF de www.adobe.com puede cargar datos únicamente de orígenes que estén también en www.adobe.com.

Para más información, consulte las siguientes secciones:

• El capítulo de seguridad de la guía Programación con ActionScript 3.0 y los últimos comentarios realizados en LiveDocs.
• El documento técnico sobre la seguridad de Flash Player 9.

En archivos SWF que se ejecuten en una versión del reproductor anterior a Flash Player 7, url debe estar en el mismo superdominio que el archivo SWF que emite esta llamada. El superdominio se obtiene al eliminar el componente más a la izquierda de la URL de un archivo. Por ejemplo, un archivo SWF situado en www.adobe.com puede cargar datos de fuentes situadas en store.adobe.com porque ambos archivos se encuentran en el mismo superdominio de adobe.com.

Parámetros

Véase también

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.xml.*;
    import flash.events.IOErrorEvent;

    public class URLLoader_loadExample extends Sprite {
        private var xmlTextField:TextField = new TextField();
        private var externalXML:XML;
        private var loader:URLLoader;

        public function URLLoader_loadExample() {
            var request:URLRequest = new URLRequest("xmlFile.xml");

            loader = new URLLoader();

            try {
                loader.load(request);
            }
            catch (error:SecurityError)
            {
                trace("A SecurityError has occurred.");
            }

             loader.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
            loader.addEventListener(Event.COMPLETE, loaderCompleteHandler);

            xmlTextField.x = 10;
            xmlTextField.y = 10;
            xmlTextField.background = true;
            xmlTextField.autoSize = TextFieldAutoSize.LEFT;

            addChild(xmlTextField);
        }

        private function loaderCompleteHandler(event:Event):void {

                try {
                    externalXML = new XML(loader.data);
                    readNodes(externalXML);
                } catch (e:TypeError) {
                    trace("Could not parse the XML file.");
                }
        }

        private function readNodes(node:XML):void {

                for each (var element:XML in node.elements()) {
                    xmlTextField.appendText(element.attributes()[0] + "\n");

                    readNodes(element);
                }
        }

        private function errorHandler(e:IOErrorEvent):void {
            xmlTextField.text = "Had problem loading the XML File.";
        }
    }
}

Se distribuye tras decodificar y colocar todos los datos recibidos en la propiedad data del objeto URLLoader. Es posible acceder a los datos recibidos una vez distribuido este evento.

Este evento tiene las propiedades siguientes:

Véase también

Se distribuye si una llamada a URLLoader.load() intenta acceder a datos sobre HTTP y si el entorno de Flash Player actual puede detectar y devolver el código de estado para la solicitud. (Es posible que algunos entornos de navegador no proporcionen esta información.) Tenga en cuenta que se enviará el evento httpStatus (si existe) antes que (y además de) cualquier evento complete o error.

Este evento tiene las propiedades siguientes:

Véase también

Se distribuye si el resultado de una llamada a URLLoader.load() es un error grave que hace que la descarga finalice.

Este evento tiene las propiedades siguientes:

Véase también

Se distribuye cuando se inicia la operación de descarga tras una llamada al método URLLoader.load().

Este evento tiene las propiedades siguientes:

Véase también

Se distribuye al recibirse datos mientras progresa una operación de descarga.

Tenga en cuenta que con un objeto URLLoader no es posible acceder a los datos hasta que no se reciben por completo. Por tanto, el evento de progreso únicamente sirve de notificación para saber qué grado de progreso ha alcanzado la descarga. Para acceder a los datos antes de que se descarguen por completo, utilice un objeto URLStream.

Este evento tiene las propiedades siguientes:

Véase también

Se distribuye si se intenta llamar a URLLoader.load() para cargar datos de un servidor situado fuera del entorno limitado de seguridad.

Este evento tiene las propiedades siguientes:

Véase también

Nota: para ejecutar este ejemplo, coloque un archivo llamado urlLoaderExample.txt en el mismo directorio que el archivo SWF. Dicho archivo debe contener únicamente la siguiente línea de texto: answer=42&question=unknown

El código de ejemplo cumple las siguientes funciones:

1. La función constructora crea una instancia de URLLoader llamada loader y una instancia de URLRequest request, que contiene la ubicación y el nombre del archivo que se va a cargar.
2. El objeto loader se transfiere al método configureListeners(), que añade detectores para cada uno de los eventos URLLoader admitidos.
3. Posteriormente, el objeto request se transfiere a loader.load(), que carga el archivo de texto.
4. Cuando URLLoader finaliza la carga del archivo de texto, se activa el evento Event.COMPLETE, que activa el método completeHandler(). El método completeHandler() crea variables de URLVariables a partir del texto cargado desde el archivo. El objeto URLVariables convierte los pares nombre/valor con codificación URL en propiedades de ActionScript para facilitar la manipulación de los datos cargados.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLLoaderExample extends Sprite {
        public function URLLoaderExample() {
            var loader:URLLoader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("urlLoaderExample.txt");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);

            var vars:URLVariables = new URLVariables(loader.data);
            trace("The answer is " + vars.answer);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}