Un objeto con propiedades que describen el estado del objeto o la situación de error.

El objeto de información podría tener una propiedad code que contenga una cadena para representar un evento concreto o una propiedad level que incluya una cadena "status" o "error".

El objeto de información también debe ser algo distinto. Las propiedades code y level pueden no funcionar en algunas implementaciones y determinados servidores podrían enviar objetos distintos.

En la tabla siguiente se describen los posibles valores de las propiedades code y level.

Si recibe muchos errores relacionados con el búfer, intente cambiarlo con la propiedad NetStream.bufferTime.

Véase también

Crea un objeto de evento que contiene información sobre eventos netStatus. Los objetos de evento se transfieren como parámetros a los detectores de eventos.

Véase también

Crea una copia del objeto NetStatusEvent y define el valor de cada propiedad para que coincida con el del objeto original.

Devuelve una cadena con todas las propiedades del objeto NetStatusEvent. La cadena tiene el siguiente formato:

[NetStatusEvent type=value bubbles=value cancelable=value info=value]

Define el valor de la propiedad type de un objeto de evento netStatus.

Este evento tiene las propiedades siguientes:

Véase también

En este ejemplo, el método netStatusHandler se registra como detector para el evento NetStatusEvent NetConnection.netStatus. Cuando se determina el estado (éxito o error) del intento de NetConnection.connect(), el evento netStatus activa este método. Si el intento de conexión con el objeto NetConnection es correcto (dicho de otro modo, si la propiedad info del objeto NetStatusEvent distribuido por el evento netStatus tiene una propiedad code que indica el éxito de la conexión), el código crea los objetos Video y NetStream y llama a los métodos Video.attachNetStream() y NetStream.play().

Nota: para ejecutar este ejemplo, necesita un archivo FLV con el mismo nombre y ubicación que la variable transferida a videoURL; en este caso, un archivo FLV llamado Video.flv que se encuentra en el mismo directorio que el archivo SWF.

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class NetStatusEventExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function NetStatusEventExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }

    }
 }