Especifica el modo de botón de este elemento sprite. Si el valor es true, este elemento sprite se comporta como un botón, lo que significa que activa la visualización del cursor de mano cuando el cursor pasa por encima del elemento sprite y puede recibir un evento click si se presionan las teclas Intro o espacio cuando está seleccionado el elemento sprite. Puede suprimir la visualización del cursor de mano al definir la propiedad useHandCursor con el valor false, en cuyo caso se muestra el puntero.

Aunque es preferible utilizar la clase SimpleButton para crear botones, puede utilizar la propiedad buttonMode con el fin de dar a un elemento sprite alguna funcionalidad de botón. Para incluir un elemento sprite en el orden de tabulación, defina la propiedad tabEnabled (heredada de la clase InteractiveObject y con el valor predeterminado false) con el valor true. Además, decida si desea que los elementos secundarios del elemento sprite estén habilitados para ratón. La mayoría de los botones no activan la interactividad de ratón para sus objetos secundarios, ya que ello genera confusión en el flujo de eventos. Para desactivar la interactividad de ratón para todos los objetos secundarios, debe definir la propiedad mouseChildren (heredada de la clase DisplayObjectContainer) con el valor false.

Si utiliza la propiedad buttonMode con la clase MovieClip (que es una subclase de la clase Sprite), el botón puede tener alguna funcionalidad añadida. Si incluye fotogramas etiquetados con _up, _over y _down, Flash Player proporcionará cambios de estado automáticos (funcionalidad similar a la que se ofrecía en versiones anteriores de ActionScript para clips de película utilizados como botones). Estos cambios de estado automáticos no están disponibles para elementos sprite, que carecen de línea de tiempo y, por consiguiente, no tienen fotogramas que etiquetar.

Véase también

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace("Click!");
}

addChild(circle1);
addChild(circle2);

Especifica el objeto de visualización sobre el que se está arrastrando el elemento sprite o sobre el que se ha colocado el elemento sprite.

Véase también

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown)

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Especifica el objeto Graphics que pertenece a este elemento sprite, donde pueden ejecutarse comandos de dibujo vectorial.

import flash.display.Sprite;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(40, 40, 40);
addChild(circle);

Designa otro elemento sprite para que actúe como área activa de un elemento sprite. Si la propiedad hitArea no existe o tiene el valor null o undefined, se utilizará el propio elemento sprite como área activa. El valor de la propiedad hitArea puede ser una referencia a un objeto Sprite.

Puede cambiar la propiedad hitArea en cualquier momento; el elemento sprite modificado adoptará de inmediato el nuevo comportamiento de área activa. No es preciso que el elemento sprite designado como área activa sea visible; se detectará la condición de "activa" de su forma gráfica aunque no sea visible.

Nota: debe establecer con el valor false la propiedad mouseEnabled del elemento sprite designado como área activa. En caso contrario, el botón sprite podría no funcionar, ya que el elemento sprite designado como área activa recibe eventos del ratón en lugar del botón sprite.

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var square:Sprite = new Sprite();
square.graphics.beginFill(0xCCFF00);
square.graphics.drawRect(200, 0, 100, 100);

circle.hitArea = square;
square.mouseEnabled = false;

circle.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void{
    trace(event.target == circle); // true
    trace(event.target == square); // false
}

addChild(circle);
addChild(square);

Controla el sonido dentro de este elemento sprite.

Véase también

import flash.display.Sprite;
import flash.display.Loader;
import flash.events.IOErrorEvent;
import flash.events.MouseEvent;
import flash.net.URLRequest;
import flash.text.TextField;
import flash.media.SoundTransform;

var container:Sprite = new Sprite();
addChild(container);

var ldr:Loader = new Loader;
var urlReq:URLRequest = new URLRequest("SoundPlayer.swf");
ldr.load(urlReq);

container.addChild(ldr);
ldr.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, urlNotFound);

var tf:TextField = new TextField();
tf.htmlText = "<a href = 'event:Mute'>Mute / Unmute</a>";
addChild(tf);

var mySoundTransform:SoundTransform = new SoundTransform();
mySoundTransform.volume = 1;

tf.addEventListener(MouseEvent.CLICK, mute);

function mute(event:MouseEvent):void {
    if (mySoundTransform.volume == 0) {
        mySoundTransform.volume = 1;
    } else {
        mySoundTransform.volume = 0;
    }
    container.soundTransform = mySoundTransform;
}

function urlNotFound(event:IOErrorEvent):void {
    trace("The URL was not found.");
}

Valor booleano que indica si debe aparecer la mano que señala (cursor de mano) cuando el ratón pasa por encima de un elemento sprite en el que la propiedad buttonMode se ha definido con el valor true. El valor predeterminado de la propiedad useHandCursor es true. Si useHandCursor se establece con el valor true, la mano que señala empleada para los botones se mostrará cuando el ratón pase por encima de un elemento sprite de botón. Si useHandCursor se establece con el valor false, se utilizará el puntero de flecha.

