La fecha de creación del archivo en el disco local. Si aún no se ha llenado el objeto FileReference, una llamada para obtener el valor de esta propiedad devolverá null.

Véase también

El tipo de creador del archivo en Macintosh. En Windows, esta propiedad es null. Si aún no se ha llenado el objeto FileReference, una llamada para obtener el valor de esta propiedad devolverá null.

Véase también

La última fecha de modificación del archivo en el disco local. Si aún no se ha llenado el objeto FileReference, una llamada para obtener el valor de esta propiedad devolverá null.

Véase también

El nombre del archivo en el disco local. Si aún no se ha llenado el objeto FileReference, una llamada para obtener el valor de esta propiedad devolverá null.

Al llamar al método browse() se llenan todas las propiedades de un objeto FileReference. A diferencia de otras propiedades FileReference, si llama al método download(), la propiedad name se llena cuando se distribuye el evento select.

Véase también

El tamaño del archivo en el disco local, expresado en bytes. Si size es 0, se emitirá una excepción.

Véase también

El tipo de archivo. En Windows esta propiedad es la extensión de archivo. En Macintosh, esta propiedad es el tipo de archivo de cuatro caracteres. Si aún no se ha llenado el objeto FileReference, una llamada para obtener el valor de esta propiedad devolverá null.

Crea un nuevo objeto FileReference. Cuando está lleno, un objeto FileReference representa un archivo en el disco local del usuario.

Véase también

Muestra un cuadro de diálogo de búsqueda de archivos en el que el usuario puede seleccionar un archivo para la carga. El cuadro de diálogo depende del sistema operativo del usuario. El usuario puede seleccionar un archivo del equipo local o de otros sistemas, por ejemplo, a través de una ruta UNC en Windows.

Cuando se llama a este método y el usuario selecciona correctamente un archivo, las propiedades de este objeto FileReference se llenan con las propiedades de dicho archivo. Posteriormente, cada vez que se llama a al método FileReference.browse(), las propiedades del objeto FileReference se restablecen según el archivo seleccionado por el usuario en el cuadro de diálogo. Sólo se puede realizar una sesión browse() o download() cada vez (porque no se pueden invocar varios cuadros de diálogo de forma simultánea).

Con el parámetro typeFilter, se puede determinar qué archivos se mostrarán en el cuadro de diálogo.

Parámetros

Véase también

Cancela la operación de carga o descarga en curso en este objeto FileReference. Al llamar a este método no se distribuye el evento cancel; dicho evento se distribuye sólo cuando el usuario cancela la operación cerrando el cuadro de diálogo de carga o de descarga de archivos.

Abre un cuadro de diálogo que permite al usuario descargar un archivo desde un servidor remoto. Aunque Flash Player no tiene restricciones con respecto al tamaño de los archivos que pueden cargarse y descargarse, oficialmente el reproductor admite cargas y descargas de un máximo de 100 MB.

Este método download() abre en primer lugar un cuadro de diálogo del sistema operativo que pide al usuario que introduzca un nombre de archivo y seleccione una ubicación en el equipo local para guardar el archivo. Cuando el usuario selecciona una ubicación y confirma la operación de descarga (por ejemplo, haciendo clic en Guardar), comienza la descarga del servidor remoto. Los detectores reciben eventos para indicar el progreso, el éxito o un error en la descarga. Para comprobar el estado del cuadro de diálogo y la operación de descarga después de llamar a download(), el código ActionScript deberá detectar eventos como cancel, open, progress y complete.

Las funciones FileReference.upload() y FileReference.download() no son bloqueantes. Estas funciones se devuelven después de la llamada y antes de que finalice la transmisión del archivo. Además, si el objeto FileReference va más allá del ámbito, se cancelará cualquier carga o descarga que no haya finalizado en dicho objeto. Es importante que el objeto FileReference permanezca dentro del ámbito durante todo el tiempo de carga y descarga.

Una vez descargado el archivo correctamente, las propiedades del objeto FileReference se llenan con las propiedades del archivo local. Se distribuye el evento complete si la descarga se realiza correctamente.

Sólo se puede realizar una sesión browse() o download() cada vez (porque no se pueden invocar varios cuadros de diálogo de forma simultánea).

Este método admite la descarga de cualquier tipo de archivo, con HTTP o HTTPS.

Nota: si el servidor requiere autenticación del usuario, sólo los archivos que se ejecutan en un navegador, es decir que utilizan el plug-in de navegador o controles ActiveX, pueden mostrar un cuadro de diálogo para pedir al usuario un nombre de usuario y una contraseña para la autenticación, y sólo para las descargas. La transferencia de archivos fallará en las cargas que utilicen el plug-in o el control ActiveX, y en las cargas y descargas que utilicen el reproductor autónomo o externo.

