flash.events.Event (ActionScript 3.0)

	Propiedad	Definido por
		bubbles : Boolean [read-only] Indica si un evento es un evento de propagación.	Event
		cancelable : Boolean [read-only] Indica si se puede evitar el comportamiento asociado al evento.	Event
		constructor : Object Una referencia a la clase de objeto o función constructora para una instancia de objeto determinada.	Object
		currentTarget : Object [read-only] El objeto que procesa de forma activa el objeto de evento con un detector de eventos.	Event
		eventPhase : uint [read-only] La fase actual en el flujo del evento.	Event
		prototype : Object [static] Una referencia al objeto prototipo de una clase u objeto de función.	Object
		target : Object [read-only] El destino del evento.	Event
		type : String [read-only] El tipo de evento.	Event

	Método	Definido por
		Event(type:String, bubbles:Boolean = false, cancelable:Boolean = false) Crea un objeto de evento para transmitirlo como un parámetro a los detectores de eventos.	Event
		clone():Event Duplica una instancia de la subclase Event.	Event
		formatToString(className:String, ... arguments):String Una función de utilidad para implementar el método toString() en la clase Event personalizada.	Event
		hasOwnProperty(name:String):Boolean Indica si un objeto tiene definida una propiedad especificada.	Object
		isDefaultPrevented():Boolean Comprueba si se ha llamado a preventDefault() en el evento.	Event
		isPrototypeOf(theClass:Object):Boolean Indica si hay una instancia de la clase Object en la cadena de prototipo del objeto especificado como parámetro.	Object
		preventDefault():void Cancela el comportamiento predeterminado de un evento si es posible cancelarlo.	Event
		propertyIsEnumerable(name:String):Boolean Indica si existe la propiedad especificada y si es enumerable.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Establece la disponibilidad de una propiedad dinámica para operaciones de bucle.	Object
		stopImmediatePropagation():void Impide el proceso de cualquier detector de eventos en el nodo actual y los nodos siguientes en el flujo del evento.	Event
		stopPropagation():void Impide el proceso de cualquier detector de eventos en nodos siguientes al nodo actual.	Event
		toString():String Devuelve una cadena que contiene todas las propiedades del objeto de evento.	Event
		valueOf():Object Devuelve el valor simple del objeto especificado.	Object

	Constante	Definido por
		ACTIVATE : String = "activate" [static] Define el valor de la propiedad type para un objeto de evento activate.	Event
		ADDED : String = "added" [static] Define el valor de la propiedad type para un objeto de evento added.	Event
		ADDED_TO_STAGE : String = "addedToStage" [static] Define el valor de la propiedad type para un objeto de evento addedToStage.	Event
		CANCEL : String = "cancel" [static] Define el valor de la propiedad type para un objeto de evento cancel.	Event
		CHANGE : String = "change" [static] Define el valor de la propiedad type para un objeto de evento change.	Event
		CLOSE : String = "close" [static] Define el valor de la propiedad type para un objeto de evento close.	Event
		COMPLETE : String = "complete" [static] Define el valor de la propiedad type para un objeto de evento complete.	Event
		CONNECT : String = "connect" [static] Define el valor de la propiedad type para un objeto de evento connect.	Event
		DEACTIVATE : String = "deactivate" [static] Define el valor de la propiedad type para un objeto de evento deactivate.	Event
		ENTER_FRAME : String = "enterFrame" [static] Define el valor de la propiedad type para un objeto de evento enterFrame.	Event
		FULLSCREEN : String = "fullScreen" [static] Define el valor de la propiedad type para un objeto de evento fullScreen.	Event
		ID3 : String = "id3" [static] Define el valor de la propiedad type para un objeto de evento id3.	Event
		INIT : String = "init" [static] Define el valor de la propiedad type para un objeto de evento init.	Event
		MOUSE_LEAVE : String = "mouseLeave" [static] Define el valor de la propiedad type para un objeto de evento mouseLeave.	Event
		OPEN : String = "open" [static] Define el valor de la propiedad type para un objeto de evento open.	Event
		REMOVED : String = "removed" [static] Define el valor de la propiedad type para un objeto de evento removed.	Event
		REMOVED_FROM_STAGE : String = "removedFromStage" [static] Define el valor de la propiedad type para un objeto de evento removedFromStage.	Event
		RENDER : String = "render" [static] Define el valor de la propiedad type para un objeto de evento render.	Event
		RESIZE : String = "resize" [static] Define el valor de la propiedad type para un objeto de evento resize.	Event
		SCROLL : String = "scroll" [static] Define el valor de la propiedad type para un objeto de evento scroll.	Event
		SELECT : String = "select" [static] Define el valor de la propiedad type para un objeto de evento select.	Event
		SOUND_COMPLETE : String = "soundComplete" [static] Define el valor de la propiedad type para un objeto de evento soundComplete.	Event
		TAB_CHILDREN_CHANGE : String = "tabChildrenChange" [static] Define el valor de la propiedad type para un objeto de evento tabChildrenChange.	Event
		TAB_ENABLED_CHANGE : String = "tabEnabledChange" [static] Define el valor de la propiedad type para un objeto de evento tabEnabledChange.	Event
		TAB_INDEX_CHANGE : String = "tabIndexChange" [static] Define el valor de la propiedad type para un objeto de evento tabIndexChange.	Event
		UNLOAD : String = "unload" [static] Define el valor de la propiedad type para un objeto de evento unload.	Event

