Especifica un objeto de visualización que se utiliza como objeto visual para el estado "Presionado" del botón; el estado en que se encuentra el botón cuando el usuario hace clic en el objeto hitTestState.

Véase también

Un valor booleano que especifica si está activado un botón. Cuando un botón está desactivado (la propiedad enabled está configurada como false), el botón está visible pero no se puede hacer clic en él. El valor predeterminado es true. Esta propiedad resulta útil si desea desactivar parte de la navegación; por ejemplo, puede que desee desactivar un botón de la página mostrada actualmente para que no se pueda hacer clic en él y no pueda volver a cargarse la página.

Especifica un objeto de visualización que se utiliza como objeto de prueba de zona activa para el botón. En el caso de un botón básico, establezca la propiedad hitTestState con el mismo objeto de visualización que la propiedad overState. Si no establece la propiedad hitTestState, SimpleButton está inactivo, no responde a los eventos del ratón y el teclado.

Véase también

Especifica un objeto de visualización que se utiliza como objeto visual para el estado del botón cuando se desplaza el puntero sobre él, el estado en que se encuentra el botón cuando el ratón se sitúa sobre el botón.

Véase también

El objeto SoundTransform asignado a este botón. Un objeto SoundTransform incluye propiedades para establecer el volumen, el desplazamiento lateral, la asignación del altavoz izquierdo y la asignación del altavoz derecho. Este objeto SoundTransform aplica todos los estados del botón. Este objeto SoundTransform sólo afecta a los sonidos incorporados.

Véase también

Indica si otros objetos de visualización que sean objetos SimpleButton o MovieClip pueden recibir eventos de liberación del botón del ratón. La propiedad trackAsMenu permite crear menús. Puede establecer la propiedad trackAsMenu en cualquier objeto SimpleButton o MovieClip. Si la propiedad trackAsMenu no existe, el comportamiento predeterminado será false.

Puede cambiar la propiedad trackAsMenu en cualquier momento; el botón modificado adoptará de inmediato el nuevo comportamiento.

Especifica un objeto de visualización que se utiliza como objeto visual para el estado del botón sin presionar, el estado en que se encuentra el botón cuando el ratón no está situado sobre el botón.

Véase también

Valor booleano que, cuando se establece como true, indica si debe aparecer el cursor de mano cuando el ratón pasa por encima de un botón. Si esta propiedad se establece como false, se mostrará el cursor de puntero de flecha. El valor predeterminado es true.

Puede cambiar la propiedad useHandCursor en cualquier momento; el botón modificado adoptará de inmediato el nuevo comportamiento de cursor.

Crea una nueva instancia de SimpleButton. Cualquiera de los objetos de visualización que representan los diversos estados del botón pueden establecerse como parámetros en el constructor.

1. En el constructor SimpleButtonExample(), se crea un nuevo objeto CustomSimpleButton de tipo SimpleButton denominado button, que llama al método constructor CustomSimpleButton. El objeto button se añade a la lista de visualización. El color y el tamaño del botón se determinan en los pasos siguientes.
2. En la clase CustomSimpleButton, se declaran propiedades de instancia que se utilizarán más adelante para controlar el tamaño y el color de fondo de button, según el estado que tengan (naranja para el estado normal, amarillo oscuro para cuando se pasa el ratón por encima, azul claro cuando el ratón está en estado presionado). En todos los estados de button, el tamaño del cuadrado se establece en 80 píxeles mediante la propiedad size.
3. La función constructora para la clase CustomSimpleButton establece las propiedades downState, overState, upState, hitTestState y useHandCursor con cuatro instancias de la clase ButtonDisplayState.
4. En la clase ButtonDisplayState, el constructor establece el valor del color de fondo y el tamaño del cuadrado y llama al método draw().
5. El método draw() vuelve a dibujar el cuadrado con el tamaño y color de fondo definidos en el constructor según el estado del botón.

package {
    import flash.display.Sprite;

    public class SimpleButtonExample extends Sprite {
        public function SimpleButtonExample() {
            var button:CustomSimpleButton = new CustomSimpleButton();
            addChild(button);
        }
    }
}

import flash.display.DisplayObject;
import flash.display.Shape;
import flash.display.SimpleButton;

class CustomSimpleButton extends SimpleButton {
    private var upColor:uint   = 0xFFCC00;
    private var overColor:uint = 0xCCFF00;
    private var downColor:uint = 0x00CCFF;
    private var size:uint      = 80;

    public function CustomSimpleButton() {
        downState      = new ButtonDisplayState(downColor, size);
        overState      = new ButtonDisplayState(overColor, size);
        upState        = new ButtonDisplayState(upColor, size);
        hitTestState   = new ButtonDisplayState(upColor, size * 2);
        hitTestState.x = -(size / 4);
        hitTestState.y = hitTestState.x;
        useHandCursor  = true;
    }
}

class ButtonDisplayState extends Shape {
    private var bgColor:uint;
    private var size:uint;

    public function ButtonDisplayState(bgColor:uint, size:uint) {
        this.bgColor = bgColor;
        this.size    = size;
        draw();
    }

    private function draw():void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, size, size);
        graphics.endFill();
    }
}