Cuando utilice este método, tenga en cuenta el modelo de seguridad de Flash Player:

• No se admiten operaciones de carga si el archivo SWF que realiza la llamada está en un entorno limitado local que no es de confianza.
• El comportamiento predeterminado es denegar el acceso entre entornos limitados. Un sitio Web puede activar el acceso a un recurso utilizando un archivo de política de varios dominios.
• Asimismo, se puede impedir que un archivo SWF utilice este método si define el parámetro allowNetworking de las etiquetas object y embed de la página HTML que aloja el contenido SWF.

Para más información, consulte las siguientes secciones:

• El capítulo de seguridad de la guía Programación con ActionScript 3.0 y los últimos comentarios realizados en LiveDocs.
• El documento técnico sobre la seguridad de Flash Player 9.

Parámetros

Véase también

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Inicia la carga de un archivo seleccionado por un usuario en un servidor remoto. Aunque Flash Player no tiene restricciones con respecto al tamaño de los archivos que pueden cargarse y descargarse, oficialmente el reproductor admite cargas y descargas de un máximo de 100 MB. Se debe llamar al método FileReference.browse() o FileReferenceList.browse() para poder llamar a este método.

Los detectores reciben eventos para indicar el progreso, éxito o error en la carga. Aunque se puede utilizar el objeto FileReferenceList para que los usuarios puedan seleccionar varios archivos para la carga, éstos se deben cargar de uno en uno; para ello, itere por la matriz FileReferenceList.fileList de objetos FileReference.

Las funciones FileReference.upload() y FileReference.download() no son bloqueantes. Estas funciones se devuelven después de la llamada y antes de que finalice la transmisión del archivo. Además, si el objeto FileReference va más allá del ámbito, se cancelará cualquier carga o descarga que no haya finalizado en dicho objeto. Es importante que el objeto FileReference permanezca dentro del ámbito durante todo el tiempo de carga y descarga.

El archivo se carga en la URL pasada en el parámetro url. La URL debe ser un script de servidor configurado para aceptar cargas. Flash Player carga archivos mediante el método HTTP POST. El script de servidor que gestiona la carga espera una petición POST con los siguientes elementos:

• Content-Type de multipart/form-data
• Un elemento Content-Disposition con un atributo name establecido de forma predeterminada como "Filedata" y un atributo filename establecido como el nombre del archivo original.
• El contenido binario del archivo.

Para consultar una solicitud POST de ejemplo, consulte la descripción del parámetro uploadDataFieldName. Se pueden enviar parámetros POST o GET al servidor con el método upload(); consulte la descripción del parámetro request.

Si el parámetro testUpload es true, y el tamaño del archivo que se va a cargar supera los 10 KB, Flash Player (en Windows) primero envía una operación POST de carga de prueba sin contenido antes de cargar el archivo real. De esta forma, se verifica si la transmisión será correcta. A continuación, Flash Player envía una segunda operación POST que incluye el contenido del archivo real. En el caso de archivos con tamaño inferior a 10 KB, Flash Player lleva a cabo una sola operación POST de carga con el contenido del archivo real. En Macintosh, Flash Player no lleva a cabo ninguna operación POST de carga de prueba.

Nota: si el servidor requiere autenticación del usuario, sólo los archivos que se ejecutan en un navegador, es decir que utilizan el plug-in de navegador o controles ActiveX, pueden mostrar un cuadro de diálogo para pedir al usuario un nombre de usuario y una contraseña para la autenticación, y sólo para las descargas. La transferencia de archivos fallará en las cargas que utilicen el plug-in o el control ActiveX, y en las cargas y descargas que utilicen el reproductor autónomo o externo.

Cuando utilice este método, tenga en cuenta las restricciones siguientes para el modelo de seguridad de Flash Player:

• No se admiten operaciones de carga si el archivo SWF que realiza la llamada está en un entorno limitado local que no es de confianza.
• El comportamiento predeterminado es denegar el acceso entre entornos limitados. Un sitio Web puede activar el acceso a un recurso utilizando un archivo de política de varios dominios.
• Asimismo, se puede impedir que un archivo SWF utilice este método si define el parámetro allowNetworking de las etiquetas object y embed de la página HTML que aloja el contenido SWF.

Para más información, consulte las siguientes secciones:

• El capítulo de seguridad de la guía Programación con ActionScript 3.0 y los últimos comentarios realizados en LiveDocs.
• El documento técnico sobre la seguridad de Flash Player 9.