Información sobre propiedades

bubbles

propiedad

bubbles:Boolean [read-only]

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Indica si un evento es un evento de propagación. Si el evento se puede propagar, este valor es true; en caso contrario, es false.

Cuando se produce un evento, recorre las tres fases del flujo del evento: la fase de captura, que fluye desde el principio de la jerarquía de la lista de visualización hasta el nodo situado justo antes del nodo de destino; la fase de destino, que contiene el nodo de destino; y la fase de propagación, que fluye desde el nodo siguiente al de destino y recorre ascendentemente la jerarquía de la lista de visualización.

Algunos eventos, como activate y unload, no tienen fase de propagación. La propiedad bubbles tiene un valor false para eventos que no tienen fase de propagación.

Implementación
public function get bubbles():Boolean

Véase también

Objetos de evento

cancelable

propiedad

cancelable:Boolean [read-only]

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Indica si se puede evitar el comportamiento asociado al evento. Si el comportamiento se puede cancelar, este valor es true; en caso contrario, es false.

Implementación
public function get cancelable():Boolean

Véase también

Event.preventDefault()
Objetos de evento

currentTarget

propiedad

currentTarget:Object [read-only]

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

El objeto que procesa de forma activa el objeto de evento con un detector de eventos. Por ejemplo, si el usuario hace clic en un botón Aceptar, el destino actual puede estar en un nodo que contenga dicho botón o en uno de sus ascendientes que haya registrado un detector de eventos para dicho evento.

Implementación
public function get currentTarget():Object

Véase también

Objetos de evento

eventPhase

propiedad

eventPhase:uint [read-only]

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

La fase actual en el flujo del evento. Esta propiedad puede contener los siguientes valores numéricos:

1 Fase de captura (EventPhase.CAPTURING_PHASE).
2 Fase de destino (EventPhase.AT_TARGET).
3 Fase de propagación (EventPhase.BUBBLING_PHASE).

Implementación
public function get eventPhase():uint

Véase también

Objetos de evento

target

propiedad

target:Object [read-only]

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

El destino del evento. Esta propiedad contiene el nodo de destino. Por ejemplo, si el usuario hace clic en un botón Aceptar, el nodo de destino será el nodo de la lista de visualización que contenga dicho botón.

Implementación
public function get target():Object

Véase también

Objetos de evento

type

propiedad

type:String [read-only]

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

El tipo de evento. Este tipo distingue entre mayúsculas y minúsculas.

Implementación
public function get type():String

Véase también

Objetos de evento

Información sobre constructores

Event

()

constructor

public function Event(type:String, bubbles:Boolean = false, cancelable:Boolean = false)

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Crea un objeto de evento para transmitirlo como un parámetro a los detectores de eventos.

Parámetros

	`type:String` — El tipo de evento, al que se puede acceder como `Event.type`.

	`bubbles:Boolean` (default = `false`) — Determina si el objeto de evento participa en la fase de propagación del flujo del evento. El valor predeterminado es `false`.

	`cancelable:Boolean` (default = `false`) — Determina si se puede cancelar el objeto Event. El valor predeterminado es `false`.

Información sobre métodos

