Paqueteflash.filters
Clasepublic class BitmapFilter
HerenciaBitmapFilter Inheritance Object
Subclases BevelFilter, BlurFilter, ColorMatrixFilter, ConvolutionFilter, DisplacementMapFilter, DropShadowFilter, GlowFilter, GradientBevelFilter, GradientGlowFilter

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

La clase BitmapFilter es la clase básica para todos los efectos de filtro de imagen.

Las clases BevelFilter, BlurFilter, ColorMatrixFilter, ConvolutionFilter, DisplacementMapFilter, DropShadowFilter, GlowFilter, GradientBevelFilter y GradientGlowFilter amplían la clase BitmapFilter. Puede aplicar estos efectos de filtro a cualquier objeto de visualización.

No puede ampliar BitmapFilter ni crear instancias directamente.

Ver los ejemplos


Propiedades públicas
 PropiedadDefinido por
 Inheritedconstructor : Object
Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada.
Object
 Inheritedprototype : Object
[static] Una referencia al objeto prototipo de una clase u objeto de función.
Object
Métodos públicos
 MétodoDefinido por
  
clone():BitmapFilter
Devuelve un objeto BitmapFilter que es una copia exacta del objeto BitmapFilter original.
BitmapFilter
 Inherited
hasOwnProperty(name:String):Boolean
Indica si un objeto tiene definida una propiedad especificada.
Object
 Inherited
isPrototypeOf(theClass:Object):Boolean
Indica si hay una instancia de la clase Object en la cadena de prototipo del objeto especificado como parámetro.
Object
 Inherited
propertyIsEnumerable(name:String):Boolean
Indica si existe la propiedad especificada y si es enumerable.
Object
 Inherited
setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void
Establece la disponibilidad de una propiedad dinámica para operaciones de bucle.
Object
 Inherited
toString():String
Devuelve la representación de cadena del objeto especificado.
Object
 Inherited
valueOf():Object
Devuelve el valor simple del objeto especificado.
Object
Información sobre métodos
clone()método
public function clone():BitmapFilter

Versión del lenguaje: ActionScript 3.0
Versión del reproductor: Flash Player 9

Devuelve un objeto BitmapFilter que es una copia exacta del objeto BitmapFilter original.

Valor devuelto
BitmapFilter — Un objeto BitmapFilter.
Ejemplos Cómo utilizar los ejemplos
BitmapFilterExample.as

En el ejemplo siguiente, se muestra cómo se pueden aplicar diversos filtros a un objeto DisplayObject determinado y realizar un seguimiento con la propiedad filters. 
package {
    import flash.display.Sprite;
    import flash.filters.*;

    public class BitmapFilterExample extends Sprite {
        public function BitmapFilterExample() {
            trace(this.filters.length);             // 0

            var tmpFilters:Array = this.filters;
            tmpFilters.push(FilterFactory.createFilter(FilterFactory.BEVEL_FILTER));
            tmpFilters.push(FilterFactory.createFilter(FilterFactory.GLOW_FILTER));
            this.filters = tmpFilters;

            trace(this.filters.length);             // 2
            trace(this.filters[0] is BitmapFilter); // true
            trace(this.filters[0] is BevelFilter);  // true
            trace(this.filters[1] is BitmapFilter); // true
            trace(this.filters[1] is GlowFilter);   // true
        }
    }
}

import flash.filters.*;
class FilterFactory {
    public static var BEVEL_FILTER:String = "BevelFilter";
    public static var BevelFilterConstructor:Class = BevelFilter;

    public static var BLUR_FILTER:String = "BlurFilter";
    public static var BlurFilterConstructor:Class = BlurFilter;

    public static var COLOR_MATRIX_FILTER:String = "ColorMatrixFilter";
    public static var ColorMatrixFilterConstructor:Class = ColorMatrixFilter;

    public static var CONVOLUTION_FILTER:String = "ConvolutionFilter";
    public static var ConvolutionFilterConstructor:Class = ConvolutionFilter;

    public static var DISPLACEMENT_MAP_FILTER:String = "DisplacementMapFilter";
    public static var DisplacementMapFilterConstructor:Class = DisplacementMapFilter;

    public static var DROP_SHADOW_FILTER:String = "DropShadowFilter";
    public static var DropShadowFilterConstructor:Class = DropShadowFilter;

    public static var GLOW_FILTER:String = "GlowFilter";
    public static var GlowFilterConstructor:Class = GlowFilter;

    public static var GRADIENT_BEVEL_FILTER:String = "GradientBevelFilter";
    public static var GradientBevelFilterConstructor:Class = GradientBevelFilter;

    public static var GRADIENT_GLOW_FILTER:String = "GradientGlowFilter";
    public static var GradientGlowFilterConstructor:Class = GradientGlowFilter;

    public static function createFilter(type:String):BitmapFilter {
        return new FilterFactory[type + "Constructor"]();
    }
}



© 2004-2007 Adobe Systems Incorporated. Todos los derechos reservados.
Fri Oct 12 2007, 2:30 AM GMT-07:00

 

Enviarme un mensaje de correo electrónico cuando se añadan comentarios a esta página | Informe de comentarios

Página actual: http://livedocs.adobe.com/flash/9.0_es/ActionScriptLangRefV3/flash/filters/BitmapFilter.html