Parámetros

 Content-Type: multipart/form-data; boundary=AaB03x --AaB03x Content-Disposition: form-data; name="Filedata"; filename="example.jpg" Content-Type: application/octet-stream... contents of example.jpg... --AaB03x--
 

Véase también

Se distribuye cuando el usuario cancela la carga o descarga de un archivo mediante el cuadro de diálogo de búsqueda de archivos. Flash Player no distribuye este evento si el usuario cancela una carga o descarga mediante otros métodos (cerrando el navegador o la aplicación actual).

Este evento tiene las propiedades siguientes:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_cancel extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_cancel() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(Event.CANCEL, cancelHandler);
            file.download(downloadURL, fileName);
        }
        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }
    }
}

Se distribuye cuando finaliza la descarga o cuando la carga genera un código de estado HTTP de 200. En el caso de la descarga de archivos, se distribuye cuando Flash Player finaliza la descarga del archivo completo en el disco. En el caso de la carga de archivos, este evento se distribuye después de que Flash Player haya recibido un código de estado HTTP de 200 desde el servidor que recibe la transmisión.

Este evento tiene las propiedades siguientes:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_complete extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_complete() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Véase también

Se distribuye cuando la carga falla y hay un código de estado HTTP disponible para describir el error. El evento httpStatus siempre se distribuye, seguido de un evento ioError.

El evento httpStatus se distribuye sólo cuando se producen errores de carga. Debido a la forma en que Flash Player se basa en la pila del navegador durante la descarga de archivos, este evento no es aplicable a fallos de descarga. Si falla una descarga debido a un error HTTP, el error se transmite como error de E/S.

Este evento tiene las propiedades siguientes:

Véase también

Se distribuye cuando falla la carga o la descarga. La transferencia de archivos puede fallar por uno de los siguientes motivos:

• Se produce un error de entrada/salida durante la lectura, escritura o transmisión del archivo.
• El SWF intenta cargar un archivo en un servidor que requiere autenticación, como un nombre de usuario y una contraseña. Durante la carga, Flash Player no proporciona un medio para que los usuarios introduzcan contraseñas. Si un SWF intenta cargar un archivo en un servidor que requiere autenticación, la carga produce un fallo.
• El archivo SWF intenta descargar un archivo desde un servidor que requiere autenticación, en el reproductor autónomo o externo. Durante la descarga, los reproductores autónomos y externos no proporcionan un medio para que los usuarios introduzcan contraseñas. Si un archivo SWF en estos reproductores intenta descargar un archivo desde un servidor que requiere autenticación, la descarga produce un error. La descarga de archivos sólo podrá realizarse correctamente en el control ActiveX y los reproductores plug-in del navegador.
• El valor transferido al parámetro url en el método upload() contiene un protocolo no válido. Los protocolos válidos son HTTP y HTTPS.

Importante: sólo las aplicaciones Flash que se ejecutan en un navegador, es decir, que emplean el plug-in de navegador o un control ActiveX, pueden mostrar un cuadro de diálogo para pedir al usuario que introduzca un nombre de usuario y una contraseña para la autenticación y, además, sólo para descargas. La transferencia de archivos fallará en las cargas que utilicen el plug-in o el control ActiveX, y en las cargas y descargas que utilicen el reproductor autónomo o externo.

Este evento tiene las propiedades siguientes:

Véase también

Se distribuye cuando se inicia una operación de carga o descarga.

Este evento tiene las propiedades siguientes:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.net.FileFilter;

    public class FileReference_download extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_download() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            configureListeners(file);
            file.download(downloadURL, fileName);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + downloadURL.url);
        }
    }
}

Véase también

Se distribuye periódicamente durante la operación de carga o descarga de archivos. El evento progress se distribuye mientras Flash Player transmite bytes a un servidor y se distribuye de forma periódica durante la transmisión, aunque no finalice correctamente. Para determinar si la transmisión realmente es correcta y completa, detecte el evento complete.

En algunos casos, no se reciben eventos progress. Por ejemplo, si el archivo que se transmite es muy pequeño o si la carga o la descarga se producen muy rápido, es posible que no se distribuya un evento progress.

El progreso de carga de archivos no puede determinarse en plataformas Macintosh anteriores a OS X 10.3. Durante la operación de carga, se llama al evento progress, pero el valor de la propiedad bytesLoaded del evento de progreso es -1, lo que indica que no es posible determinar el progreso.