clone

()

método

public function clone():Event

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Duplica una instancia de la subclase Event.

Devuelve un nuevo objeto de evento que es una copia de la instancia original del objeto de evento. No llame manualmente a clone(); la clase EventDispatcher realiza la llamada automáticamente al redistribuir un evento, es decir, al llamar a dispatchEvent(event) desde un controlador que controla event.

El nuevo objeto de evento incluye todas las propiedades del original.

Al crear su propia clase Event personalizada, debe anular el método Event.clone() heredado para que pueda duplicar las propiedades de la clase personalizada. Si no establece todas las propiedades añadidas a la subclase Event, dichas propiedades no contendrán valores correctos cuando los detectores controlen el evento redistribuido.

En este ejemplo, PingEvent es una subclase de Event y, por tanto, implementa su propia versión de clone().

  class PingEvent extends Event { var URL:String; public override function clone():Event { return new PingEvent(type, bubbles, cancelable, URL); } }

Valor devuelto

Event — Un objeto de evento nuevo que es idéntico al original.

Véase también

Objetos de evento

formatToString

()

método

public function formatToString(className:String, ... arguments):String

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Una función de utilidad para implementar el método toString() en la clase Event personalizada. Se recomienda anular el método toString(), pero no es necesario.

  class PingEvent extends Event { var URL:String; public override function toString():String { return formatToString("PingEvent", "type", "bubbles", "cancelable", "eventPhase", "URL"); } }

Parámetros

	`className:String` — Nombre de la clase Event personalizada. En el ejemplo anterior, el parámetro `className` es `PingEvent`.

	`... arguments` — Las propiedades de la clase Event y las propiedades añadidas a su clase Event personalizada. En el ejemplo anterior, el parámetro `...arguments` incluye `type`, `bubbles`, `cancelable`, `eventPhase` y `URL`.

Valor devuelto

String — El nombre de la clase Event personalizada y el valor String del parámetro ...arguments.

isDefaultPrevented

()

método

public function isDefaultPrevented():Boolean

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Comprueba si se ha llamado a preventDefault() en el evento. Si se ha llamado a preventDefault(), devuelve el valor true; en caso contrario, devuelve false.

Valor devuelto

Boolean — Si se ha llamado a preventDefault(), devuelve el valor true; en caso contrario, devuelve false.

Véase también

flash.events.Event.preventDefault()
Objetos de evento

preventDefault

()

método

public function preventDefault():void

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Cancela el comportamiento predeterminado de un evento si es posible cancelarlo.

Muchos eventos tienen comportamientos asociados que Flash Player lleva a cabo de forma predeterminada. Por ejemplo, si un usuario escribe un carácter en un campo de texto, el comportamiento predeterminado será que el carácter se muestre en el campo de texto. Debido a que se puede cancelar el comportamiento predeterminado del evento TextEvent.TEXT_INPUT, se puede utilizar el método preventDefault() para evitar que se muestre el carácter.

Un ejemplo de comportamiento que no puede cancelarse es el comportamiento predeterminado asociado al evento Event.REMOVED, que se general cuando Flash Player está a punto de quitar un objeto de la lista de visualización. El comportamiento predeterminado (quitar el elemento) no se puede cancelar, por lo que el método preventDefault() no surte ningún efecto sobre este comportamiento predeterminado.

Puede utilizar la propiedad Event.cancelable para comprobar si es posible evitar el comportamiento predeterminado asociado a un evento concreto. Si el valor de Event.cancelable es true, se puede utilizar preventDefault() para cancelar el evento; en caso contrario, preventDefault() no surte ningún efecto.

Véase también

flash.events.Event.isDefaultPrevented()
Event.cancelable
Objetos de evento

stopImmediatePropagation

()

método

public function stopImmediatePropagation():void

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Impide el proceso de cualquier detector de eventos en el nodo actual y los nodos siguientes en el flujo del evento. Este método surte efecto de forma inmediata y afecta a los detectores de eventos del nodo actual. Por el contrario, el método stopPropagation() no surte efecto hasta que todos los detectores de eventos del nodo actual terminan su procesamiento.

Nota: este método no cancela el comportamiento asociado a dicho evento; consulte preventDefault() para más información sobre esta función.

Véase también

flash.events.Event.stopPropagation()
flash.events.Event.preventDefault()
Objetos de evento

