Objeto ColorTransform que contiene valores que ajustan globalmente los colores en el objeto de visualización.

Véase también

Objeto ColorTransform que representa las transformaciones de color aplicadas al objeto de visualización y todas las de sus objetos principales hasta el nivel de la raíz, combinadas. Si se han aplicado transformaciones de color diferentes en niveles distintos, para esta propiedad se concatenarán todas en un objeto ColorTransform.

Véase también

Objeto Matrix que representa las matrices de transformación aplicadas al objeto de visualización y todas las de sus objetos principales hasta el nivel de la raíz, combinadas. Si se han aplicado matrices de transformación diferentes en niveles distintos, para esta propiedad se concatenarán todas en un objeto Matrix.

Objeto Matrix que contiene valores que afectan al ajuste de tamaño, rotación y conversión del objeto de visualización.

Véase también

Un objeto Rectangle que define el rectángulo de delimitación del objeto de visualización en el escenario.

1. El constructor TransformExample() crea un nuevo objeto sprite target.
2. El constructor TransformExample() llama al método draw(), que dibuja un cuadrado con degradado en el elemento sprite.
3. El constructor TransformExample() añade un detector de eventos click para el elemento sprite, que se controla con el método clickHandler().
4. El método clickHandler() crea un nuevo objeto Matrix, skewMatrix, que se define para aplicar un efecto de sesgo. Otro objeto Matrix, tempMatrix, se asigna a la matriz de transformación actual del elemento sprite y, a continuación, se combina con skewMatrix utilizando el método concat(). Esta matriz se asigna a la propiedad transform.matrix asignada del elemento sprite cuadrado. Cada vez que el usuario hace clic en el cuadrado, la llamada a clickHandler() modifica la forma del cuadrado, sesgándola.
5. Asimismo, el método clickHandler() crea un nuevo objeto ColorTransform. La propiedad redOffset del nuevo objeto ColorTransform se define con el valor actual de redOffset y se incrementa en 25. Del mismo modo, la propiedad blueOffset se reduce en 25. Con cada clic, los colores del elemento sprite cambian.

package {
    import flash.display.Sprite;
    import flash.display.GradientType;
    import flash.geom.Matrix;
    import flash.geom.ColorTransform;
    import flash.events.MouseEvent;

    public class TransformExample extends Sprite {
        public function TransformExample() {
            var target:Sprite = new Sprite();
            draw(target);
            addChild(target);
            target.useHandCursor = true;
            target.buttonMode = true;
            target.addEventListener(MouseEvent.CLICK, clickHandler)
        }
        public function draw(sprite:Sprite):void {
            var red:uint = 0xFF0000;
            var green:uint = 0x00FF00;
            var blue:uint = 0x0000FF;
            var size:Number = 100;
            sprite.graphics.beginGradientFill(GradientType.LINEAR, [red, blue, green], [1, 0.5, 1], [0, 200, 255]);
            sprite.graphics.drawRect(0, 0, 100, 100);
        }
        public function clickHandler(event:MouseEvent):void {
            var skewMatrix:Matrix = new Matrix();
            skewMatrix.c = 0.25;
            var tempMatrix:Matrix = this.transform.matrix;
            tempMatrix.concat(skewMatrix);
            this.transform.matrix = tempMatrix;

            var rOffset:Number = this.transform.colorTransform.redOffset + 25;
            var bOffset:Number = this.transform.colorTransform.blueOffset - 25;
            this.transform.colorTransform = new ColorTransform(1, 1, 1, 1, rOffset, 0, bOffset, 0);
        }
    }
}