Este evento tiene las propiedades siguientes:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_progress extends Sprite {
        private var downloadURL:URLRequest;
        private var fileName:String = "SomeFile.pdf";
        private var file:FileReference;

        public function FileReference_event_progress() {
            downloadURL = new URLRequest();
            downloadURL.url = "http://www.[yourDomain].com/SomeFile.pdf";
            file = new FileReference();
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.download(downloadURL, fileName);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Véase también

Se distribuye cuando una llamada al método FileReference.upload() o FileReference.download() intenta cargar un archivo en un servidor u obtener un archivo de un servidor que se encuentra fuera del entorno limitado de seguridad del elemento que realiza la llamada. El valor de la propiedad de texto que describe el error específico ocurrido suele ser "securitySandboxError". Es posible que el archivo SWF que realiza la llamada haya intentado acceder a un archivo SWF fuera de su dominio y no tenga permiso para hacerlo. Puede intentar solucionar este error utilizando un archivo de política de varios dominios.

Este evento tiene las propiedades siguientes:

Véase también

Se distribuye cuando el usuario selecciona un archivo para la carga o descarga en el cuadro de diálogo de búsqueda de archivos. (Este cuadro de diálogo se abre cuando llama a los métodos FileReference.browse(), FileReferenceList.browse() o FileReference.download().) Cuando el usuario selecciona un archivo y confirma la operación (por ejemplo, haciendo clic en Aceptar), se llenan las propiedades del objeto FileReference.

El evento select se comporta de forma algo diferente según el método que lo invoque. Cuando se distribuye el evento select después de una llamada a browse(), Flash Player puede leer todas las propiedades del objeto FileReference, ya que el archivo seleccionado por el usuario está en el sistema de archivos local. Cuando se distribuye el evento select después de una llamada a download(), Flash Player sólo puede leer la propiedad name, debido a que el archivo no se ha descargado todavía en el sistema local de archivos en el momento de distribuir el evento select. Una vez que se haya descargado el archivo y se haya distribuido el evento complete, Flash Player puede leer todas las demás propiedades del objeto FileReference.

Este evento tiene las propiedades siguientes:

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReference_event_select extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReference_event_select() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            file.addEventListener(Event.SELECT, selectHandler);
            file.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            file.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            file.addEventListener(Event.COMPLETE, completeHandler);
            file.browse();
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler: name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }
    }
}

Se distribuye cuando se han recibido datos del servidor tras una carga correcta. Este evento no se distribuye si no se devuelven datos desde el servidor.

Este evento tiene las propiedades siguientes:

Nota: para ejecutar este ejemplo, cambie la propiedad uploadURL.url para que señale a una URL real, y no a la URL ficticia del ejemplo. La URL debe señalar a un archivo llamado yourUploadHandlerScript.cfm en el directorio raíz Web de la URL especificada. Según la configuración, también podría ser necesario compilar el archivo SWF con la opción Seguridad de reproducción local establecida como Acceder sólo a la red o actualizar la configuración de seguridad de Flash Player para que permita el acceso de este archivo a la red.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.FileFilter;
    import flash.net.FileReference;
    import flash.net.URLRequest;

    public class FileReferenceExample extends Sprite {
        private var uploadURL:URLRequest;
        private var file:FileReference;

        public function FileReferenceExample() {
            uploadURL = new URLRequest();
            uploadURL.url = "http://www.[yourDomain].com/yourUploadHandlerScript.cfm";
            file = new FileReference();
            configureListeners(file);
            file.browse(getTypes());
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CANCEL, cancelHandler);
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(Event.SELECT, selectHandler);
            dispatcher.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA,uploadCompleteDataHandler);
        }

        private function getTypes():Array {
            var allTypes:Array = new Array(getImageTypeFilter(), getTextTypeFilter());
            return allTypes;
        }

        private function getImageTypeFilter():FileFilter {
            return new FileFilter("Images (*.jpg, *.jpeg, *.gif, *.png)", "*.jpg;*.jpeg;*.gif;*.png");
        }

        private function getTextTypeFilter():FileFilter {
            return new FileFilter("Text Files (*.txt, *.rtf)", "*.txt;*.rtf");
        }

        private function cancelHandler(event:Event):void {
            trace("cancelHandler: " + event);
        }

        private function completeHandler(event:Event):void {
            trace("completeHandler: " + event);
        }

        private function uploadCompleteDataHandler(event:Event):void {
            trace("uploadCompleteData: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            var file:FileReference = FileReference(event.target);
            trace("progressHandler name=" + file.name + " bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function selectHandler(event:Event):void {
            var file:FileReference = FileReference(event.target);
            trace("selectHandler: name=" + file.name + " URL=" + uploadURL.url);
            file.upload(uploadURL);
        }
    }
}