stopPropagation

()

método

public function stopPropagation():void

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Impide el proceso de cualquier detector de eventos en nodos siguientes al nodo actual. Este método no afecta a ningún detector de eventos del nodo actual (currentTarget). Por el contrario, el método stopImmediatePropagation() evita el procesamiento de los detectores de eventos del nodo actual y de los siguientes. Las llamadas adicionales a este método no surten ningún efecto. Se puede llamar a este método en cualquier fase del flujo del evento.

Nota: este método no cancela el comportamiento asociado a dicho evento; consulte preventDefault() para más información sobre esta función.

Véase también

flash.events.Event.stopImmediatePropagation()
flash.events.Event.preventDefault()

toString

()

método

public function toString():String

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Devuelve una cadena que contiene todas las propiedades del objeto de evento. La cadena tiene el siguiente formato:

[Event type=value bubbles=value cancelable=value]

Valor devuelto

String — Una cadena que contiene todas las propiedades del objeto de evento.

Véase también

Objetos de evento

Información sobre constantes

ACTIVATE

Constante

public static const ACTIVATE:String = "activate"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de eventoactivate.

Nota: este evento no recorre una "fase de captura" y se distribuye directamente en el destino, ya se encuentre este destino en la lista de visualización o no.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	Cualquier instancia de DisplayObject con un detector registrado para el evento ACTIVATE.

Véase también

flash.events.EventDispatcher.activate
DEACTIVATE

ADDED

Constante

public static const ADDED:String = "added"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento added.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`true`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	La instancia de DisplayObject que se va a añadir a la lista de visualización. El objeto `target` no siempre es el objeto de la lista de visualización que registró el detector de eventos. Utilice la propiedad `currentTarget` para acceder al objeto de la lista de visualización que está procesando el evento actualmente.

Véase también

flash.display.DisplayObject.added
ADDED_TO_STAGE
REMOVED
REMOVED_FROM_STAGE

ADDED_TO_STAGE

Constante

public static const ADDED_TO_STAGE:String = "addedToStage"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Define el valor de la propiedad type de un objeto de evento addedToStage.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	La instancia de DisplayObject que se añade a la lista de visualización del escenario, bien directamente o a través de un subárbol que contiene la instancia de DisplayObject. Si la instancia de DisplayObject se añade directamente, el evento `added` se genera antes de este evento.

Véase también

flash.display.DisplayObject.addedToStage
ADDED
REMOVED
REMOVED_FROM_STAGE

CANCEL

Constante

public static const CANCEL:String = "cancel"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento cancel.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	Referencia al objeto en el que se cancela la operación.

Véase también

flash.net.FileReference.cancel

CHANGE

Constante

public static const CHANGE:String = "change"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento change.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`true`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	Objeto al que se ha modificado su valor. El objeto `target` no siempre es el objeto de la lista de visualización que registró el detector de eventos. Utilice la propiedad `currentTarget` para acceder al objeto de la lista de visualización que está procesando el evento actualmente.

Véase también

flash.text.TextField.change
flash.events.TextEvent.TEXT_INPUT

Constante

public static const CLOSE:String = "close"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento close.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	Objeto cuya conexión se ha cerrado.

Véase también

flash.net.Socket.close
flash.net.XMLSocket.close

COMPLETE

Constante

public static const COMPLETE:String = "complete"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento complete.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	Objeto de red que ha terminado de cargarse.

Véase también

flash.display.LoaderInfo.complete
flash.media.Sound.complete
flash.net.FileReference.complete
flash.net.URLLoader.complete
flash.net.URLStream.complete
Utilización de datos externos

CONNECT

Constante

public static const CONNECT:String = "connect"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento connect.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	Objeto Socket o XMLSocket que ha establecido una conexión de red.

Véase también

flash.net.Socket.connect
flash.net.XMLSocket.connect

DEACTIVATE

Constante

public static const DEACTIVATE:String = "deactivate"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento deactivate.

Nota: este evento no recorre una "fase de captura" y se distribuye directamente en el destino, ya se encuentre este destino en la lista de visualización o no.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	Cualquier instancia de DisplayObject con un detector registrado para el evento DEACTIVATE.

Véase también

flash.events.EventDispatcher.deactivate
ACTIVATE