Puede cambiar la propiedad useHandCursor en cualquier momento; el elemento sprite modificado adoptará de inmediato el nuevo aspecto de cursor.

Véase también

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle1:Sprite = new Sprite();
circle1.graphics.beginFill(0xFFCC00);
circle1.graphics.drawCircle(40, 40, 40);
circle1.buttonMode = true;
circle1.useHandCursor = true;
circle1.addEventListener(MouseEvent.CLICK, clicked);

var circle2:Sprite = new Sprite();
circle2.graphics.beginFill(0xFFCC00);
circle2.graphics.drawCircle(120, 40, 40);
circle2.buttonMode = true;
circle2.useHandCursor = false;
circle2.addEventListener(MouseEvent.CLICK, clicked);

function clicked(event:MouseEvent):void {
    trace("Click!");
}

addChild(circle1);
addChild(circle2);

Crea una nueva instancia de Sprite. Tras crear la instancia de Sprite, llame al método DisplayObjectContainer.addChild() o DisplayObjectContainer.addChildAt() para añadir la instancia Sprite a una instancia DisplayObjectContainer principal.

Permite al usuario arrastrar el elemento sprite especificado. El elemento sprite se puede seguir arrastrando hasta que se detenga explícitamente mediante una llamada a Sprite.stopDrag() o hasta que otro elemento sprite pueda arrastrarse. Sólo es posible arrastrar elementos sprite de uno en uno.

Parámetros

Véase también

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown)

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

Finaliza el método startDrag(). Un elemento sprite que se ha convertido en arrastrable con el método startDrag() podrá arrastrarse hasta que se añada un método stopDrag() o hasta que se pueda arrastrar otro elemento sprite. Sólo es posible arrastrar elementos sprite de uno en uno.

Véase también

import flash.display.Sprite;
import flash.events.MouseEvent;

var circle:Sprite = new Sprite();
circle.graphics.beginFill(0xFFCC00);
circle.graphics.drawCircle(0, 0, 40);

var target1:Sprite = new Sprite();
target1.graphics.beginFill(0xCCFF00);
target1.graphics.drawRect(0, 0, 100, 100);
target1.name = "target1";

var target2:Sprite = new Sprite();
target2.graphics.beginFill(0xCCFF00);
target2.graphics.drawRect(0, 200, 100, 100);
target2.name = "target2";

addChild(target1);
addChild(target2);
addChild(circle);

circle.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown)

function mouseDown(event:MouseEvent):void {
    circle.startDrag();
}
circle.addEventListener(MouseEvent.MOUSE_UP, mouseReleased);

function mouseReleased(event:MouseEvent):void {
    circle.stopDrag();
    trace(circle.dropTarget.name);
}

1. Declare la propiedad size (100 x 100 píxeles) y el color de fondo (naranja) para utilizarlos después al dibujar el cuadrado.
2. A continuación, el constructor crea un nuevo objeto Sprite child y lo emplea para añadir dos detectores de eventos y los métodos asociados: mouseDownHandler() y mouseUpHandler().
3. El objeto Sprite child se transfiere después al método draw(), que dibuja el cuadrado naranja.
4. El elemento secundario se coloca en la lista de visualización mediante una llamada al método addChild().
5. Los detectores de eventos funcionan del modo siguiente:
   • mouseDownHandler(): cuando el usuario hace clic en el objeto Sprite, este método añade un detector de eventos mouseMove, el método mouseMoveHandler(), que procesa los movimientos del ratón. Posteriormente se llama al método startDrag(), que permite que se arrastre el objeto Sprite.
   • mouseUpHandler(): cuando se suelta el botón del ratón, se elimina el detector de eventos mouseMove y se llama al método stopDrag() que fija el cuadrado naranja en su lugar correspondiente.
   • mouseMoveHandler: siempre que el botón izquierdo del ratón esté pulsado, este método da instrucciones al reproductor para que vuelva a dibujar continuamente el cuadrado naranja.

Nota: cada uno de los métodos de detectores de eventos declara una variable local sprite local, que se asigna como propiedad target del evento.

package {
    import flash.display.Sprite;
    import flash.events.*;

    public class SpriteExample extends Sprite {
        private var size:uint    = 100;
        private var bgColor:uint = 0xFFCC00;

        public function SpriteExample() {
            var child:Sprite = new Sprite();
            child.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);
            child.addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
            draw(child);
            addChild(child);
        }

        private function mouseDownHandler(event:MouseEvent):void {
            trace("mouseDownHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.startDrag();
        }

        private function mouseUpHandler(event:MouseEvent):void {
            trace("mouseUpHandler");
            var sprite:Sprite = Sprite(event.target);
            sprite.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler);
            sprite.stopDrag();
        }

        private function mouseMoveHandler(event:MouseEvent):void {
            trace("mouseMoveHandler");
            event.updateAfterEvent();
        }

        private function draw(sprite:Sprite):void {
            sprite.graphics.beginFill(bgColor);
            sprite.graphics.drawRect(0, 0, size, size);
            sprite.graphics.endFill();
        }
    }
}