ENTER_FRAME

Constante

public static const ENTER_FRAME:String = "enterFrame"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento enterFrame.

Nota: este evento no recorre una "fase de captura" y se distribuye directamente en el destino, ya se encuentre este destino en la lista de visualización o no.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	Cualquier instancia de DisplayObject con un detector registrado para el evento ENTER_FRAME.

Véase también

flash.display.DisplayObject.enterFrame

FULLSCREEN

Constante

public static const FULLSCREEN:String = "fullScreen"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento fullScreen.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	El objeto Stage.

Véase también

flash.display.Stage.fullScreen

ID3

Constante

public static const ID3:String = "id3"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento id3.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	Objeto Sound que carga el MP3 para el que los datos ID3 están ahora disponibles. El objeto `target` no siempre es el objeto de la lista de visualización que registró el detector de eventos. Utilice la propiedad `currentTarget` para acceder al objeto de la lista de visualización que está procesando el evento actualmente.

Véase también

flash.media.Sound.id3

INIT

Constante

public static const INIT:String = "init"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento init.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	Objeto LoaderInfo asociado al archivo SWF que se está cargando.

Véase también

flash.display.LoaderInfo.init

MOUSE_LEAVE

Constante

public static const MOUSE_LEAVE:String = "mouseLeave"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento mouseLeave.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	El objeto Stage. El objeto `target` no siempre es el objeto de la lista de visualización que registró el detector de eventos. Utilice la propiedad `currentTarget` para acceder al objeto de la lista de visualización que está procesando el evento actualmente.

Véase también

flash.display.Stage.mouseLeave
flash.events.MouseEvent

OPEN

Constante

public static const OPEN:String = "open"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento open.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	Objeto de red que ha abierto una conexión.

Véase también

flash.display.LoaderInfo.open
flash.media.Sound.open
flash.net.FileReference.open
flash.net.URLLoader.open
flash.net.URLStream.open

REMOVED

Constante

public static const REMOVED:String = "removed"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento removed.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`true`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	La instancia de DisplayObject que se va a quitar de la lista de visualización. El objeto `target` no siempre es el objeto de la lista de visualización que registró el detector de eventos. Utilice la propiedad `currentTarget` para acceder al objeto de la lista de visualización que está procesando el evento actualmente.

Véase también

flash.display.DisplayObject.removed
ADDED
ADDED_TO_STAGE
REMOVED_FROM_STAGE

REMOVED_FROM_STAGE

Constante

public static const REMOVED_FROM_STAGE:String = "removedFromStage"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9.0.28.0

Define el valor de la propiedad type de un objeto de evento removedFromStage.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	La instancia de DisplayObject que se elimina de la lista de visualización del escenario, bien directamente o a través de un subárbol que contiene la instancia de DisplayObject. Si la instancia de DisplayObject se elimina directamente, el evento `removed` se produce antes de este evento.

Véase también

flash.display.DisplayObject.removedFromStage
ADDED
REMOVED
ADDED_TO_STAGE

RENDER

Constante

public static const RENDER:String = "render"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento render.

Nota: este evento no recorre una "fase de captura" y se distribuye directamente en el destino, ya se encuentre este destino en la lista de visualización o no.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no es posible cancelar el comportamiento predeterminado.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	Cualquier instancia de DisplayObject con un detector registrado para el evento RENDER.

Véase también

flash.display.DisplayObject.render
flash.display.Stage.invalidate()

RESIZE

Constante

public static const RESIZE:String = "resize"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento resize.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	El objeto Stage.

Véase también

flash.display.Stage.resize

SCROLL

Constante

public static const SCROLL:String = "scroll"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento scroll.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	El objeto TextField que se desplaza. El objeto `target` no siempre es el objeto de la lista de visualización que registró el detector de eventos. Utilice la propiedad `currentTarget` para acceder al objeto de la lista de visualización que está procesando el evento actualmente.

Véase también

flash.text.TextField.scroll

SELECT

Constante

public static const SELECT:String = "select"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento select.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	El objeto FileReference en el que se ha seleccionado un elemento.

Véase también

flash.net.FileReference.select

SOUND_COMPLETE

Constante

public static const SOUND_COMPLETE:String = "soundComplete"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento soundComplete.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	El objeto Sound en el que ha terminado de reproducirse un sonido.

Véase también

flash.media.SoundChannel.soundComplete

TAB_CHILDREN_CHANGE

Constante

public static const TAB_CHILDREN_CHANGE:String = "tabChildrenChange"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento tabChildrenChange.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`true`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	El objeto cuyo indicador tabChildren ha cambiado. El objeto `target` no siempre es el objeto de la lista de visualización que registró el detector de eventos. Utilice la propiedad `currentTarget` para acceder al objeto de la lista de visualización que está procesando el evento actualmente.

Véase también

flash.display.InteractiveObject.tabChildrenChange

TAB_ENABLED_CHANGE

Constante

public static const TAB_ENABLED_CHANGE:String = "tabEnabledChange"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento tabEnabledChange.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`true`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	El objeto InteractiveObject cuyo indicador tabEnabled ha cambiado. El objeto `target` no siempre es el objeto de la lista de visualización que registró el detector de eventos. Utilice la propiedad `currentTarget` para acceder al objeto de la lista de visualización que está procesando el evento actualmente.

Véase también

flash.display.InteractiveObject.tabEnabledChange

TAB_INDEX_CHANGE

Constante

public static const TAB_INDEX_CHANGE:String = "tabIndexChange"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento tabIndexChange.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`true`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	El objeto cuyo tabIndex ha cambiado. El objeto `target` no siempre es el objeto de la lista de visualización que registró el detector de eventos. Utilice la propiedad `currentTarget` para acceder al objeto de la lista de visualización que está procesando el evento actualmente.

Véase también

flash.display.InteractiveObject.tabIndexChange

UNLOAD

Constante

public static const UNLOAD:String = "unload"

Versión del lenguaje:

ActionScript 3.0

Versión del reproductor:

Flash Player 9

Define el valor de la propiedad type de un objeto de evento unload.

Este evento tiene las propiedades siguientes:

Propiedad	Valor
`bubbles`	`false`
`cancelable`	`false`; no hay ningún comportamiento predeterminado que cancelar.
`currentTarget`	El objeto que procesa de forma activa el objeto de evento con un detector de eventos.
`target`	El objeto LoaderInfo asociado al archivo SWF que se está descargando o reemplazando.

Véase también

flash.display.LoaderInfo.unload

Ejemplos Cómo utilizar los ejemplos

EventExample.as

En el ejemplo siguiente, se utiliza la clase EventExample y la clase personalizada Square para demostrar cómo se gestiona la propagación de eventos.

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;

    public class EventExample extends Sprite {

        public function EventExample() {
            var square_0:Square = new Square(300, 0x336633);
            addChild(square_0);

            var square_1:Square = new Square(250, 0x669966);
            square_0.addChild(square_1);

            var square_2:Square = new Square(200, 0x66CC66);
            square_1.addChild(square_2);

            var square_3:Square = new Square(150, 0xAA0000);
            square_3.shouldBubble = false;
            square_2.addChild(square_3);

            var square_4:Square = new Square(100, 0x66FF66);
            square_3.addChild(square_4);

            var square_5:Square = new Square(50, 0xCC0000);
            square_5.shouldBubble = false;
            square_4.addChild(square_5);

            this.addEventListener(MouseEvent.CLICK, clickHandler);
        }

        private function clickHandler(e:Event):void {
            trace(">> stage: " + e.type + " event from " + e.target.name + " called on " + this.name);
            trace(">> --------------------------------------------");
        }
    }
}

import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;

class Square extends Sprite {
    private var sideLen:int;
    private var color:Number;
    public var shouldBubble:Boolean = true;

    public function Square(sideLen:int, color:Number) {
        this.sideLen = sideLen;
        this.color = color;
        init();
        draw();
    }

    private function init():void {
        buttonMode = true;
        this.addEventListener(MouseEvent.CLICK, firstClickHandler);
        this.addEventListener(MouseEvent.CLICK, secondClickHandler);
        this.addEventListener(MouseEvent.CLICK, thirdClickHandler);
    }

    private function draw():void {
        this.graphics.beginFill(color);
        this.graphics.drawRect(0, 0, sideLen, sideLen);
    }

    private function firstClickHandler(e:Event):void {
        trace(">> 1e: " + e.type + " event from " + e.target.name + " called on " + this.name);
        if(!shouldBubble) {
            e.stopPropagation();
        }
    }

    private function secondClickHandler(e:Event):void {
        trace(">> 2e: " + e.type + " event from " + e.target.name + " called on " + this.name);
        if(!shouldBubble) {
            e.stopImmediatePropagation();
            trace(">> --------------------------------------------");
        }
    }

    private function thirdClickHandler(e:Event):void {
        trace(">> 3e: " + e.type + " event from " + e.target.name + " called on " + this.name);
    }
}

EventExample2.as

En el siguiente ejemplo se crea una demostración interactiva de la diferencia entre los eventos ADDED y ADDED_TO_STAGE, así como la diferencia entre los eventos REMOVED y REMOVED_FROM_STAGE. Hacer clic en un elemento sprite lo elimina del escenario, así como todos los elementos anidados. Por ejemplo, hacer clic en el elemento sprite de mayor tamaño activa un evento REMOVED y tres eventos REMOVED_FROM_STAGE.

 package {
    import flash.display.Sprite;
    import flash.events.*;

    public class EventExample2 extends Sprite {
        public function EventExample2():void {
            var parentSprite:Sprite = createSprite("parentSprite",200);
            var childSprite:Sprite = createSprite("childSprite",100);
            var childOfChildSprite:Sprite = createSprite("childOfChildSprite",50);

            trace(":: Adding to Stage ::");
            this.addChild(parentSprite);
            trace(":: Adding to Stage ::");
            parentSprite.addChild(childSprite);
            trace(":: Adding to Stage ::");
            childSprite.addChild(childOfChildSprite);
        }
        private function createSprite(name:String,size:uint):Sprite {
            trace(":: Creating Sprite ::");
            var newSprite:Sprite = new Sprite();
            newSprite.name = name;
            newSprite.graphics.beginFill(0xFFFFFF * Math.random(),1);
            newSprite.graphics.drawRect(0,0,size,size);
            newSprite.graphics.endFill();
            newSprite.addEventListener(Event.ADDED, spriteAdded);
            newSprite.addEventListener(Event.ADDED_TO_STAGE, spriteAddedToStage);
            newSprite.addEventListener(Event.REMOVED, spriteRemoved);
            newSprite.addEventListener(Event.REMOVED_FROM_STAGE, spriteRemovedFromStage);
            newSprite.addEventListener(MouseEvent.CLICK, remove);
            return newSprite;
        }
        private function remove(event:Event) {
            if(event.target == event.currentTarget) {
                trace(":: Removing Clicked Sprite ::");
                var target:Sprite = Sprite(event.target);
                target.parent.removeChild(target);
            }
        }
        private function spriteRemovedFromStage(event:Event):void {
            trace("REMOVED_FROM_STAGE: " + event.target.name + " : " + event.currentTarget.name);
        }
        private function spriteRemoved(event:Event):void {
            trace("REMOVED: " + event.target.name + " from " + event.currentTarget.name);
        }
        private function spriteAddedToStage(event:Event):void {
            trace("ADDED_TO_STAGE: " + event.target.name + " : " + event.currentTarget.name);
        }
        private function spriteAdded(event:Event):void {
            trace("ADDED: " + event.target.name + " within " + event.currentTarget.name);
        }
    }
}

Página actual: http://livedocs.adobe.com/flash/9.0_es/ActionScriptLangRefV3/flash/events/Event.html

Referencia del lenguaje y componentes ActionScript 3.0		Todos los paquetes \| Todas las clases \| Elementos del lenguaje \| Índice \| Apéndices \| Convenciones \| Marcos Quitar marcos
Event	Propiedades \| Métodos \| Constantes \| Ejemplos

Paquete	flash.events
Clase	public class Event
Herencia	Event Object
Subclases	ActivityEvent, CaptionChangeEvent, CaptionTargetEvent, ColorPickerEvent, ComponentEvent, ContextMenuEvent, DataChangeEvent, FocusEvent, HTTPStatusEvent, KeyboardEvent, LayoutEvent, ListEvent, MetadataEvent, MotionEvent, MouseEvent, NetStatusEvent, ProgressEvent, ScrollEvent, SliderEvent, SoundEvent, StatusEvent, SyncEvent, TextEvent, TimerEvent, TweenEvent, VideoEvent